matita/matita/contribs/lambdadelta/basic_2/relocation/drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_coafter.ma".
  16 include "basic_2/notation/relations/rdropstar_3.ma".
  17 include "basic_2/notation/relations/rdropstar_4.ma".
  18 include "basic_2/relocation/lreq.ma".
  19 include "basic_2/relocation/lifts.ma".
  20
  21 (* GENERIC SLICING FOR LOCAL ENVIRONMENTS ***********************************)
  22
  23 (* Basic_1: includes: drop_skip_bind drop1_skip_bind *)
  24 (* Basic_2A1: includes: drop_atom drop_pair drop_drop drop_skip
  25                         drop_refl_atom_O2 drop_drop_lt drop_skip_lt
  26 *)
  27 inductive drops (b:bool): rtmap → relation lenv ≝
  28 | drops_atom: ∀f. (b = Ⓣ → 𝐈⦃f⦄) → drops b (f) (⋆) (⋆)
  29 | drops_drop: ∀f,I,L1,L2,V. drops b f L1 L2 → drops b (⫯f) (L1.ⓑ{I}V) L2
  30 | drops_skip: ∀f,I,L1,L2,V1,V2.
  31               drops b f L1 L2 → ⬆*[f] V2 ≡ V1 →
  32               drops b (↑f) (L1.ⓑ{I}V1) (L2.ⓑ{I}V2)
  33 .
  34
  35 interpretation "uniform slicing (local environment)"
  36    'RDropStar i L1 L2 = (drops true (uni i) L1 L2).
  37
  38 interpretation "generic slicing (local environment)"
  39    'RDropStar b f L1 L2 = (drops b f L1 L2).
  40
  41 definition d_liftable1: predicate (relation2 lenv term) ≝
  42                         λR. ∀K,T. R K T → ∀b,f,L. ⬇*[b, f] L ≡ K →
  43                         ∀U. ⬆*[f] T ≡ U → R L U.
  44
  45 definition d_deliftable1: predicate (relation2 lenv term) ≝
  46                           λR. ∀L,U. R L U → ∀b,f,K. ⬇*[b, f] L ≡ K →
  47                           ∀T. ⬆*[f] T ≡ U → R K T.
  48
  49 definition d_liftable2: predicate (lenv → relation term) ≝
  50                         λR. ∀K,T1,T2. R K T1 T2 → ∀b,f,L. ⬇*[b, f] L ≡ K →
  51                         ∀U1. ⬆*[f] T1 ≡ U1 →
  52                         ∃∃U2. ⬆*[f] T2 ≡ U2 & R L U1 U2.
  53
  54 definition d_deliftable2_sn: predicate (lenv → relation term) ≝
  55                              λR. ∀L,U1,U2. R L U1 U2 → ∀b,f,K. ⬇*[b, f] L ≡ K →
  56                              ∀T1. ⬆*[f] T1 ≡ U1 →
  57                              ∃∃T2. ⬆*[f] T2 ≡ U2 & R K T1 T2.
  58
  59 definition co_dropable_sn: predicate (rtmap → relation lenv) ≝
  60                            λR. ∀b,f,L1,K1. ⬇*[b, f] L1 ≡ K1 → 𝐔⦃f⦄ →
  61                            ∀f2,L2. R f2 L1 L2 → ∀f1. f ~⊚ f1 ≡ f2 →
  62                            ∃∃K2. R f1 K1 K2 & ⬇*[b, f] L2 ≡ K2.
  63
  64
  65 definition co_dropable_dx: predicate (rtmap → relation lenv) ≝
  66                            λR. ∀f2,L1,L2. R f2 L1 L2 →
  67                            ∀b,f,K2. ⬇*[b, f] L2 ≡ K2 → 𝐔⦃f⦄ →
  68                            ∀f1. f ~⊚ f1 ≡ f2 →
  69                            ∃∃K1. ⬇*[b, f] L1 ≡ K1 & R f1 K1 K2.
  70
  71 definition co_dedropable_sn: predicate (rtmap → relation lenv) ≝
  72                              λR. ∀b,f,L1,K1. ⬇*[b, f] L1 ≡ K1 → ∀f1,K2. R f1 K1 K2 →
  73                              ∀f2. f ~⊚ f1 ≡ f2 →
  74                              ∃∃L2. R f2 L1 L2 & ⬇*[b, f] L2 ≡ K2 & L1 ≡[f] L2.
  75
  76 (* Basic properties *********************************************************)
  77
  78 lemma drops_atom_F: ∀f. ⬇*[Ⓕ, f] ⋆ ≡ ⋆.
  79 #f @drops_atom #H destruct
  80 qed.
  81
  82 lemma drops_eq_repl_back: ∀b,L1,L2. eq_repl_back … (λf. ⬇*[b, f] L1 ≡ L2).
  83 #b #L1 #L2 #f1 #H elim H -f1 -L1 -L2
  84 [ /4 width=3 by drops_atom, isid_eq_repl_back/
  85 | #f1 #I #L1 #L2 #V #_ #IH #f2 #H elim (eq_inv_nx … H) -H
  86   /3 width=3 by drops_drop/
  87 | #f1 #I #L1 #L2 #V1 #v2 #_ #HV #IH #f2 #H elim (eq_inv_px … H) -H
  88   /3 width=3 by drops_skip, lifts_eq_repl_back/
  89 ]
  90 qed-.
  91
  92 lemma drops_eq_repl_fwd: ∀b,L1,L2. eq_repl_fwd … (λf. ⬇*[b, f] L1 ≡ L2).
  93 #b #L1 #L2 @eq_repl_sym /2 width=3 by drops_eq_repl_back/ (**) (* full auto fails *)
  94 qed-.
  95
  96 (* Basic_2A1: includes: drop_FT *)
  97 lemma drops_TF: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → ⬇*[Ⓕ, f] L1 ≡ L2.
  98 #f #L1 #L2 #H elim H -f -L1 -L2
  99 /3 width=1 by drops_atom, drops_drop, drops_skip/
 100 qed.
 101
 102 (* Basic_2A1: includes: drop_gen *)
 103 lemma drops_gen: ∀b,f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → ⬇*[b, f] L1 ≡ L2.
 104 * /2 width=1 by drops_TF/
 105 qed-.
 106
 107 (* Basic_2A1: includes: drop_T *)
 108 lemma drops_F: ∀b,f,L1,L2. ⬇*[b, f] L1 ≡ L2 → ⬇*[Ⓕ, f] L1 ≡ L2.
 109 * /2 width=1 by drops_TF/
 110 qed-.
 111
 112 (* Basic inversion lemmas ***************************************************)
 113
 114 fact drops_inv_atom1_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → X = ⋆ →
 115                           Y = ⋆ ∧ (b = Ⓣ → 𝐈⦃f⦄).
 116 #b #f #X #Y * -f -X -Y
 117 [ /3 width=1 by conj/
 118 | #f #I #L1 #L2 #V #_ #H destruct
 119 | #f #I #L1 #L2 #V1 #V2 #_ #_ #H destruct
 120 ]
 121 qed-.
 122
 123 (* Basic_1: includes: drop_gen_sort *)
 124 (* Basic_2A1: includes: drop_inv_atom1 *)
 125 lemma drops_inv_atom1: ∀b,f,Y. ⬇*[b, f] ⋆ ≡ Y → Y = ⋆ ∧ (b = Ⓣ → 𝐈⦃f⦄).
 126 /2 width=3 by drops_inv_atom1_aux/ qed-.
 127
 128 fact drops_inv_drop1_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → ∀g,I,K,V. X = K.ⓑ{I}V → f = ⫯g →
 129                           ⬇*[b, g] K ≡ Y.
 130 #b #f #X #Y * -f -X -Y
 131 [ #f #Hf #g #J #K #W #H destruct
 132 | #f #I #L1 #L2 #V #HL #g #J #K #W #H1 #H2 <(injective_next … H2) -g destruct //
 133 | #f #I #L1 #L2 #V1 #V2 #_ #_ #g #J #K #W #_ #H2 elim (discr_push_next … H2)
 134 ]
 135 qed-.
 136
 137 (* Basic_1: includes: drop_gen_drop *)
 138 (* Basic_2A1: includes: drop_inv_drop1_lt drop_inv_drop1 *)
 139 lemma drops_inv_drop1: ∀b,f,I,K,Y,V. ⬇*[b, ⫯f] K.ⓑ{I}V ≡ Y → ⬇*[b, f] K ≡ Y.
 140 /2 width=7 by drops_inv_drop1_aux/ qed-.
 141
 142 fact drops_inv_skip1_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → ∀g,I,K1,V1. X = K1.ⓑ{I}V1 → f = ↑g →
 143                           ∃∃K2,V2. ⬇*[b, g] K1 ≡ K2 & ⬆*[g] V2 ≡ V1 & Y = K2.ⓑ{I}V2.
 144 #b #f #X #Y * -f -X -Y
 145 [ #f #Hf #g #J #K1 #W1 #H destruct
 146 | #f #I #L1 #L2 #V #_ #g #J #K1 #W1 #_ #H2 elim (discr_next_push … H2)
 147 | #f #I #L1 #L2 #V1 #V2 #HL #HV #g #J #K1 #W1 #H1 #H2 <(injective_push … H2) -g destruct
 148   /2 width=5 by ex3_2_intro/
 149 ]
 150 qed-.
 151
 152 (* Basic_1: includes: drop_gen_skip_l *)
 153 (* Basic_2A1: includes: drop_inv_skip1 *)
 154 lemma drops_inv_skip1: ∀b,f,I,K1,V1,Y. ⬇*[b, ↑f] K1.ⓑ{I}V1 ≡ Y →
 155                        ∃∃K2,V2. ⬇*[b, f] K1 ≡ K2 & ⬆*[f] V2 ≡ V1 & Y = K2.ⓑ{I}V2.
 156 /2 width=5 by drops_inv_skip1_aux/ qed-.
 157
 158 fact drops_inv_skip2_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → ∀g,I,K2,V2. Y = K2.ⓑ{I}V2 → f = ↑g →
 159                           ∃∃K1,V1. ⬇*[b, g] K1 ≡ K2 & ⬆*[g] V2 ≡ V1 & X = K1.ⓑ{I}V1.
 160 #b #f #X #Y * -f -X -Y
 161 [ #f #Hf #g #J #K2 #W2 #H destruct
 162 | #f #I #L1 #L2 #V #_ #g #J #K2 #W2 #_ #H2 elim (discr_next_push … H2)
 163 | #f #I #L1 #L2 #V1 #V2 #HL #HV #g #J #K2 #W2 #H1 #H2 <(injective_push … H2) -g destruct
 164   /2 width=5 by ex3_2_intro/
 165 ]
 166 qed-.
 167
 168 (* Basic_1: includes: drop_gen_skip_r *)
 169 (* Basic_2A1: includes: drop_inv_skip2 *)
 170 lemma drops_inv_skip2: ∀b,f,I,X,K2,V2. ⬇*[b, ↑f] X ≡ K2.ⓑ{I}V2 →
 171                        ∃∃K1,V1. ⬇*[b, f] K1 ≡ K2 & ⬆*[f] V2 ≡ V1 & X = K1.ⓑ{I}V1.
 172 /2 width=5 by drops_inv_skip2_aux/ qed-.
 173
 174 (* Basic forward lemmas *****************************************************)
 175
 176 fact drops_fwd_drop2_aux: ∀b,f2,X,Y. ⬇*[b, f2] X ≡ Y → ∀I,K,V. Y = K.ⓑ{I}V →
 177                           ∃∃f1,f. 𝐈⦃f1⦄ & f2 ⊚ ⫯f1 ≡ f & ⬇*[b, f] X ≡ K.
 178 #b #f2 #X #Y #H elim H -f2 -X -Y
 179 [ #f2 #Hf2 #J #K #W #H destruct
 180 | #f2 #I #L1 #L2 #V #_ #IHL #J #K #W #H elim (IHL … H) -IHL
 181   /3 width=7 by after_next, ex3_2_intro, drops_drop/
 182 | #f2 #I #L1 #L2 #V1 #V2 #HL #_ #_ #J #K #W #H destruct
 183   lapply (after_isid_dx 𝐈𝐝 … f2) /3 width=9 by after_push, ex3_2_intro, drops_drop/
 184 ]
 185 qed-.
 186
 187 lemma drops_fwd_drop2: ∀b,f2,I,X,K,V. ⬇*[b, f2] X ≡ K.ⓑ{I}V →
 188                        ∃∃f1,f. 𝐈⦃f1⦄ & f2 ⊚ ⫯f1 ≡ f & ⬇*[b, f] X ≡ K.
 189 /2 width=5 by drops_fwd_drop2_aux/ qed-.
 190
 191 (* Properties with test for identity ****************************************)
 192
 193 (* Basic_2A1: includes: drop_refl *)
 194 lemma drops_refl: ∀b,L,f. 𝐈⦃f⦄ → ⬇*[b, f] L ≡ L.
 195 #b #L elim L -L /2 width=1 by drops_atom/
 196 #L #I #V #IHL #f #Hf elim (isid_inv_gen … Hf) -Hf
 197 /3 width=1 by drops_skip, lifts_refl/
 198 qed.
 199
 200 (* Forward lemmas test for identity *****************************************)
 201
 202 (* Basic_1: includes: drop_gen_refl *)
 203 (* Basic_2A1: includes: drop_inv_O2 *)
 204 lemma drops_fwd_isid: ∀b,f,L1,L2. ⬇*[b, f] L1 ≡ L2 → 𝐈⦃f⦄ → L1 = L2.
 205 #b #f #L1 #L2 #H elim H -f -L1 -L2 //
 206 [ #f #I #L1 #L2 #V #_ #_ #H elim (isid_inv_next … H) //
 207 | /5 width=5 by isid_inv_push, lifts_fwd_isid, eq_f3, sym_eq/
 208 ]
 209 qed-.
 210
 211
 212 lemma drops_after_fwd_drop2: ∀b,f2,I,X,K,V. ⬇*[b, f2] X ≡ K.ⓑ{I}V →
 213                              ∀f1,f. 𝐈⦃f1⦄ → f2 ⊚ ⫯f1 ≡ f → ⬇*[b, f] X ≡ K.
 214 #b #f2 #I #X #K #V #H #f1 #f #Hf1 #Hf elim (drops_fwd_drop2 … H) -H
 215 #g1 #g #Hg1 #Hg #HK lapply (after_mono_eq … Hg … Hf ??) -Hg -Hf
 216 /3 width=5 by drops_eq_repl_back, isid_inv_eq_repl, eq_next/
 217 qed-.
 218
 219 (* Forward lemmas with test for finite colength *****************************)
 220
 221 lemma drops_fwd_isfin: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → 𝐅⦃f⦄.
 222 #f #L1 #L2 #H elim H -f -L1 -L2
 223 /3 width=1 by isfin_next, isfin_push, isfin_isid/
 224 qed-.
 225
 226 (* Properties with test for uniformity **************************************)
 227
 228 lemma drops_isuni_ex: ∀f. 𝐔⦃f⦄ → ∀L. ∃K. ⬇*[Ⓕ, f] L ≡ K.
 229 #f #H elim H -f /4 width=2 by drops_refl, drops_TF, ex_intro/
 230 #f #_ #g #H #IH * /2 width=2 by ex_intro/
 231 #L #I #V destruct
 232 elim (IH L) -IH /3 width=2 by drops_drop, ex_intro/
 233 qed-.
 234
 235 (* Inversion lemmas with test for uniformity ********************************)
 236
 237 lemma drops_inv_isuni: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → 𝐔⦃f⦄ →
 238                        (𝐈⦃f⦄ ∧ L1 = L2) ∨
 239                        ∃∃g,I,K,V. ⬇*[Ⓣ, g] K ≡ L2 & 𝐔⦃g⦄ & L1 = K.ⓑ{I}V & f = ⫯g.
 240 #f #L1 #L2 * -f -L1 -L2
 241 [ /4 width=1 by or_introl, conj/
 242 | /4 width=8 by isuni_inv_next, ex4_4_intro, or_intror/
 243 | /7 width=6 by drops_fwd_isid, lifts_fwd_isid, isuni_inv_push, isid_push, or_introl, conj, eq_f3, sym_eq/
 244 ]
 245 qed-.
 246
 247 (* Basic_2A1: was: drop_inv_O1_pair1 *)
 248 lemma drops_inv_pair1_isuni: ∀b,f,I,K,L2,V. 𝐔⦃f⦄ → ⬇*[b, f] K.ⓑ{I}V ≡ L2 →
 249                              (𝐈⦃f⦄ ∧ L2 = K.ⓑ{I}V) ∨
 250                              ∃∃g. 𝐔⦃g⦄ & ⬇*[b, g] K ≡ L2 & f = ⫯g.
 251 #b #f #I #K #L2 #V #Hf #H elim (isuni_split … Hf) -Hf * #g #Hg #H0 destruct
 252 [ lapply (drops_inv_skip1 … H) -H * #Y #X #HY #HX #H destruct
 253   <(drops_fwd_isid … HY Hg) -Y >(lifts_fwd_isid … HX Hg) -X
 254   /4 width=3 by isid_push, or_introl, conj/
 255 | lapply (drops_inv_drop1 … H) -H /3 width=4 by ex3_intro, or_intror/
 256 ]
 257 qed-.
 258
 259 (* Basic_2A1: was: drop_inv_O1_pair2 *)
 260 lemma drops_inv_pair2_isuni: ∀b,f,I,K,V,L1. 𝐔⦃f⦄ → ⬇*[b, f] L1 ≡ K.ⓑ{I}V →
 261                              (𝐈⦃f⦄ ∧ L1 = K.ⓑ{I}V) ∨
 262                              ∃∃g,I1,K1,V1. 𝐔⦃g⦄ & ⬇*[b, g] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1 & f = ⫯g.
 263 #b #f #I #K #V *
 264 [ #Hf #H elim (drops_inv_atom1 … H) -H #H destruct
 265 | #L1 #I1 #V1 #Hf #H elim (drops_inv_pair1_isuni … Hf H) -Hf -H *
 266   [ #Hf #H destruct /3 width=1 by or_introl, conj/
 267   | /3 width=8 by ex4_4_intro, or_intror/
 268   ]
 269 ]
 270 qed-.
 271
 272 lemma drops_inv_pair2_isuni_next: ∀b,f,I,K,V,L1. 𝐔⦃f⦄ → ⬇*[b, ⫯f] L1 ≡ K.ⓑ{I}V →
 273                                   ∃∃I1,K1,V1. ⬇*[b, f] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1.
 274 #b #f #I #K #V #L1 #Hf #H elim (drops_inv_pair2_isuni … H) -H /2 width=3 by isuni_next/ -Hf *
 275 [ #H elim (isid_inv_next … H) -H //
 276 | /2 width=5 by ex2_3_intro/
 277 ]
 278 qed-.
 279
 280 fact drops_inv_TF_aux: ∀f,L1,L2. ⬇*[Ⓕ, f] L1 ≡ L2 → 𝐔⦃f⦄ →
 281                        ∀I,K,V. L2 = K.ⓑ{I}V →
 282                        ⬇*[Ⓣ, f] L1 ≡ K.ⓑ{I}V.
 283 #f #L1 #L2 #H elim H -f -L1 -L2
 284 [ #f #_ #_ #J #K #W #H destruct
 285 | #f #I #L1 #L2 #V #_ #IH #Hf #J #K #W #H destruct
 286   /4 width=3 by drops_drop, isuni_inv_next/
 287 | #f #I #L1 #L2 #V1 #V2 #HL12 #HV21 #_ #Hf #J #K #W #H destruct
 288   lapply (isuni_inv_push … Hf ??) -Hf [1,2: // ] #Hf
 289   <(drops_fwd_isid … HL12) -K // <(lifts_fwd_isid … HV21) -V1
 290   /3 width=3 by drops_refl, isid_push/
 291 ]
 292 qed-.
 293
 294 (* Basic_2A1: includes: drop_inv_FT *)
 295 lemma drops_inv_TF: ∀f,I,L,K,V. ⬇*[Ⓕ, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 296                     ⬇*[Ⓣ, f] L ≡ K.ⓑ{I}V.
 297 /2 width=3 by drops_inv_TF_aux/ qed-.
 298
 299 (* Basic_2A1: includes: drop_inv_gen *)
 300 lemma drops_inv_gen: ∀b,f,I,L,K,V. ⬇*[b, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 301                      ⬇*[Ⓣ, f] L ≡ K.ⓑ{I}V.
 302 * /2 width=1 by drops_inv_TF/
 303 qed-.
 304
 305 (* Basic_2A1: includes: drop_inv_T *)
 306 lemma drops_inv_F: ∀b,f,I,L,K,V. ⬇*[Ⓕ, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 307                    ⬇*[b, f] L ≡ K.ⓑ{I}V.
 308 * /2 width=1 by drops_inv_TF/
 309 qed-.
 310
 311 (* Forward lemmas with test for uniformity **********************************)
 312
 313 (* Basic_1: was: drop_S *)
 314 (* Basic_2A1: was: drop_fwd_drop2 *)
 315 lemma drops_isuni_fwd_drop2: ∀b,f,I,X,K,V. 𝐔⦃f⦄ → ⬇*[b, f] X ≡ K.ⓑ{I}V → ⬇*[b, ⫯f] X ≡ K.
 316 /3 width=7 by drops_after_fwd_drop2, after_isid_isuni/ qed-.
 317
 318 (* Inversion lemmas with uniform relocations ********************************)
 319
 320 lemma drops_inv_atom2: ∀b,L,f. ⬇*[b, f] L ≡ ⋆ →
 321                        ∃∃n,f1. ⬇*[b, 𝐔❴n❵] L ≡ ⋆ & 𝐔❴n❵ ⊚ f1 ≡ f.
 322 #b #L elim L -L
 323 [ /3 width=4 by drops_atom, after_isid_sn, ex2_2_intro/
 324 | #L #I #V #IH #f #H elim (pn_split f) * #g #H0 destruct
 325   [ elim (drops_inv_skip1 … H) -H #K #W #_ #_ #H destruct
 326   | lapply (drops_inv_drop1 … H) -H #HL
 327     elim (IH … HL) -IH -HL /3 width=8 by drops_drop, after_next, ex2_2_intro/
 328   ]
 329 ]
 330 qed-.
 331
 332 lemma drops_inv_succ: ∀l,L1,L2. ⬇*[⫯l] L1 ≡ L2 →
 333                       ∃∃I,K,V. ⬇*[l] K ≡ L2 & L1 = K.ⓑ{I}V.
 334 #l #L1 #L2 #H elim (drops_inv_isuni … H) -H // *
 335 [ #H elim (isid_inv_next … H) -H //
 336 | /2 width=5 by ex2_3_intro/
 337 ]
 338 qed-.
 339
 340 (* Properties with uniform relocations **************************************)
 341
 342 lemma drops_F_uni: ∀L,i. ⬇*[Ⓕ, 𝐔❴i❵] L ≡ ⋆ ∨ ∃∃I,K,V. ⬇*[i] L ≡ K.ⓑ{I}V.
 343 #L elim L -L /2 width=1 by or_introl/
 344 #L #I #V #IH * /4 width=4 by drops_refl, ex1_3_intro, or_intror/
 345 #i elim (IH i) -IH /3 width=1 by drops_drop, or_introl/
 346 * /4 width=4 by drops_drop, ex1_3_intro, or_intror/
 347 qed-.
 348
 349 (* Basic_2A1: includes: drop_split *)
 350 lemma drops_split_trans: ∀b,f,L1,L2. ⬇*[b, f] L1 ≡ L2 → ∀f1,f2. f1 ⊚ f2 ≡ f → 𝐔⦃f1⦄ →
 351                          ∃∃L. ⬇*[b, f1] L1 ≡ L & ⬇*[b, f2] L ≡ L2.
 352 #b #f #L1 #L2 #H elim H -f -L1 -L2
 353 [ #f #H0f #f1 #f2 #Hf #Hf1 @(ex2_intro … (⋆)) @drops_atom
 354   #H lapply (H0f H) -b
 355   #H elim (after_inv_isid3 … Hf H) -f //
 356 | #f #I #L1 #L2 #V #HL12 #IHL12 #f1 #f2 #Hf #Hf1 elim (after_inv_xxn … Hf) -Hf [1,3: * |*: // ]
 357   [ #g1 #g2 #Hf #H1 #H2 destruct
 358     lapply (isuni_inv_push … Hf1 ??) -Hf1 [1,2: // ] #Hg1
 359     elim (IHL12 … Hf) -f
 360     /4 width=5 by drops_drop, drops_skip, lifts_refl, isuni_isid, ex2_intro/
 361   | #g1 #Hf #H destruct elim (IHL12 … Hf) -f
 362     /3 width=5 by ex2_intro, drops_drop, isuni_inv_next/
 363   ]
 364 | #f #I #L1 #L2 #V1 #V2 #_ #HV21 #IHL12 #f1 #f2 #Hf #Hf1 elim (after_inv_xxp … Hf) -Hf [2,3: // ]
 365   #g1 #g2 #Hf #H1 #H2 destruct elim (lifts_split_trans … HV21 … Hf) -HV21
 366   elim (IHL12 … Hf) -f /3 width=5 by ex2_intro, drops_skip, isuni_fwd_push/
 367 ]
 368 qed-.
 369
 370 lemma drops_split_div: ∀b,f1,L1,L. ⬇*[b, f1] L1 ≡ L → ∀f2,f. f1 ⊚ f2 ≡ f → 𝐔⦃f2⦄ →
 371                        ∃∃L2. ⬇*[Ⓕ, f2] L ≡ L2 & ⬇*[Ⓕ, f] L1 ≡ L2.
 372 #b #f1 #L1 #L #H elim H -f1 -L1 -L
 373 [ #f1 #Hf1 #f2 #f #Hf #Hf2 @(ex2_intro … (⋆)) @drops_atom #H destruct
 374 | #f1 #I #L1 #L #V #HL1 #IH #f2 #f #Hf #Hf2 elim (after_inv_nxx … Hf) -Hf [2,3: // ]
 375   #g #Hg #H destruct elim (IH … Hg) -IH -Hg /3 width=5 by drops_drop, ex2_intro/
 376 | #f1 #I #L1 #L #V1 #V #HL1 #HV1 #IH #f2 #f #Hf #Hf2
 377   elim (after_inv_pxx … Hf) -Hf [1,3: * |*: // ]
 378   #g2 #g #Hg #H2 #H0 destruct
 379   [ lapply (isuni_inv_push … Hf2 ??) -Hf2 [1,2: // ] #Hg2 -IH
 380     lapply (after_isid_inv_dx … Hg … Hg2) -Hg #Hg
 381     /5 width=7 by drops_eq_repl_back, drops_F, drops_refl, drops_skip, lifts_eq_repl_back, isid_push, ex2_intro/
 382   | lapply (isuni_inv_next … Hf2 ??) -Hf2 [1,2: // ] #Hg2 -HL1 -HV1
 383     elim (IH … Hg) -f1 /3 width=3 by drops_drop, ex2_intro/
 384   ]
 385 ]
 386 qed-.
 387
 388 (* Properties with application **********************************************)
 389
 390 lemma drops_tls_at: ∀f,i1,i2. @⦃i1,f⦄ ≡ i2 →
 391                     ∀b,L1,L2. ⬇*[b,⫱*[i2]f] L1 ≡ L2 →
 392                     ⬇*[b,↑⫱*[⫯i2]f] L1 ≡ L2.
 393 /3 width=3 by drops_eq_repl_fwd, at_inv_tls/ qed-.
 394
 395 lemma drops_split_trans_pair2: ∀b,f,I,L,K0,V. ⬇*[b, f] L ≡ K0.ⓑ{I}V → ∀n. @⦃O, f⦄ ≡ n →
 396                                ∃∃K,W. ⬇*[n]L ≡ K.ⓑ{I}W & ⬇*[b, ⫱*[⫯n]f] K ≡ K0 & ⬆*[⫱*[⫯n]f] V ≡ W.
 397 #b #f #I #L #K0 #V #H #n #Hf
 398 elim (drops_split_trans … H) -H [ |5: @(after_uni_dx … Hf) |2,3: skip ] /2 width=1 by after_isid_dx/ #Y #HLY #H
 399 lapply (drops_tls_at … Hf … H) -H #H
 400 elim (drops_inv_skip2 … H) -H #K #W #HK0 #HVW #H destruct
 401 /3 width=5 by drops_inv_gen, ex3_2_intro/
 402 qed-.
 403
 404 (* Basic_2A1: removed theorems 12:
 405               drops_inv_nil drops_inv_cons d1_liftable_liftables
 406               drop_refl_atom_O2 drop_inv_pair1
 407               drop_inv_Y1 drop_Y1 drop_O_Y drop_fwd_Y2
 408               drop_fwd_length_minus2 drop_fwd_length_minus4
 409 *)
 410 (* Basic_1: removed theorems 53:
 411             drop1_gen_pnil drop1_gen_pcons drop1_getl_trans
 412             drop_ctail drop_skip_flat
 413             cimp_flat_sx cimp_flat_dx cimp_bind cimp_getl_conf
 414             drop_clear drop_clear_O drop_clear_S
 415             clear_gen_sort clear_gen_bind clear_gen_flat clear_gen_flat_r
 416             clear_gen_all clear_clear clear_mono clear_trans clear_ctail clear_cle
 417             getl_ctail_clen getl_gen_tail clear_getl_trans getl_clear_trans
 418             getl_clear_bind getl_clear_conf getl_dec getl_drop getl_drop_conf_lt
 419             getl_drop_conf_ge getl_conf_ge_drop getl_drop_conf_rev
 420             drop_getl_trans_lt drop_getl_trans_le drop_getl_trans_ge
 421             getl_drop_trans getl_flt getl_gen_all getl_gen_sort getl_gen_O
 422             getl_gen_S getl_gen_2 getl_gen_flat getl_gen_bind getl_conf_le
 423             getl_trans getl_refl getl_head getl_flat getl_ctail getl_mono
 424 *)