matita/matita/contribs/lambdadelta/basic_2/relocation/drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_coafter.ma".
  16 include "basic_2/notation/relations/rdropstar_3.ma".
  17 include "basic_2/notation/relations/rdropstar_4.ma".
  18 include "basic_2/relocation/lreq.ma".
  19 include "basic_2/relocation/lifts.ma".
  20
  21 (* GENERIC SLICING FOR LOCAL ENVIRONMENTS ***********************************)
  22
  23 (* Basic_1: includes: drop_skip_bind drop1_skip_bind *)
  24 (* Basic_2A1: includes: drop_atom drop_pair drop_drop drop_skip
  25                         drop_refl_atom_O2 drop_drop_lt drop_skip_lt
  26 *)
  27 inductive drops (b:bool): rtmap → relation lenv ≝
  28 | drops_atom: ∀f. (b = Ⓣ → 𝐈⦃f⦄) → drops b (f) (⋆) (⋆)
  29 | drops_drop: ∀f,I,L1,L2,V. drops b f L1 L2 → drops b (⫯f) (L1.ⓑ{I}V) L2
  30 | drops_skip: ∀f,I,L1,L2,V1,V2.
  31               drops b f L1 L2 → ⬆*[f] V2 ≡ V1 →
  32               drops b (↑f) (L1.ⓑ{I}V1) (L2.ⓑ{I}V2)
  33 .
  34
  35 interpretation "uniform slicing (local environment)"
  36    'RDropStar i L1 L2 = (drops true (uni i) L1 L2).
  37
  38 interpretation "generic slicing (local environment)"
  39    'RDropStar b f L1 L2 = (drops b f L1 L2).
  40
  41 definition d_liftable1: relation2 lenv term → predicate bool ≝
  42                         λR,b. ∀f,L,K. ⬇*[b, f] L ≡ K →
  43                         ∀T,U. ⬆*[f] T ≡ U → R K T → R L U.
  44
  45 definition d_liftable2: predicate (lenv → relation term) ≝
  46                         λR. ∀K,T1,T2. R K T1 T2 → ∀b,f,L. ⬇*[b, f] L ≡ K →
  47                         ∀U1. ⬆*[f] T1 ≡ U1 →
  48                         ∃∃U2. ⬆*[f] T2 ≡ U2 & R L U1 U2.
  49
  50 definition d_deliftable2_sn: predicate (lenv → relation term) ≝
  51                              λR. ∀L,U1,U2. R L U1 U2 → ∀b,f,K. ⬇*[b, f] L ≡ K →
  52                              ∀T1. ⬆*[f] T1 ≡ U1 →
  53                              ∃∃T2. ⬆*[f] T2 ≡ U2 & R K T1 T2.
  54
  55 definition dropable_sn: predicate (rtmap → relation lenv) ≝
  56                         λR. ∀b,f,L1,K1. ⬇*[b, f] L1 ≡ K1 → ∀f2,L2. R f2 L1 L2 →
  57                         ∀f1. f ~⊚ f1 ≡ f2 →
  58                         ∃∃K2. R f1 K1 K2 & ⬇*[b, f] L2 ≡ K2.
  59
  60 definition dropable_dx: predicate (rtmap → relation lenv) ≝
  61                         λR. ∀f2,L1,L2. R f2 L1 L2 →
  62                         ∀b,f,K2. ⬇*[b, f] L2 ≡ K2 →  𝐔⦃f⦄ →
  63                         ∀f1. f ~⊚ f1 ≡ f2 →
  64                         ∃∃K1. ⬇*[b, f] L1 ≡ K1 & R f1 K1 K2.
  65
  66 definition dedropable_sn: predicate (rtmap → relation lenv) ≝
  67                           λR. ∀b,f,L1,K1. ⬇*[b, f] L1 ≡ K1 → ∀f1,K2. R f1 K1 K2 →
  68                           ∀f2. f ~⊚ f1 ≡ f2 →
  69                           ∃∃L2. R f2 L1 L2 & ⬇*[b, f] L2 ≡ K2 & L1 ≡[f] L2.
  70
  71 (* Basic properties *********************************************************)
  72
  73 lemma drops_atom_F: ∀f. ⬇*[Ⓕ, f] ⋆ ≡ ⋆.
  74 #f @drops_atom #H destruct
  75 qed.
  76
  77 lemma drops_eq_repl_back: ∀b,L1,L2. eq_repl_back … (λf. ⬇*[b, f] L1 ≡ L2).
  78 #b #L1 #L2 #f1 #H elim H -f1 -L1 -L2
  79 [ /4 width=3 by drops_atom, isid_eq_repl_back/
  80 | #f1 #I #L1 #L2 #V #_ #IH #f2 #H elim (eq_inv_nx … H) -H
  81   /3 width=3 by drops_drop/
  82 | #f1 #I #L1 #L2 #V1 #v2 #_ #HV #IH #f2 #H elim (eq_inv_px … H) -H
  83   /3 width=3 by drops_skip, lifts_eq_repl_back/
  84 ]
  85 qed-.
  86
  87 lemma drops_eq_repl_fwd: ∀b,L1,L2. eq_repl_fwd … (λf. ⬇*[b, f] L1 ≡ L2).
  88 #b #L1 #L2 @eq_repl_sym /2 width=3 by drops_eq_repl_back/ (**) (* full auto fails *)
  89 qed-.
  90
  91 (* Basic_2A1: includes: drop_FT *)
  92 lemma drops_TF: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → ⬇*[Ⓕ, f] L1 ≡ L2.
  93 #f #L1 #L2 #H elim H -f -L1 -L2
  94 /3 width=1 by drops_atom, drops_drop, drops_skip/
  95 qed.
  96
  97 (* Basic_2A1: includes: drop_gen *)
  98 lemma drops_gen: ∀b,f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → ⬇*[b, f] L1 ≡ L2.
  99 * /2 width=1 by drops_TF/
 100 qed-.
 101
 102 (* Basic_2A1: includes: drop_T *)
 103 lemma drops_F: ∀b,f,L1,L2. ⬇*[b, f] L1 ≡ L2 → ⬇*[Ⓕ, f] L1 ≡ L2.
 104 * /2 width=1 by drops_TF/
 105 qed-.
 106
 107 (* Basic inversion lemmas ***************************************************)
 108
 109 fact drops_inv_atom1_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → X = ⋆ →
 110                           Y = ⋆ ∧ (b = Ⓣ → 𝐈⦃f⦄).
 111 #b #f #X #Y * -f -X -Y
 112 [ /3 width=1 by conj/
 113 | #f #I #L1 #L2 #V #_ #H destruct
 114 | #f #I #L1 #L2 #V1 #V2 #_ #_ #H destruct
 115 ]
 116 qed-.
 117
 118 (* Basic_1: includes: drop_gen_sort *)
 119 (* Basic_2A1: includes: drop_inv_atom1 *)
 120 lemma drops_inv_atom1: ∀b,f,Y. ⬇*[b, f] ⋆ ≡ Y → Y = ⋆ ∧ (b = Ⓣ → 𝐈⦃f⦄).
 121 /2 width=3 by drops_inv_atom1_aux/ qed-.
 122
 123 fact drops_inv_drop1_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → ∀g,I,K,V. X = K.ⓑ{I}V → f = ⫯g →
 124                           ⬇*[b, g] K ≡ Y.
 125 #b #f #X #Y * -f -X -Y
 126 [ #f #Hf #g #J #K #W #H destruct
 127 | #f #I #L1 #L2 #V #HL #g #J #K #W #H1 #H2 <(injective_next … H2) -g destruct //
 128 | #f #I #L1 #L2 #V1 #V2 #_ #_ #g #J #K #W #_ #H2 elim (discr_push_next … H2)
 129 ]
 130 qed-.
 131
 132 (* Basic_1: includes: drop_gen_drop *)
 133 (* Basic_2A1: includes: drop_inv_drop1_lt drop_inv_drop1 *)
 134 lemma drops_inv_drop1: ∀b,f,I,K,Y,V. ⬇*[b, ⫯f] K.ⓑ{I}V ≡ Y → ⬇*[b, f] K ≡ Y.
 135 /2 width=7 by drops_inv_drop1_aux/ qed-.
 136
 137 fact drops_inv_skip1_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → ∀g,I,K1,V1. X = K1.ⓑ{I}V1 → f = ↑g →
 138                           ∃∃K2,V2. ⬇*[b, g] K1 ≡ K2 & ⬆*[g] V2 ≡ V1 & Y = K2.ⓑ{I}V2.
 139 #b #f #X #Y * -f -X -Y
 140 [ #f #Hf #g #J #K1 #W1 #H destruct
 141 | #f #I #L1 #L2 #V #_ #g #J #K1 #W1 #_ #H2 elim (discr_next_push … H2)
 142 | #f #I #L1 #L2 #V1 #V2 #HL #HV #g #J #K1 #W1 #H1 #H2 <(injective_push … H2) -g destruct
 143   /2 width=5 by ex3_2_intro/
 144 ]
 145 qed-.
 146
 147 (* Basic_1: includes: drop_gen_skip_l *)
 148 (* Basic_2A1: includes: drop_inv_skip1 *)
 149 lemma drops_inv_skip1: ∀b,f,I,K1,V1,Y. ⬇*[b, ↑f] K1.ⓑ{I}V1 ≡ Y →
 150                        ∃∃K2,V2. ⬇*[b, f] K1 ≡ K2 & ⬆*[f] V2 ≡ V1 & Y = K2.ⓑ{I}V2.
 151 /2 width=5 by drops_inv_skip1_aux/ qed-.
 152
 153 fact drops_inv_skip2_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → ∀g,I,K2,V2. Y = K2.ⓑ{I}V2 → f = ↑g →
 154                           ∃∃K1,V1. ⬇*[b, g] K1 ≡ K2 & ⬆*[g] V2 ≡ V1 & X = K1.ⓑ{I}V1.
 155 #b #f #X #Y * -f -X -Y
 156 [ #f #Hf #g #J #K2 #W2 #H destruct
 157 | #f #I #L1 #L2 #V #_ #g #J #K2 #W2 #_ #H2 elim (discr_next_push … H2)
 158 | #f #I #L1 #L2 #V1 #V2 #HL #HV #g #J #K2 #W2 #H1 #H2 <(injective_push … H2) -g destruct
 159   /2 width=5 by ex3_2_intro/
 160 ]
 161 qed-.
 162
 163 (* Basic_1: includes: drop_gen_skip_r *)
 164 (* Basic_2A1: includes: drop_inv_skip2 *)
 165 lemma drops_inv_skip2: ∀b,f,I,X,K2,V2. ⬇*[b, ↑f] X ≡ K2.ⓑ{I}V2 →
 166                        ∃∃K1,V1. ⬇*[b, f] K1 ≡ K2 & ⬆*[f] V2 ≡ V1 & X = K1.ⓑ{I}V1.
 167 /2 width=5 by drops_inv_skip2_aux/ qed-.
 168
 169 (* Basic forward lemmas *****************************************************)
 170
 171 fact drops_fwd_drop2_aux: ∀b,f2,X,Y. ⬇*[b, f2] X ≡ Y → ∀I,K,V. Y = K.ⓑ{I}V →
 172                           ∃∃f1,f. 𝐈⦃f1⦄ & f2 ⊚ ⫯f1 ≡ f & ⬇*[b, f] X ≡ K.
 173 #b #f2 #X #Y #H elim H -f2 -X -Y
 174 [ #f2 #Hf2 #J #K #W #H destruct
 175 | #f2 #I #L1 #L2 #V #_ #IHL #J #K #W #H elim (IHL … H) -IHL
 176   /3 width=7 by after_next, ex3_2_intro, drops_drop/
 177 | #f2 #I #L1 #L2 #V1 #V2 #HL #_ #_ #J #K #W #H destruct
 178   lapply (after_isid_dx 𝐈𝐝 … f2) /3 width=9 by after_push, ex3_2_intro, drops_drop/
 179 ]
 180 qed-.
 181
 182 lemma drops_fwd_drop2: ∀b,f2,I,X,K,V. ⬇*[b, f2] X ≡ K.ⓑ{I}V →
 183                        ∃∃f1,f. 𝐈⦃f1⦄ & f2 ⊚ ⫯f1 ≡ f & ⬇*[b, f] X ≡ K.
 184 /2 width=5 by drops_fwd_drop2_aux/ qed-.
 185
 186 (* Properties with test for identity ****************************************)
 187
 188 (* Basic_2A1: includes: drop_refl *)
 189 lemma drops_refl: ∀b,L,f. 𝐈⦃f⦄ → ⬇*[b, f] L ≡ L.
 190 #b #L elim L -L /2 width=1 by drops_atom/
 191 #L #I #V #IHL #f #Hf elim (isid_inv_gen … Hf) -Hf
 192 /3 width=1 by drops_skip, lifts_refl/
 193 qed.
 194
 195 (* Forward lemmas test for identity *****************************************)
 196
 197 (* Basic_1: includes: drop_gen_refl *)
 198 (* Basic_2A1: includes: drop_inv_O2 *)
 199 lemma drops_fwd_isid: ∀b,f,L1,L2. ⬇*[b, f] L1 ≡ L2 → 𝐈⦃f⦄ → L1 = L2.
 200 #b #f #L1 #L2 #H elim H -f -L1 -L2 //
 201 [ #f #I #L1 #L2 #V #_ #_ #H elim (isid_inv_next … H) //
 202 | /5 width=5 by isid_inv_push, lifts_fwd_isid, eq_f3, sym_eq/
 203 ]
 204 qed-.
 205
 206
 207 lemma drops_after_fwd_drop2: ∀b,f2,I,X,K,V. ⬇*[b, f2] X ≡ K.ⓑ{I}V →
 208                              ∀f1,f. 𝐈⦃f1⦄ → f2 ⊚ ⫯f1 ≡ f → ⬇*[b, f] X ≡ K.
 209 #b #f2 #I #X #K #V #H #f1 #f #Hf1 #Hf elim (drops_fwd_drop2 … H) -H
 210 #g1 #g #Hg1 #Hg #HK lapply (after_mono_eq … Hg … Hf ??) -Hg -Hf
 211 /3 width=5 by drops_eq_repl_back, isid_inv_eq_repl, eq_next/
 212 qed-.
 213
 214 (* Forward lemmas with test for finite colength *****************************)
 215
 216 lemma drops_fwd_isfin: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → 𝐅⦃f⦄.
 217 #f #L1 #L2 #H elim H -f -L1 -L2
 218 /3 width=1 by isfin_next, isfin_push, isfin_isid/
 219 qed-.
 220
 221 (* Properties with uniform relocations **************************************)
 222
 223 lemma drops_uni_ex: ∀L,i. ⬇*[Ⓕ, 𝐔❴i❵] L ≡ ⋆ ∨ ∃∃I,K,V. ⬇*[i] L ≡ K.ⓑ{I}V.
 224 #L elim L -L /2 width=1 by or_introl/
 225 #L #I #V #IH * /4 width=4 by drops_refl, ex1_3_intro, or_intror/
 226 #i elim (IH i) -IH /3 width=1 by drops_drop, or_introl/
 227 * /4 width=4 by drops_drop, ex1_3_intro, or_intror/
 228 qed-.
 229
 230 (* Basic_2A1: includes: drop_split *)
 231 lemma drops_split_trans: ∀b,f,L1,L2. ⬇*[b, f] L1 ≡ L2 → ∀f1,f2. f1 ⊚ f2 ≡ f → 𝐔⦃f1⦄ →
 232                          ∃∃L. ⬇*[b, f1] L1 ≡ L & ⬇*[b, f2] L ≡ L2.
 233 #b #f #L1 #L2 #H elim H -f -L1 -L2
 234 [ #f #H0f #f1 #f2 #Hf #Hf1 @(ex2_intro … (⋆)) @drops_atom
 235   #H lapply (H0f H) -b
 236   #H elim (after_inv_isid3 … Hf H) -f //
 237 | #f #I #L1 #L2 #V #HL12 #IHL12 #f1 #f2 #Hf #Hf1 elim (after_inv_xxn … Hf) -Hf [1,3: * |*: // ]
 238   [ #g1 #g2 #Hf #H1 #H2 destruct
 239     lapply (isuni_inv_push … Hf1 ??) -Hf1 [1,2: // ] #Hg1
 240     elim (IHL12 … Hf) -f
 241     /4 width=5 by drops_drop, drops_skip, lifts_refl, isuni_isid, ex2_intro/
 242   | #g1 #Hf #H destruct elim (IHL12 … Hf) -f
 243     /3 width=5 by ex2_intro, drops_drop, isuni_inv_next/
 244   ]
 245 | #f #I #L1 #L2 #V1 #V2 #_ #HV21 #IHL12 #f1 #f2 #Hf #Hf1 elim (after_inv_xxp … Hf) -Hf [2,3: // ]
 246   #g1 #g2 #Hf #H1 #H2 destruct elim (lifts_split_trans … HV21 … Hf) -HV21
 247   elim (IHL12 … Hf) -f /3 width=5 by ex2_intro, drops_skip, isuni_fwd_push/
 248 ]
 249 qed-.
 250
 251 lemma drops_split_div: ∀b,f1,L1,L. ⬇*[b, f1] L1 ≡ L → ∀f2,f. f1 ⊚ f2 ≡ f → 𝐔⦃f2⦄ →
 252                        ∃∃L2. ⬇*[Ⓕ, f2] L ≡ L2 & ⬇*[Ⓕ, f] L1 ≡ L2.
 253 #b #f1 #L1 #L #H elim H -f1 -L1 -L
 254 [ #f1 #Hf1 #f2 #f #Hf #Hf2 @(ex2_intro … (⋆)) @drops_atom #H destruct
 255 | #f1 #I #L1 #L #V #HL1 #IH #f2 #f #Hf #Hf2 elim (after_inv_nxx … Hf) -Hf [2,3: // ]
 256   #g #Hg #H destruct elim (IH … Hg) -IH -Hg /3 width=5 by drops_drop, ex2_intro/
 257 | #f1 #I #L1 #L #V1 #V #HL1 #HV1 #IH #f2 #f #Hf #Hf2
 258   elim (after_inv_pxx … Hf) -Hf [1,3: * |*: // ]
 259   #g2 #g #Hg #H2 #H0 destruct
 260   [ lapply (isuni_inv_push … Hf2 ??) -Hf2 [1,2: // ] #Hg2 -IH
 261     lapply (after_isid_inv_dx … Hg … Hg2) -Hg #Hg
 262     /5 width=7 by drops_eq_repl_back, drops_F, drops_refl, drops_skip, lifts_eq_repl_back, isid_push, ex2_intro/
 263   | lapply (isuni_inv_next … Hf2 ??) -Hf2 [1,2: // ] #Hg2 -HL1 -HV1
 264     elim (IH … Hg) -f1 /3 width=3 by drops_drop, ex2_intro/
 265   ]
 266 ]
 267 qed-.
 268
 269 (* Inversion lemmas with test for uniformity ********************************)
 270
 271 lemma drops_inv_isuni: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → 𝐔⦃f⦄ →
 272                        (𝐈⦃f⦄ ∧ L1 = L2) ∨
 273                        ∃∃g,I,K,V. ⬇*[Ⓣ, g] K ≡ L2 & 𝐔⦃g⦄ & L1 = K.ⓑ{I}V & f = ⫯g.
 274 #f #L1 #L2 * -f -L1 -L2
 275 [ /4 width=1 by or_introl, conj/
 276 | /4 width=8 by isuni_inv_next, ex4_4_intro, or_intror/
 277 | /7 width=6 by drops_fwd_isid, lifts_fwd_isid, isuni_inv_push, isid_push, or_introl, conj, eq_f3, sym_eq/
 278 ]
 279 qed-.
 280
 281 (* Basic_2A1: was: drop_inv_O1_pair1 *)
 282 lemma drops_inv_pair1_isuni: ∀b,f,I,K,L2,V. 𝐔⦃f⦄ → ⬇*[b, f] K.ⓑ{I}V ≡ L2 →
 283                              (𝐈⦃f⦄ ∧ L2 = K.ⓑ{I}V) ∨
 284                              ∃∃g. 𝐔⦃g⦄ & ⬇*[b, g] K ≡ L2 & f = ⫯g.
 285 #b #f #I #K #L2 #V #Hf #H elim (isuni_split … Hf) -Hf * #g #Hg #H0 destruct
 286 [ lapply (drops_inv_skip1 … H) -H * #Y #X #HY #HX #H destruct
 287   <(drops_fwd_isid … HY Hg) -Y >(lifts_fwd_isid … HX Hg) -X
 288   /4 width=3 by isid_push, or_introl, conj/
 289 | lapply (drops_inv_drop1 … H) -H /3 width=4 by ex3_intro, or_intror/
 290 ]
 291 qed-.
 292
 293 (* Basic_2A1: was: drop_inv_O1_pair2 *)
 294 lemma drops_inv_pair2_isuni: ∀b,f,I,K,V,L1. 𝐔⦃f⦄ → ⬇*[b, f] L1 ≡ K.ⓑ{I}V →
 295                              (𝐈⦃f⦄ ∧ L1 = K.ⓑ{I}V) ∨
 296                              ∃∃g,I1,K1,V1. 𝐔⦃g⦄ & ⬇*[b, g] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1 & f = ⫯g.
 297 #b #f #I #K #V *
 298 [ #Hf #H elim (drops_inv_atom1 … H) -H #H destruct
 299 | #L1 #I1 #V1 #Hf #H elim (drops_inv_pair1_isuni … Hf H) -Hf -H *
 300   [ #Hf #H destruct /3 width=1 by or_introl, conj/
 301   | /3 width=8 by ex4_4_intro, or_intror/
 302   ]
 303 ]
 304 qed-.
 305
 306 lemma drops_inv_pair2_isuni_next: ∀b,f,I,K,V,L1. 𝐔⦃f⦄ → ⬇*[b, ⫯f] L1 ≡ K.ⓑ{I}V →
 307                                   ∃∃I1,K1,V1. ⬇*[b, f] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1.
 308 #b #f #I #K #V #L1 #Hf #H elim (drops_inv_pair2_isuni … H) -H /2 width=3 by isuni_next/ -Hf *
 309 [ #H elim (isid_inv_next … H) -H //
 310 | /2 width=5 by ex2_3_intro/
 311 ]
 312 qed-.
 313
 314 fact drops_inv_TF_aux: ∀f,L1,L2. ⬇*[Ⓕ, f] L1 ≡ L2 → 𝐔⦃f⦄ →
 315                        ∀I,K,V. L2 = K.ⓑ{I}V →
 316                        ⬇*[Ⓣ, f] L1 ≡ K.ⓑ{I}V.
 317 #f #L1 #L2 #H elim H -f -L1 -L2
 318 [ #f #_ #_ #J #K #W #H destruct
 319 | #f #I #L1 #L2 #V #_ #IH #Hf #J #K #W #H destruct
 320   /4 width=3 by drops_drop, isuni_inv_next/
 321 | #f #I #L1 #L2 #V1 #V2 #HL12 #HV21 #_ #Hf #J #K #W #H destruct
 322   lapply (isuni_inv_push … Hf ??) -Hf [1,2: // ] #Hf
 323   <(drops_fwd_isid … HL12) -K // <(lifts_fwd_isid … HV21) -V1
 324   /3 width=3 by drops_refl, isid_push/
 325 ]
 326 qed-.
 327
 328 (* Basic_2A1: includes: drop_inv_FT *)
 329 lemma drops_inv_TF: ∀f,I,L,K,V. ⬇*[Ⓕ, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 330                     ⬇*[Ⓣ, f] L ≡ K.ⓑ{I}V.
 331 /2 width=3 by drops_inv_TF_aux/ qed-.
 332
 333 (* Basic_2A1: includes: drop_inv_gen *)
 334 lemma drops_inv_gen: ∀b,f,I,L,K,V. ⬇*[b, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 335                      ⬇*[Ⓣ, f] L ≡ K.ⓑ{I}V.
 336 * /2 width=1 by drops_inv_TF/
 337 qed-.
 338
 339 (* Basic_2A1: includes: drop_inv_T *)
 340 lemma drops_inv_F: ∀b,f,I,L,K,V. ⬇*[Ⓕ, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 341                    ⬇*[b, f] L ≡ K.ⓑ{I}V.
 342 * /2 width=1 by drops_inv_TF/
 343 qed-.
 344
 345 (* Forward lemmas with test for uniformity **********************************)
 346
 347 (* Basic_1: was: drop_S *)
 348 (* Basic_2A1: was: drop_fwd_drop2 *)
 349 lemma drops_isuni_fwd_drop2: ∀b,f,I,X,K,V. 𝐔⦃f⦄ → ⬇*[b, f] X ≡ K.ⓑ{I}V → ⬇*[b, ⫯f] X ≡ K.
 350 /3 width=7 by drops_after_fwd_drop2, after_isid_isuni/ qed-.
 351
 352 (* Inversion lemmas with uniform relocations ********************************)
 353
 354 lemma drops_inv_atom2: ∀b,L,f. ⬇*[b, f] L ≡ ⋆ →
 355                        ∃∃n,f1. ⬇*[b, 𝐔❴n❵] L ≡ ⋆ & 𝐔❴n❵ ⊚ f1 ≡ f.
 356 #b #L elim L -L
 357 [ /3 width=4 by drops_atom, after_isid_sn, ex2_2_intro/
 358 | #L #I #V #IH #f #H elim (pn_split f) * #g #H0 destruct
 359   [ elim (drops_inv_skip1 … H) -H #K #W #_ #_ #H destruct
 360   | lapply (drops_inv_drop1 … H) -H #HL
 361     elim (IH … HL) -IH -HL /3 width=8 by drops_drop, after_next, ex2_2_intro/
 362   ]
 363 ]
 364 qed-.
 365
 366 lemma drops_inv_succ: ∀l,L1,L2. ⬇*[⫯l] L1 ≡ L2 →
 367                       ∃∃I,K,V. ⬇*[l] K ≡ L2 & L1 = K.ⓑ{I}V.
 368 #l #L1 #L2 #H elim (drops_inv_isuni … H) -H // *
 369 [ #H elim (isid_inv_next … H) -H //
 370 | /2 width=5 by ex2_3_intro/
 371 ]
 372 qed-.
 373
 374 (* Properties with application **********************************************)
 375
 376 lemma drops_tls_at: ∀f,i1,i2. @⦃i1,f⦄ ≡ i2 →
 377                     ∀b,L1,L2. ⬇*[b,⫱*[i2]f] L1 ≡ L2 →
 378                     ⬇*[b,↑⫱*[⫯i2]f] L1 ≡ L2.
 379 /3 width=3 by drops_eq_repl_fwd, at_inv_tls/ qed-.
 380
 381 lemma drops_split_trans_pair2: ∀b,f,I,L,K0,V. ⬇*[b, f] L ≡ K0.ⓑ{I}V → ∀n. @⦃O, f⦄ ≡ n →
 382                                ∃∃K,W. ⬇*[n]L ≡ K.ⓑ{I}W & ⬇*[b, ⫱*[⫯n]f] K ≡ K0 & ⬆*[⫱*[⫯n]f] V ≡ W.
 383 #b #f #I #L #K0 #V #H #n #Hf
 384 elim (drops_split_trans … H) -H [ |5: @(after_uni_dx … Hf) |2,3: skip ] /2 width=1 by after_isid_dx/ #Y #HLY #H
 385 lapply (drops_tls_at … Hf … H) -H #H
 386 elim (drops_inv_skip2 … H) -H #K #W #HK0 #HVW #H destruct
 387 /3 width=5 by drops_inv_gen, ex3_2_intro/
 388 qed-.
 389
 390 (* Basic_2A1: removed theorems 12:
 391               drops_inv_nil drops_inv_cons d1_liftable_liftables
 392               drop_refl_atom_O2 drop_inv_pair1
 393               drop_inv_Y1 drop_Y1 drop_O_Y drop_fwd_Y2
 394               drop_fwd_length_minus2 drop_fwd_length_minus4
 395 *)
 396 (* Basic_1: removed theorems 53:
 397             drop1_gen_pnil drop1_gen_pcons drop1_getl_trans
 398             drop_ctail drop_skip_flat
 399             cimp_flat_sx cimp_flat_dx cimp_bind cimp_getl_conf
 400             drop_clear drop_clear_O drop_clear_S
 401             clear_gen_sort clear_gen_bind clear_gen_flat clear_gen_flat_r
 402             clear_gen_all clear_clear clear_mono clear_trans clear_ctail clear_cle
 403             getl_ctail_clen getl_gen_tail clear_getl_trans getl_clear_trans
 404             getl_clear_bind getl_clear_conf getl_dec getl_drop getl_drop_conf_lt
 405             getl_drop_conf_ge getl_conf_ge_drop getl_drop_conf_rev
 406             drop_getl_trans_lt drop_getl_trans_le drop_getl_trans_ge
 407             getl_drop_trans getl_flt getl_gen_all getl_gen_sort getl_gen_O
 408             getl_gen_S getl_gen_2 getl_gen_flat getl_gen_bind getl_conf_le
 409             getl_trans getl_refl getl_head getl_flat getl_ctail getl_mono
 410 *)