matita/matita/contribs/lambdadelta/basic_2/relocation/drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/rdropstar_3.ma".
  16 include "basic_2/notation/relations/rdropstar_4.ma".
  17 include "basic_2/relocation/lreq.ma".
  18 include "basic_2/relocation/lifts.ma".
  19
  20 (* GENERIC SLICING FOR LOCAL ENVIRONMENTS ***********************************)
  21
  22 (* Basic_1: includes: drop_skip_bind drop1_skip_bind *)
  23 (* Basic_2A1: includes: drop_atom drop_pair drop_drop drop_skip
  24                         drop_refl_atom_O2 drop_drop_lt drop_skip_lt
  25 *)
  26 inductive drops (b:bool): rtmap → relation lenv ≝
  27 | drops_atom: ∀f. (b = Ⓣ → 𝐈⦃f⦄) → drops b (f) (⋆) (⋆)
  28 | drops_drop: ∀f,I,L1,L2,V. drops b f L1 L2 → drops b (⫯f) (L1.ⓑ{I}V) L2
  29 | drops_skip: ∀f,I,L1,L2,V1,V2.
  30               drops b f L1 L2 → ⬆*[f] V2 ≡ V1 →
  31               drops b (↑f) (L1.ⓑ{I}V1) (L2.ⓑ{I}V2)
  32 .
  33
  34 interpretation "uniform slicing (local environment)"
  35    'RDropStar i L1 L2 = (drops true (uni i) L1 L2).
  36
  37 interpretation "generic slicing (local environment)"
  38    'RDropStar b f L1 L2 = (drops b f L1 L2).
  39
  40 definition d_liftable1: relation2 lenv term → predicate bool ≝
  41                         λR,b. ∀f,L,K. ⬇*[b, f] L ≡ K →
  42                         ∀T,U. ⬆*[f] T ≡ U → R K T → R L U.
  43
  44 definition d_liftable2: predicate (lenv → relation term) ≝
  45                         λR. ∀K,T1,T2. R K T1 T2 → ∀b,f,L. ⬇*[b, f] L ≡ K →
  46                         ∀U1. ⬆*[f] T1 ≡ U1 →
  47                         ∃∃U2. ⬆*[f] T2 ≡ U2 & R L U1 U2.
  48
  49 definition d_deliftable2_sn: predicate (lenv → relation term) ≝
  50                              λR. ∀L,U1,U2. R L U1 U2 → ∀b,f,K. ⬇*[b, f] L ≡ K →
  51                              ∀T1. ⬆*[f] T1 ≡ U1 →
  52                              ∃∃T2. ⬆*[f] T2 ≡ U2 & R K T1 T2.
  53
  54 definition dropable_sn: predicate (rtmap → relation lenv) ≝
  55                         λR. ∀b,f,L1,K1. ⬇*[b, f] L1 ≡ K1 → ∀f2,L2. R f2 L1 L2 →
  56                         ∀f1. f ⊚ f1 ≡ f2 →
  57                         ∃∃K2. R f1 K1 K2 & ⬇*[b, f] L2 ≡ K2.
  58
  59 definition dropable_dx: predicate (rtmap → relation lenv) ≝
  60                         λR. ∀f2,L1,L2. R f2 L1 L2 →
  61                         ∀b,f,K2. ⬇*[b, f] L2 ≡ K2 →  𝐔⦃f⦄ →
  62                         ∀f1. f ⊚ f1 ≡ f2 →
  63                         ∃∃K1. ⬇*[b, f] L1 ≡ K1 & R f1 K1 K2.
  64
  65 definition dedropable_sn: predicate (rtmap → relation lenv) ≝
  66                           λR. ∀b,f,L1,K1. ⬇*[b, f] L1 ≡ K1 → ∀f1,K2. R f1 K1 K2 →
  67                           ∀f2. f ⊚ f1 ≡ f2 →
  68                           ∃∃L2. R f2 L1 L2 & ⬇*[b, f] L2 ≡ K2 & L1 ≡[f] L2.
  69
  70 (* Basic properties *********************************************************)
  71
  72 lemma drops_atom_F: ∀f. ⬇*[Ⓕ, f] ⋆ ≡ ⋆.
  73 #f @drops_atom #H destruct
  74 qed.
  75
  76 lemma drops_eq_repl_back: ∀b,L1,L2. eq_repl_back … (λf. ⬇*[b, f] L1 ≡ L2).
  77 #b #L1 #L2 #f1 #H elim H -f1 -L1 -L2
  78 [ /4 width=3 by drops_atom, isid_eq_repl_back/
  79 | #f1 #I #L1 #L2 #V #_ #IH #f2 #H elim (eq_inv_nx … H) -H
  80   /3 width=3 by drops_drop/
  81 | #f1 #I #L1 #L2 #V1 #v2 #_ #HV #IH #f2 #H elim (eq_inv_px … H) -H
  82   /3 width=3 by drops_skip, lifts_eq_repl_back/
  83 ]
  84 qed-.
  85
  86 lemma drops_eq_repl_fwd: ∀b,L1,L2. eq_repl_fwd … (λf. ⬇*[b, f] L1 ≡ L2).
  87 #b #L1 #L2 @eq_repl_sym /2 width=3 by drops_eq_repl_back/ (**) (* full auto fails *)
  88 qed-.
  89
  90 lemma drops_inv_tls_at: ∀f,i1,i2. @⦃i1,f⦄ ≡ i2 →
  91                         ∀b,L1,L2. ⬇*[b,⫱*[i2]f] L1 ≡ L2 →
  92                         ⬇*[b,↑⫱*[⫯i2]f] L1 ≡ L2.
  93 /3 width=3 by drops_eq_repl_fwd, at_inv_tls/ qed-.
  94
  95 (* Basic_2A1: includes: drop_FT *)
  96 lemma drops_TF: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → ⬇*[Ⓕ, f] L1 ≡ L2.
  97 #f #L1 #L2 #H elim H -f -L1 -L2
  98 /3 width=1 by drops_atom, drops_drop, drops_skip/
  99 qed.
 100
 101 (* Basic_2A1: includes: drop_gen *)
 102 lemma drops_gen: ∀b,f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → ⬇*[b, f] L1 ≡ L2.
 103 * /2 width=1 by drops_TF/
 104 qed-.
 105
 106 (* Basic_2A1: includes: drop_T *)
 107 lemma drops_F: ∀b,f,L1,L2. ⬇*[b, f] L1 ≡ L2 → ⬇*[Ⓕ, f] L1 ≡ L2.
 108 * /2 width=1 by drops_TF/
 109 qed-.
 110
 111 (* Basic_2A1: includes: drop_refl *)
 112 lemma drops_refl: ∀b,L,f. 𝐈⦃f⦄ → ⬇*[b, f] L ≡ L.
 113 #b #L elim L -L /2 width=1 by drops_atom/
 114 #L #I #V #IHL #f #Hf elim (isid_inv_gen … Hf) -Hf
 115 /3 width=1 by drops_skip, lifts_refl/
 116 qed.
 117
 118 (* Basic_2A1: includes: drop_split *)
 119 lemma drops_split_trans: ∀b,f,L1,L2. ⬇*[b, f] L1 ≡ L2 → ∀f1,f2. f1 ⊚ f2 ≡ f → 𝐔⦃f1⦄ →
 120                          ∃∃L. ⬇*[b, f1] L1 ≡ L & ⬇*[b, f2] L ≡ L2.
 121 #b #f #L1 #L2 #H elim H -f -L1 -L2
 122 [ #f #H0f #f1 #f2 #Hf #Hf1 @(ex2_intro … (⋆)) @drops_atom
 123   #H lapply (H0f H) -b
 124   #H elim (after_inv_isid3 … Hf H) -f //
 125 | #f #I #L1 #L2 #V #HL12 #IHL12 #f1 #f2 #Hf #Hf1 elim (after_inv_xxn … Hf) -Hf [1,3: * |*: // ]
 126   [ #g1 #g2 #Hf #H1 #H2 destruct
 127     lapply (isuni_inv_push … Hf1 ??) -Hf1 [1,2: // ] #Hg1
 128     elim (IHL12 … Hf) -f
 129     /4 width=5 by drops_drop, drops_skip, lifts_refl, isuni_isid, ex2_intro/
 130   | #g1 #Hf #H destruct elim (IHL12 … Hf) -f
 131     /3 width=5 by ex2_intro, drops_drop, isuni_inv_next/
 132   ]
 133 | #f #I #L1 #L2 #V1 #V2 #_ #HV21 #IHL12 #f1 #f2 #Hf #Hf1 elim (after_inv_xxp … Hf) -Hf [2,3: // ]
 134   #g1 #g2 #Hf #H1 #H2 destruct elim (lifts_split_trans … HV21 … Hf) -HV21
 135   elim (IHL12 … Hf) -f /3 width=5 by ex2_intro, drops_skip, isuni_fwd_push/
 136 ]
 137 qed-.
 138
 139 lemma drops_split_div: ∀b,f1,L1,L. ⬇*[b, f1] L1 ≡ L → ∀f2,f. f1 ⊚ f2 ≡ f → 𝐔⦃f2⦄ →
 140                        ∃∃L2. ⬇*[Ⓕ, f2] L ≡ L2 & ⬇*[Ⓕ, f] L1 ≡ L2.
 141 #b #f1 #L1 #L #H elim H -f1 -L1 -L
 142 [ #f1 #Hf1 #f2 #f #Hf #Hf2 @(ex2_intro … (⋆)) @drops_atom #H destruct
 143 | #f1 #I #L1 #L #V #HL1 #IH #f2 #f #Hf #Hf2 elim (after_inv_nxx … Hf) -Hf [2,3: // ]
 144   #g #Hg #H destruct elim (IH … Hg) -IH -Hg /3 width=5 by drops_drop, ex2_intro/
 145 | #f1 #I #L1 #L #V1 #V #HL1 #HV1 #IH #f2 #f #Hf #Hf2
 146   elim (after_inv_pxx … Hf) -Hf [1,3: * |*: // ]
 147   #g2 #g #Hg #H2 #H0 destruct
 148   [ lapply (isuni_inv_push … Hf2 ??) -Hf2 [1,2: // ] #Hg2 -IH
 149     lapply (after_isid_inv_dx … Hg … Hg2) -Hg #Hg
 150     /5 width=7 by drops_eq_repl_back, drops_F, drops_refl, drops_skip, lifts_eq_repl_back, isid_push, ex2_intro/
 151   | lapply (isuni_inv_next … Hf2 ??) -Hf2 [1,2: // ] #Hg2 -HL1 -HV1
 152     elim (IH … Hg) -f1 /3 width=3 by drops_drop, ex2_intro/
 153   ]
 154 ]
 155 qed-.
 156
 157 (* Basic forward lemmas *****************************************************)
 158
 159 (* Basic_1: includes: drop_gen_refl *)
 160 (* Basic_2A1: includes: drop_inv_O2 *)
 161 lemma drops_fwd_isid: ∀b,f,L1,L2. ⬇*[b, f] L1 ≡ L2 → 𝐈⦃f⦄ → L1 = L2.
 162 #b #f #L1 #L2 #H elim H -f -L1 -L2 //
 163 [ #f #I #L1 #L2 #V #_ #_ #H elim (isid_inv_next … H) //
 164 | /5 width=5 by isid_inv_push, lifts_fwd_isid, eq_f3, sym_eq/
 165 ]
 166 qed-.
 167
 168 fact drops_fwd_drop2_aux: ∀b,f2,X,Y. ⬇*[b, f2] X ≡ Y → ∀I,K,V. Y = K.ⓑ{I}V →
 169                           ∃∃f1,f. 𝐈⦃f1⦄ & f2 ⊚ ⫯f1 ≡ f & ⬇*[b, f] X ≡ K.
 170 #b #f2 #X #Y #H elim H -f2 -X -Y
 171 [ #f2 #Hf2 #J #K #W #H destruct
 172 | #f2 #I #L1 #L2 #V #_ #IHL #J #K #W #H elim (IHL … H) -IHL
 173   /3 width=7 by after_next, ex3_2_intro, drops_drop/
 174 | #f2 #I #L1 #L2 #V1 #V2 #HL #_ #_ #J #K #W #H destruct
 175   lapply (after_isid_dx 𝐈𝐝 … f2) /3 width=9 by after_push, ex3_2_intro, drops_drop/
 176 ]
 177 qed-.
 178
 179 lemma drops_fwd_drop2: ∀b,f2,I,X,K,V. ⬇*[b, f2] X ≡ K.ⓑ{I}V →
 180                        ∃∃f1,f. 𝐈⦃f1⦄ & f2 ⊚ ⫯f1 ≡ f & ⬇*[b, f] X ≡ K.
 181 /2 width=5 by drops_fwd_drop2_aux/ qed-.
 182
 183 lemma drops_after_fwd_drop2: ∀b,f2,I,X,K,V. ⬇*[b, f2] X ≡ K.ⓑ{I}V →
 184                              ∀f1,f. 𝐈⦃f1⦄ → f2 ⊚ ⫯f1 ≡ f → ⬇*[b, f] X ≡ K.
 185 #b #f2 #I #X #K #V #H #f1 #f #Hf1 #Hf elim (drops_fwd_drop2 … H) -H
 186 #g1 #g #Hg1 #Hg #HK lapply (after_mono_eq … Hg … Hf ??) -Hg -Hf
 187 /3 width=5 by drops_eq_repl_back, isid_inv_eq_repl, eq_next/
 188 qed-.
 189
 190 (* Basic_1: was: drop_S *)
 191 (* Basic_2A1: was: drop_fwd_drop2 *)
 192 lemma drops_isuni_fwd_drop2: ∀b,f,I,X,K,V. 𝐔⦃f⦄ → ⬇*[b, f] X ≡ K.ⓑ{I}V → ⬇*[b, ⫯f] X ≡ K.
 193 /3 width=7 by drops_after_fwd_drop2, after_isid_isuni/ qed-.
 194
 195 (* Forward lemmas with test for finite colength *****************************)
 196
 197 lemma drops_fwd_isfin: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → 𝐅⦃f⦄.
 198 #f #L1 #L2 #H elim H -f -L1 -L2
 199 /3 width=1 by isfin_next, isfin_push, isfin_isid/
 200 qed-.
 201
 202 (* Basic inversion lemmas ***************************************************)
 203
 204 fact drops_inv_atom1_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → X = ⋆ →
 205                           Y = ⋆ ∧ (b = Ⓣ → 𝐈⦃f⦄).
 206 #b #f #X #Y * -f -X -Y
 207 [ /3 width=1 by conj/
 208 | #f #I #L1 #L2 #V #_ #H destruct
 209 | #f #I #L1 #L2 #V1 #V2 #_ #_ #H destruct
 210 ]
 211 qed-.
 212
 213 (* Basic_1: includes: drop_gen_sort *)
 214 (* Basic_2A1: includes: drop_inv_atom1 *)
 215 lemma drops_inv_atom1: ∀b,f,Y. ⬇*[b, f] ⋆ ≡ Y → Y = ⋆ ∧ (b = Ⓣ → 𝐈⦃f⦄).
 216 /2 width=3 by drops_inv_atom1_aux/ qed-.
 217
 218 fact drops_inv_drop1_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → ∀g,I,K,V. X = K.ⓑ{I}V → f = ⫯g →
 219                           ⬇*[b, g] K ≡ Y.
 220 #b #f #X #Y * -f -X -Y
 221 [ #f #Hf #g #J #K #W #H destruct
 222 | #f #I #L1 #L2 #V #HL #g #J #K #W #H1 #H2 <(injective_next … H2) -g destruct //
 223 | #f #I #L1 #L2 #V1 #V2 #_ #_ #g #J #K #W #_ #H2 elim (discr_push_next … H2)
 224 ]
 225 qed-.
 226
 227 (* Basic_1: includes: drop_gen_drop *)
 228 (* Basic_2A1: includes: drop_inv_drop1_lt drop_inv_drop1 *)
 229 lemma drops_inv_drop1: ∀b,f,I,K,Y,V. ⬇*[b, ⫯f] K.ⓑ{I}V ≡ Y → ⬇*[b, f] K ≡ Y.
 230 /2 width=7 by drops_inv_drop1_aux/ qed-.
 231
 232 fact drops_inv_skip1_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → ∀g,I,K1,V1. X = K1.ⓑ{I}V1 → f = ↑g →
 233                           ∃∃K2,V2. ⬇*[b, g] K1 ≡ K2 & ⬆*[g] V2 ≡ V1 & Y = K2.ⓑ{I}V2.
 234 #b #f #X #Y * -f -X -Y
 235 [ #f #Hf #g #J #K1 #W1 #H destruct
 236 | #f #I #L1 #L2 #V #_ #g #J #K1 #W1 #_ #H2 elim (discr_next_push … H2)
 237 | #f #I #L1 #L2 #V1 #V2 #HL #HV #g #J #K1 #W1 #H1 #H2 <(injective_push … H2) -g destruct
 238   /2 width=5 by ex3_2_intro/
 239 ]
 240 qed-.
 241
 242 (* Basic_1: includes: drop_gen_skip_l *)
 243 (* Basic_2A1: includes: drop_inv_skip1 *)
 244 lemma drops_inv_skip1: ∀b,f,I,K1,V1,Y. ⬇*[b, ↑f] K1.ⓑ{I}V1 ≡ Y →
 245                        ∃∃K2,V2. ⬇*[b, f] K1 ≡ K2 & ⬆*[f] V2 ≡ V1 & Y = K2.ⓑ{I}V2.
 246 /2 width=5 by drops_inv_skip1_aux/ qed-.
 247
 248 fact drops_inv_skip2_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → ∀g,I,K2,V2. Y = K2.ⓑ{I}V2 → f = ↑g →
 249                           ∃∃K1,V1. ⬇*[b, g] K1 ≡ K2 & ⬆*[g] V2 ≡ V1 & X = K1.ⓑ{I}V1.
 250 #b #f #X #Y * -f -X -Y
 251 [ #f #Hf #g #J #K2 #W2 #H destruct
 252 | #f #I #L1 #L2 #V #_ #g #J #K2 #W2 #_ #H2 elim (discr_next_push … H2)
 253 | #f #I #L1 #L2 #V1 #V2 #HL #HV #g #J #K2 #W2 #H1 #H2 <(injective_push … H2) -g destruct
 254   /2 width=5 by ex3_2_intro/
 255 ]
 256 qed-.
 257
 258 (* Basic_1: includes: drop_gen_skip_r *)
 259 (* Basic_2A1: includes: drop_inv_skip2 *)
 260 lemma drops_inv_skip2: ∀b,f,I,X,K2,V2. ⬇*[b, ↑f] X ≡ K2.ⓑ{I}V2 →
 261                        ∃∃K1,V1. ⬇*[b, f] K1 ≡ K2 & ⬆*[f] V2 ≡ V1 & X = K1.ⓑ{I}V1.
 262 /2 width=5 by drops_inv_skip2_aux/ qed-.
 263
 264 fact drops_inv_TF_aux: ∀f,L1,L2. ⬇*[Ⓕ, f] L1 ≡ L2 → 𝐔⦃f⦄ →
 265                        ∀I,K,V. L2 = K.ⓑ{I}V →
 266                        ⬇*[Ⓣ, f] L1 ≡ K.ⓑ{I}V.
 267 #f #L1 #L2 #H elim H -f -L1 -L2
 268 [ #f #_ #_ #J #K #W #H destruct
 269 | #f #I #L1 #L2 #V #_ #IH #Hf #J #K #W #H destruct
 270   /4 width=3 by drops_drop, isuni_inv_next/
 271 | #f #I #L1 #L2 #V1 #V2 #HL12 #HV21 #_ #Hf #J #K #W #H destruct
 272   lapply (isuni_inv_push … Hf ??) -Hf [1,2: // ] #Hf
 273   <(drops_fwd_isid … HL12) -K // <(lifts_fwd_isid … HV21) -V1
 274   /3 width=3 by drops_refl, isid_push/
 275 ]
 276 qed-.
 277
 278 (* Basic_2A1: includes: drop_inv_FT *)
 279 lemma drops_inv_TF: ∀f,I,L,K,V. ⬇*[Ⓕ, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 280                     ⬇*[Ⓣ, f] L ≡ K.ⓑ{I}V.
 281 /2 width=3 by drops_inv_TF_aux/ qed-.
 282
 283 (* Advanced inversion lemmas ************************************************)
 284
 285 lemma drops_inv_atom2: ∀b,L,f. ⬇*[b,f] L ≡ ⋆ →
 286                        ∃∃n,f1. ⬇*[b,𝐔❴n❵] L ≡ ⋆ & 𝐔❴n❵ ⊚ f1 ≡ f.
 287 #b #L elim L -L
 288 [ /3 width=4 by drops_atom, after_isid_sn, ex2_2_intro/
 289 | #L #I #V #IH #f #H elim (pn_split f) * #g #H0 destruct
 290   [ elim (drops_inv_skip1 … H) -H #K #W #_ #_ #H destruct
 291   | lapply (drops_inv_drop1 … H) -H #HL
 292     elim (IH … HL) -IH -HL /3 width=8 by drops_drop, after_next, ex2_2_intro/
 293   ]
 294 ]
 295 qed-.
 296
 297 (* Basic_2A1: includes: drop_inv_gen *)
 298 lemma drops_inv_gen: ∀b,f,I,L,K,V. ⬇*[b, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 299                      ⬇*[Ⓣ, f] L ≡ K.ⓑ{I}V.
 300 * /2 width=1 by drops_inv_TF/
 301 qed-.
 302
 303 (* Basic_2A1: includes: drop_inv_T *)
 304 lemma drops_inv_F: ∀b,f,I,L,K,V. ⬇*[Ⓕ, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 305                    ⬇*[b, f] L ≡ K.ⓑ{I}V.
 306 * /2 width=1 by drops_inv_TF/
 307 qed-.
 308
 309 (* Inversion lemmas with test for uniformity ********************************)
 310
 311 lemma drops_inv_isuni: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → 𝐔⦃f⦄ →
 312                        (𝐈⦃f⦄ ∧ L1 = L2) ∨
 313                        ∃∃g,I,K,V. ⬇*[Ⓣ, g] K ≡ L2 & 𝐔⦃g⦄ & L1 = K.ⓑ{I}V & f = ⫯g.
 314 #f #L1 #L2 * -f -L1 -L2
 315 [ /4 width=1 by or_introl, conj/
 316 | /4 width=8 by isuni_inv_next, ex4_4_intro, or_intror/
 317 | /7 width=6 by drops_fwd_isid, lifts_fwd_isid, isuni_inv_push, isid_push, or_introl, conj, eq_f3, sym_eq/
 318 ]
 319 qed-.
 320
 321 (* Basic_2A1: was: drop_inv_O1_pair1 *)
 322 lemma drops_inv_pair1_isuni: ∀b,f,I,K,L2,V. 𝐔⦃f⦄ → ⬇*[b, f] K.ⓑ{I}V ≡ L2 →
 323                              (𝐈⦃f⦄ ∧ L2 = K.ⓑ{I}V) ∨
 324                              ∃∃g. 𝐔⦃g⦄ & ⬇*[b, g] K ≡ L2 & f = ⫯g.
 325 #b #f #I #K #L2 #V #Hf #H elim (isuni_split … Hf) -Hf * #g #Hg #H0 destruct
 326 [ lapply (drops_inv_skip1 … H) -H * #Y #X #HY #HX #H destruct
 327   <(drops_fwd_isid … HY Hg) -Y >(lifts_fwd_isid … HX Hg) -X
 328   /4 width=3 by isid_push, or_introl, conj/
 329 | lapply (drops_inv_drop1 … H) -H /3 width=4 by ex3_intro, or_intror/
 330 ]
 331 qed-.
 332
 333 (* Basic_2A1: was: drop_inv_O1_pair2 *)
 334 lemma drops_inv_pair2_isuni: ∀b,f,I,K,V,L1. 𝐔⦃f⦄ → ⬇*[b, f] L1 ≡ K.ⓑ{I}V →
 335                              (𝐈⦃f⦄ ∧ L1 = K.ⓑ{I}V) ∨
 336                              ∃∃g,I1,K1,V1. 𝐔⦃g⦄ & ⬇*[b, g] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1 & f = ⫯g.
 337 #b #f #I #K #V *
 338 [ #Hf #H elim (drops_inv_atom1 … H) -H #H destruct
 339 | #L1 #I1 #V1 #Hf #H elim (drops_inv_pair1_isuni … Hf H) -Hf -H *
 340   [ #Hf #H destruct /3 width=1 by or_introl, conj/
 341   | /3 width=8 by ex4_4_intro, or_intror/
 342   ]
 343 ]
 344 qed-.
 345
 346 lemma drops_inv_pair2_isuni_next: ∀b,f,I,K,V,L1. 𝐔⦃f⦄ → ⬇*[b, ⫯f] L1 ≡ K.ⓑ{I}V →
 347                                   ∃∃I1,K1,V1. ⬇*[b, f] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1.
 348 #b #f #I #K #V #L1 #Hf #H elim (drops_inv_pair2_isuni … H) -H /2 width=3 by isuni_next/ -Hf *
 349 [ #H elim (isid_inv_next … H) -H //
 350 | /2 width=5 by ex2_3_intro/
 351 ]
 352 qed-.
 353
 354 (* Inversion lemmas with uniform relocations ********************************)
 355
 356 lemma drops_inv_succ: ∀l,L1,L2. ⬇*[⫯l] L1 ≡ L2 →
 357                       ∃∃I,K,V. ⬇*[l] K ≡ L2 & L1 = K.ⓑ{I}V.
 358 #l #L1 #L2 #H elim (drops_inv_isuni … H) -H // *
 359 [ #H elim (isid_inv_next … H) -H //
 360 | /2 width=5 by ex2_3_intro/
 361 ]
 362 qed-.
 363
 364 (* Properties with uniform relocations **************************************)
 365
 366 lemma drops_uni_ex: ∀L,i. ⬇*[Ⓕ, 𝐔❴i❵] L ≡ ⋆ ∨ ∃∃I,K,V. ⬇*[i] L ≡ K.ⓑ{I}V.
 367 #L elim L -L /2 width=1 by or_introl/
 368 #L #I #V #IH * /4 width=4 by drops_refl, ex1_3_intro, or_intror/
 369 #i elim (IH i) -IH /3 width=1 by drops_drop, or_introl/
 370 * /4 width=4 by drops_drop, ex1_3_intro, or_intror/
 371 qed-.
 372
 373 (* Basic_2A1: removed theorems 12:
 374               drops_inv_nil drops_inv_cons d1_liftable_liftables
 375               drop_refl_atom_O2 drop_inv_pair1
 376               drop_inv_Y1 drop_Y1 drop_O_Y drop_fwd_Y2
 377               drop_fwd_length_minus2 drop_fwd_length_minus4
 378 *)
 379 (* Basic_1: removed theorems 53:
 380             drop1_gen_pnil drop1_gen_pcons drop1_getl_trans
 381             drop_ctail drop_skip_flat
 382             cimp_flat_sx cimp_flat_dx cimp_bind cimp_getl_conf
 383             drop_clear drop_clear_O drop_clear_S
 384             clear_gen_sort clear_gen_bind clear_gen_flat clear_gen_flat_r
 385             clear_gen_all clear_clear clear_mono clear_trans clear_ctail clear_cle
 386             getl_ctail_clen getl_gen_tail clear_getl_trans getl_clear_trans
 387             getl_clear_bind getl_clear_conf getl_dec getl_drop getl_drop_conf_lt
 388             getl_drop_conf_ge getl_conf_ge_drop getl_drop_conf_rev
 389             drop_getl_trans_lt drop_getl_trans_le drop_getl_trans_ge
 390             getl_drop_trans getl_flt getl_gen_all getl_gen_sort getl_gen_O
 391             getl_gen_S getl_gen_2 getl_gen_flat getl_gen_bind getl_conf_le
 392             getl_trans getl_refl getl_head getl_flat getl_ctail getl_mono
 393 *)