matita/matita/contribs/lambdadelta/basic_2/relocation/drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_coafter.ma".
  16 include "basic_2/notation/relations/rdropstar_3.ma".
  17 include "basic_2/notation/relations/rdropstar_4.ma".
  18 include "basic_2/relocation/lreq.ma".
  19 include "basic_2/relocation/lifts.ma".
  20
  21 (* GENERIC SLICING FOR LOCAL ENVIRONMENTS ***********************************)
  22
  23 (* Basic_1: includes: drop_skip_bind drop1_skip_bind *)
  24 (* Basic_2A1: includes: drop_atom drop_pair drop_drop drop_skip
  25                         drop_refl_atom_O2 drop_drop_lt drop_skip_lt
  26 *)
  27 inductive drops (b:bool): rtmap → relation lenv ≝
  28 | drops_atom: ∀f. (b = Ⓣ → 𝐈⦃f⦄) → drops b (f) (⋆) (⋆)
  29 | drops_drop: ∀f,I,L1,L2,V. drops b f L1 L2 → drops b (⫯f) (L1.ⓑ{I}V) L2
  30 | drops_skip: ∀f,I,L1,L2,V1,V2.
  31               drops b f L1 L2 → ⬆*[f] V2 ≡ V1 →
  32               drops b (↑f) (L1.ⓑ{I}V1) (L2.ⓑ{I}V2)
  33 .
  34
  35 interpretation "uniform slicing (local environment)"
  36    'RDropStar i L1 L2 = (drops true (uni i) L1 L2).
  37
  38 interpretation "generic slicing (local environment)"
  39    'RDropStar b f L1 L2 = (drops b f L1 L2).
  40
  41 definition d_liftable1: predicate (relation2 lenv term) ≝
  42                         λR. ∀K,T. R K T → ∀b,f,L. ⬇*[b, f] L ≡ K →
  43                         ∀U. ⬆*[f] T ≡ U → R L U.
  44
  45 definition d_liftable2: predicate (lenv → relation term) ≝
  46                         λR. ∀K,T1,T2. R K T1 T2 → ∀b,f,L. ⬇*[b, f] L ≡ K →
  47                         ∀U1. ⬆*[f] T1 ≡ U1 →
  48                         ∃∃U2. ⬆*[f] T2 ≡ U2 & R L U1 U2.
  49
  50 definition d_deliftable2_sn: predicate (lenv → relation term) ≝
  51                              λR. ∀L,U1,U2. R L U1 U2 → ∀b,f,K. ⬇*[b, f] L ≡ K →
  52                              ∀T1. ⬆*[f] T1 ≡ U1 →
  53                              ∃∃T2. ⬆*[f] T2 ≡ U2 & R K T1 T2.
  54
  55 definition co_dropable_sn: predicate (rtmap → relation lenv) ≝
  56                            λR. ∀b,f,L1,K1. ⬇*[b, f] L1 ≡ K1 → 𝐔⦃f⦄ →
  57                            ∀f2,L2. R f2 L1 L2 → ∀f1. f ~⊚ f1 ≡ f2 →
  58                            ∃∃K2. R f1 K1 K2 & ⬇*[b, f] L2 ≡ K2.
  59
  60
  61 definition co_dropable_dx: predicate (rtmap → relation lenv) ≝
  62                            λR. ∀f2,L1,L2. R f2 L1 L2 →
  63                            ∀b,f,K2. ⬇*[b, f] L2 ≡ K2 → 𝐔⦃f⦄ →
  64                            ∀f1. f ~⊚ f1 ≡ f2 →
  65                            ∃∃K1. ⬇*[b, f] L1 ≡ K1 & R f1 K1 K2.
  66
  67 definition co_dedropable_sn: predicate (rtmap → relation lenv) ≝
  68                              λR. ∀b,f,L1,K1. ⬇*[b, f] L1 ≡ K1 → ∀f1,K2. R f1 K1 K2 →
  69                              ∀f2. f ~⊚ f1 ≡ f2 →
  70                              ∃∃L2. R f2 L1 L2 & ⬇*[b, f] L2 ≡ K2 & L1 ≡[f] L2.
  71
  72 (* Basic properties *********************************************************)
  73
  74 lemma drops_atom_F: ∀f. ⬇*[Ⓕ, f] ⋆ ≡ ⋆.
  75 #f @drops_atom #H destruct
  76 qed.
  77
  78 lemma drops_eq_repl_back: ∀b,L1,L2. eq_repl_back … (λf. ⬇*[b, f] L1 ≡ L2).
  79 #b #L1 #L2 #f1 #H elim H -f1 -L1 -L2
  80 [ /4 width=3 by drops_atom, isid_eq_repl_back/
  81 | #f1 #I #L1 #L2 #V #_ #IH #f2 #H elim (eq_inv_nx … H) -H
  82   /3 width=3 by drops_drop/
  83 | #f1 #I #L1 #L2 #V1 #v2 #_ #HV #IH #f2 #H elim (eq_inv_px … H) -H
  84   /3 width=3 by drops_skip, lifts_eq_repl_back/
  85 ]
  86 qed-.
  87
  88 lemma drops_eq_repl_fwd: ∀b,L1,L2. eq_repl_fwd … (λf. ⬇*[b, f] L1 ≡ L2).
  89 #b #L1 #L2 @eq_repl_sym /2 width=3 by drops_eq_repl_back/ (**) (* full auto fails *)
  90 qed-.
  91
  92 (* Basic_2A1: includes: drop_FT *)
  93 lemma drops_TF: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → ⬇*[Ⓕ, f] L1 ≡ L2.
  94 #f #L1 #L2 #H elim H -f -L1 -L2
  95 /3 width=1 by drops_atom, drops_drop, drops_skip/
  96 qed.
  97
  98 (* Basic_2A1: includes: drop_gen *)
  99 lemma drops_gen: ∀b,f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → ⬇*[b, f] L1 ≡ L2.
 100 * /2 width=1 by drops_TF/
 101 qed-.
 102
 103 (* Basic_2A1: includes: drop_T *)
 104 lemma drops_F: ∀b,f,L1,L2. ⬇*[b, f] L1 ≡ L2 → ⬇*[Ⓕ, f] L1 ≡ L2.
 105 * /2 width=1 by drops_TF/
 106 qed-.
 107
 108 (* Basic inversion lemmas ***************************************************)
 109
 110 fact drops_inv_atom1_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → X = ⋆ →
 111                           Y = ⋆ ∧ (b = Ⓣ → 𝐈⦃f⦄).
 112 #b #f #X #Y * -f -X -Y
 113 [ /3 width=1 by conj/
 114 | #f #I #L1 #L2 #V #_ #H destruct
 115 | #f #I #L1 #L2 #V1 #V2 #_ #_ #H destruct
 116 ]
 117 qed-.
 118
 119 (* Basic_1: includes: drop_gen_sort *)
 120 (* Basic_2A1: includes: drop_inv_atom1 *)
 121 lemma drops_inv_atom1: ∀b,f,Y. ⬇*[b, f] ⋆ ≡ Y → Y = ⋆ ∧ (b = Ⓣ → 𝐈⦃f⦄).
 122 /2 width=3 by drops_inv_atom1_aux/ qed-.
 123
 124 fact drops_inv_drop1_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → ∀g,I,K,V. X = K.ⓑ{I}V → f = ⫯g →
 125                           ⬇*[b, g] K ≡ Y.
 126 #b #f #X #Y * -f -X -Y
 127 [ #f #Hf #g #J #K #W #H destruct
 128 | #f #I #L1 #L2 #V #HL #g #J #K #W #H1 #H2 <(injective_next … H2) -g destruct //
 129 | #f #I #L1 #L2 #V1 #V2 #_ #_ #g #J #K #W #_ #H2 elim (discr_push_next … H2)
 130 ]
 131 qed-.
 132
 133 (* Basic_1: includes: drop_gen_drop *)
 134 (* Basic_2A1: includes: drop_inv_drop1_lt drop_inv_drop1 *)
 135 lemma drops_inv_drop1: ∀b,f,I,K,Y,V. ⬇*[b, ⫯f] K.ⓑ{I}V ≡ Y → ⬇*[b, f] K ≡ Y.
 136 /2 width=7 by drops_inv_drop1_aux/ qed-.
 137
 138 fact drops_inv_skip1_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → ∀g,I,K1,V1. X = K1.ⓑ{I}V1 → f = ↑g →
 139                           ∃∃K2,V2. ⬇*[b, g] K1 ≡ K2 & ⬆*[g] V2 ≡ V1 & Y = K2.ⓑ{I}V2.
 140 #b #f #X #Y * -f -X -Y
 141 [ #f #Hf #g #J #K1 #W1 #H destruct
 142 | #f #I #L1 #L2 #V #_ #g #J #K1 #W1 #_ #H2 elim (discr_next_push … H2)
 143 | #f #I #L1 #L2 #V1 #V2 #HL #HV #g #J #K1 #W1 #H1 #H2 <(injective_push … H2) -g destruct
 144   /2 width=5 by ex3_2_intro/
 145 ]
 146 qed-.
 147
 148 (* Basic_1: includes: drop_gen_skip_l *)
 149 (* Basic_2A1: includes: drop_inv_skip1 *)
 150 lemma drops_inv_skip1: ∀b,f,I,K1,V1,Y. ⬇*[b, ↑f] K1.ⓑ{I}V1 ≡ Y →
 151                        ∃∃K2,V2. ⬇*[b, f] K1 ≡ K2 & ⬆*[f] V2 ≡ V1 & Y = K2.ⓑ{I}V2.
 152 /2 width=5 by drops_inv_skip1_aux/ qed-.
 153
 154 fact drops_inv_skip2_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → ∀g,I,K2,V2. Y = K2.ⓑ{I}V2 → f = ↑g →
 155                           ∃∃K1,V1. ⬇*[b, g] K1 ≡ K2 & ⬆*[g] V2 ≡ V1 & X = K1.ⓑ{I}V1.
 156 #b #f #X #Y * -f -X -Y
 157 [ #f #Hf #g #J #K2 #W2 #H destruct
 158 | #f #I #L1 #L2 #V #_ #g #J #K2 #W2 #_ #H2 elim (discr_next_push … H2)
 159 | #f #I #L1 #L2 #V1 #V2 #HL #HV #g #J #K2 #W2 #H1 #H2 <(injective_push … H2) -g destruct
 160   /2 width=5 by ex3_2_intro/
 161 ]
 162 qed-.
 163
 164 (* Basic_1: includes: drop_gen_skip_r *)
 165 (* Basic_2A1: includes: drop_inv_skip2 *)
 166 lemma drops_inv_skip2: ∀b,f,I,X,K2,V2. ⬇*[b, ↑f] X ≡ K2.ⓑ{I}V2 →
 167                        ∃∃K1,V1. ⬇*[b, f] K1 ≡ K2 & ⬆*[f] V2 ≡ V1 & X = K1.ⓑ{I}V1.
 168 /2 width=5 by drops_inv_skip2_aux/ qed-.
 169
 170 (* Basic forward lemmas *****************************************************)
 171
 172 fact drops_fwd_drop2_aux: ∀b,f2,X,Y. ⬇*[b, f2] X ≡ Y → ∀I,K,V. Y = K.ⓑ{I}V →
 173                           ∃∃f1,f. 𝐈⦃f1⦄ & f2 ⊚ ⫯f1 ≡ f & ⬇*[b, f] X ≡ K.
 174 #b #f2 #X #Y #H elim H -f2 -X -Y
 175 [ #f2 #Hf2 #J #K #W #H destruct
 176 | #f2 #I #L1 #L2 #V #_ #IHL #J #K #W #H elim (IHL … H) -IHL
 177   /3 width=7 by after_next, ex3_2_intro, drops_drop/
 178 | #f2 #I #L1 #L2 #V1 #V2 #HL #_ #_ #J #K #W #H destruct
 179   lapply (after_isid_dx 𝐈𝐝 … f2) /3 width=9 by after_push, ex3_2_intro, drops_drop/
 180 ]
 181 qed-.
 182
 183 lemma drops_fwd_drop2: ∀b,f2,I,X,K,V. ⬇*[b, f2] X ≡ K.ⓑ{I}V →
 184                        ∃∃f1,f. 𝐈⦃f1⦄ & f2 ⊚ ⫯f1 ≡ f & ⬇*[b, f] X ≡ K.
 185 /2 width=5 by drops_fwd_drop2_aux/ qed-.
 186
 187 (* Properties with test for identity ****************************************)
 188
 189 (* Basic_2A1: includes: drop_refl *)
 190 lemma drops_refl: ∀b,L,f. 𝐈⦃f⦄ → ⬇*[b, f] L ≡ L.
 191 #b #L elim L -L /2 width=1 by drops_atom/
 192 #L #I #V #IHL #f #Hf elim (isid_inv_gen … Hf) -Hf
 193 /3 width=1 by drops_skip, lifts_refl/
 194 qed.
 195
 196 (* Forward lemmas test for identity *****************************************)
 197
 198 (* Basic_1: includes: drop_gen_refl *)
 199 (* Basic_2A1: includes: drop_inv_O2 *)
 200 lemma drops_fwd_isid: ∀b,f,L1,L2. ⬇*[b, f] L1 ≡ L2 → 𝐈⦃f⦄ → L1 = L2.
 201 #b #f #L1 #L2 #H elim H -f -L1 -L2 //
 202 [ #f #I #L1 #L2 #V #_ #_ #H elim (isid_inv_next … H) //
 203 | /5 width=5 by isid_inv_push, lifts_fwd_isid, eq_f3, sym_eq/
 204 ]
 205 qed-.
 206
 207
 208 lemma drops_after_fwd_drop2: ∀b,f2,I,X,K,V. ⬇*[b, f2] X ≡ K.ⓑ{I}V →
 209                              ∀f1,f. 𝐈⦃f1⦄ → f2 ⊚ ⫯f1 ≡ f → ⬇*[b, f] X ≡ K.
 210 #b #f2 #I #X #K #V #H #f1 #f #Hf1 #Hf elim (drops_fwd_drop2 … H) -H
 211 #g1 #g #Hg1 #Hg #HK lapply (after_mono_eq … Hg … Hf ??) -Hg -Hf
 212 /3 width=5 by drops_eq_repl_back, isid_inv_eq_repl, eq_next/
 213 qed-.
 214
 215 (* Forward lemmas with test for finite colength *****************************)
 216
 217 lemma drops_fwd_isfin: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → 𝐅⦃f⦄.
 218 #f #L1 #L2 #H elim H -f -L1 -L2
 219 /3 width=1 by isfin_next, isfin_push, isfin_isid/
 220 qed-.
 221
 222 (* Properties with test for uniformity **************************************)
 223
 224 lemma drops_isuni_ex: ∀f. 𝐔⦃f⦄ → ∀L. ∃K. ⬇*[Ⓕ, f] L ≡ K.
 225 #f #H elim H -f /4 width=2 by drops_refl, drops_TF, ex_intro/
 226 #f #_ #g #H #IH * /2 width=2 by ex_intro/
 227 #L #I #V destruct
 228 elim (IH L) -IH /3 width=2 by drops_drop, ex_intro/
 229 qed-.
 230
 231 (* Inversion lemmas with test for uniformity ********************************)
 232
 233 lemma drops_inv_isuni: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → 𝐔⦃f⦄ →
 234                        (𝐈⦃f⦄ ∧ L1 = L2) ∨
 235                        ∃∃g,I,K,V. ⬇*[Ⓣ, g] K ≡ L2 & 𝐔⦃g⦄ & L1 = K.ⓑ{I}V & f = ⫯g.
 236 #f #L1 #L2 * -f -L1 -L2
 237 [ /4 width=1 by or_introl, conj/
 238 | /4 width=8 by isuni_inv_next, ex4_4_intro, or_intror/
 239 | /7 width=6 by drops_fwd_isid, lifts_fwd_isid, isuni_inv_push, isid_push, or_introl, conj, eq_f3, sym_eq/
 240 ]
 241 qed-.
 242
 243 (* Basic_2A1: was: drop_inv_O1_pair1 *)
 244 lemma drops_inv_pair1_isuni: ∀b,f,I,K,L2,V. 𝐔⦃f⦄ → ⬇*[b, f] K.ⓑ{I}V ≡ L2 →
 245                              (𝐈⦃f⦄ ∧ L2 = K.ⓑ{I}V) ∨
 246                              ∃∃g. 𝐔⦃g⦄ & ⬇*[b, g] K ≡ L2 & f = ⫯g.
 247 #b #f #I #K #L2 #V #Hf #H elim (isuni_split … Hf) -Hf * #g #Hg #H0 destruct
 248 [ lapply (drops_inv_skip1 … H) -H * #Y #X #HY #HX #H destruct
 249   <(drops_fwd_isid … HY Hg) -Y >(lifts_fwd_isid … HX Hg) -X
 250   /4 width=3 by isid_push, or_introl, conj/
 251 | lapply (drops_inv_drop1 … H) -H /3 width=4 by ex3_intro, or_intror/
 252 ]
 253 qed-.
 254
 255 (* Basic_2A1: was: drop_inv_O1_pair2 *)
 256 lemma drops_inv_pair2_isuni: ∀b,f,I,K,V,L1. 𝐔⦃f⦄ → ⬇*[b, f] L1 ≡ K.ⓑ{I}V →
 257                              (𝐈⦃f⦄ ∧ L1 = K.ⓑ{I}V) ∨
 258                              ∃∃g,I1,K1,V1. 𝐔⦃g⦄ & ⬇*[b, g] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1 & f = ⫯g.
 259 #b #f #I #K #V *
 260 [ #Hf #H elim (drops_inv_atom1 … H) -H #H destruct
 261 | #L1 #I1 #V1 #Hf #H elim (drops_inv_pair1_isuni … Hf H) -Hf -H *
 262   [ #Hf #H destruct /3 width=1 by or_introl, conj/
 263   | /3 width=8 by ex4_4_intro, or_intror/
 264   ]
 265 ]
 266 qed-.
 267
 268 lemma drops_inv_pair2_isuni_next: ∀b,f,I,K,V,L1. 𝐔⦃f⦄ → ⬇*[b, ⫯f] L1 ≡ K.ⓑ{I}V →
 269                                   ∃∃I1,K1,V1. ⬇*[b, f] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1.
 270 #b #f #I #K #V #L1 #Hf #H elim (drops_inv_pair2_isuni … H) -H /2 width=3 by isuni_next/ -Hf *
 271 [ #H elim (isid_inv_next … H) -H //
 272 | /2 width=5 by ex2_3_intro/
 273 ]
 274 qed-.
 275
 276 fact drops_inv_TF_aux: ∀f,L1,L2. ⬇*[Ⓕ, f] L1 ≡ L2 → 𝐔⦃f⦄ →
 277                        ∀I,K,V. L2 = K.ⓑ{I}V →
 278                        ⬇*[Ⓣ, f] L1 ≡ K.ⓑ{I}V.
 279 #f #L1 #L2 #H elim H -f -L1 -L2
 280 [ #f #_ #_ #J #K #W #H destruct
 281 | #f #I #L1 #L2 #V #_ #IH #Hf #J #K #W #H destruct
 282   /4 width=3 by drops_drop, isuni_inv_next/
 283 | #f #I #L1 #L2 #V1 #V2 #HL12 #HV21 #_ #Hf #J #K #W #H destruct
 284   lapply (isuni_inv_push … Hf ??) -Hf [1,2: // ] #Hf
 285   <(drops_fwd_isid … HL12) -K // <(lifts_fwd_isid … HV21) -V1
 286   /3 width=3 by drops_refl, isid_push/
 287 ]
 288 qed-.
 289
 290 (* Basic_2A1: includes: drop_inv_FT *)
 291 lemma drops_inv_TF: ∀f,I,L,K,V. ⬇*[Ⓕ, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 292                     ⬇*[Ⓣ, f] L ≡ K.ⓑ{I}V.
 293 /2 width=3 by drops_inv_TF_aux/ qed-.
 294
 295 (* Basic_2A1: includes: drop_inv_gen *)
 296 lemma drops_inv_gen: ∀b,f,I,L,K,V. ⬇*[b, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 297                      ⬇*[Ⓣ, f] L ≡ K.ⓑ{I}V.
 298 * /2 width=1 by drops_inv_TF/
 299 qed-.
 300
 301 (* Basic_2A1: includes: drop_inv_T *)
 302 lemma drops_inv_F: ∀b,f,I,L,K,V. ⬇*[Ⓕ, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 303                    ⬇*[b, f] L ≡ K.ⓑ{I}V.
 304 * /2 width=1 by drops_inv_TF/
 305 qed-.
 306
 307 (* Forward lemmas with test for uniformity **********************************)
 308
 309 (* Basic_1: was: drop_S *)
 310 (* Basic_2A1: was: drop_fwd_drop2 *)
 311 lemma drops_isuni_fwd_drop2: ∀b,f,I,X,K,V. 𝐔⦃f⦄ → ⬇*[b, f] X ≡ K.ⓑ{I}V → ⬇*[b, ⫯f] X ≡ K.
 312 /3 width=7 by drops_after_fwd_drop2, after_isid_isuni/ qed-.
 313
 314 (* Inversion lemmas with uniform relocations ********************************)
 315
 316 lemma drops_inv_atom2: ∀b,L,f. ⬇*[b, f] L ≡ ⋆ →
 317                        ∃∃n,f1. ⬇*[b, 𝐔❴n❵] L ≡ ⋆ & 𝐔❴n❵ ⊚ f1 ≡ f.
 318 #b #L elim L -L
 319 [ /3 width=4 by drops_atom, after_isid_sn, ex2_2_intro/
 320 | #L #I #V #IH #f #H elim (pn_split f) * #g #H0 destruct
 321   [ elim (drops_inv_skip1 … H) -H #K #W #_ #_ #H destruct
 322   | lapply (drops_inv_drop1 … H) -H #HL
 323     elim (IH … HL) -IH -HL /3 width=8 by drops_drop, after_next, ex2_2_intro/
 324   ]
 325 ]
 326 qed-.
 327
 328 lemma drops_inv_succ: ∀l,L1,L2. ⬇*[⫯l] L1 ≡ L2 →
 329                       ∃∃I,K,V. ⬇*[l] K ≡ L2 & L1 = K.ⓑ{I}V.
 330 #l #L1 #L2 #H elim (drops_inv_isuni … H) -H // *
 331 [ #H elim (isid_inv_next … H) -H //
 332 | /2 width=5 by ex2_3_intro/
 333 ]
 334 qed-.
 335
 336 (* Properties with uniform relocations **************************************)
 337
 338 lemma drops_F_uni: ∀L,i. ⬇*[Ⓕ, 𝐔❴i❵] L ≡ ⋆ ∨ ∃∃I,K,V. ⬇*[i] L ≡ K.ⓑ{I}V.
 339 #L elim L -L /2 width=1 by or_introl/
 340 #L #I #V #IH * /4 width=4 by drops_refl, ex1_3_intro, or_intror/
 341 #i elim (IH i) -IH /3 width=1 by drops_drop, or_introl/
 342 * /4 width=4 by drops_drop, ex1_3_intro, or_intror/
 343 qed-.
 344
 345 (* Basic_2A1: includes: drop_split *)
 346 lemma drops_split_trans: ∀b,f,L1,L2. ⬇*[b, f] L1 ≡ L2 → ∀f1,f2. f1 ⊚ f2 ≡ f → 𝐔⦃f1⦄ →
 347                          ∃∃L. ⬇*[b, f1] L1 ≡ L & ⬇*[b, f2] L ≡ L2.
 348 #b #f #L1 #L2 #H elim H -f -L1 -L2
 349 [ #f #H0f #f1 #f2 #Hf #Hf1 @(ex2_intro … (⋆)) @drops_atom
 350   #H lapply (H0f H) -b
 351   #H elim (after_inv_isid3 … Hf H) -f //
 352 | #f #I #L1 #L2 #V #HL12 #IHL12 #f1 #f2 #Hf #Hf1 elim (after_inv_xxn … Hf) -Hf [1,3: * |*: // ]
 353   [ #g1 #g2 #Hf #H1 #H2 destruct
 354     lapply (isuni_inv_push … Hf1 ??) -Hf1 [1,2: // ] #Hg1
 355     elim (IHL12 … Hf) -f
 356     /4 width=5 by drops_drop, drops_skip, lifts_refl, isuni_isid, ex2_intro/
 357   | #g1 #Hf #H destruct elim (IHL12 … Hf) -f
 358     /3 width=5 by ex2_intro, drops_drop, isuni_inv_next/
 359   ]
 360 | #f #I #L1 #L2 #V1 #V2 #_ #HV21 #IHL12 #f1 #f2 #Hf #Hf1 elim (after_inv_xxp … Hf) -Hf [2,3: // ]
 361   #g1 #g2 #Hf #H1 #H2 destruct elim (lifts_split_trans … HV21 … Hf) -HV21
 362   elim (IHL12 … Hf) -f /3 width=5 by ex2_intro, drops_skip, isuni_fwd_push/
 363 ]
 364 qed-.
 365
 366 lemma drops_split_div: ∀b,f1,L1,L. ⬇*[b, f1] L1 ≡ L → ∀f2,f. f1 ⊚ f2 ≡ f → 𝐔⦃f2⦄ →
 367                        ∃∃L2. ⬇*[Ⓕ, f2] L ≡ L2 & ⬇*[Ⓕ, f] L1 ≡ L2.
 368 #b #f1 #L1 #L #H elim H -f1 -L1 -L
 369 [ #f1 #Hf1 #f2 #f #Hf #Hf2 @(ex2_intro … (⋆)) @drops_atom #H destruct
 370 | #f1 #I #L1 #L #V #HL1 #IH #f2 #f #Hf #Hf2 elim (after_inv_nxx … Hf) -Hf [2,3: // ]
 371   #g #Hg #H destruct elim (IH … Hg) -IH -Hg /3 width=5 by drops_drop, ex2_intro/
 372 | #f1 #I #L1 #L #V1 #V #HL1 #HV1 #IH #f2 #f #Hf #Hf2
 373   elim (after_inv_pxx … Hf) -Hf [1,3: * |*: // ]
 374   #g2 #g #Hg #H2 #H0 destruct
 375   [ lapply (isuni_inv_push … Hf2 ??) -Hf2 [1,2: // ] #Hg2 -IH
 376     lapply (after_isid_inv_dx … Hg … Hg2) -Hg #Hg
 377     /5 width=7 by drops_eq_repl_back, drops_F, drops_refl, drops_skip, lifts_eq_repl_back, isid_push, ex2_intro/
 378   | lapply (isuni_inv_next … Hf2 ??) -Hf2 [1,2: // ] #Hg2 -HL1 -HV1
 379     elim (IH … Hg) -f1 /3 width=3 by drops_drop, ex2_intro/
 380   ]
 381 ]
 382 qed-.
 383
 384 (* Properties with application **********************************************)
 385
 386 lemma drops_tls_at: ∀f,i1,i2. @⦃i1,f⦄ ≡ i2 →
 387                     ∀b,L1,L2. ⬇*[b,⫱*[i2]f] L1 ≡ L2 →
 388                     ⬇*[b,↑⫱*[⫯i2]f] L1 ≡ L2.
 389 /3 width=3 by drops_eq_repl_fwd, at_inv_tls/ qed-.
 390
 391 lemma drops_split_trans_pair2: ∀b,f,I,L,K0,V. ⬇*[b, f] L ≡ K0.ⓑ{I}V → ∀n. @⦃O, f⦄ ≡ n →
 392                                ∃∃K,W. ⬇*[n]L ≡ K.ⓑ{I}W & ⬇*[b, ⫱*[⫯n]f] K ≡ K0 & ⬆*[⫱*[⫯n]f] V ≡ W.
 393 #b #f #I #L #K0 #V #H #n #Hf
 394 elim (drops_split_trans … H) -H [ |5: @(after_uni_dx … Hf) |2,3: skip ] /2 width=1 by after_isid_dx/ #Y #HLY #H
 395 lapply (drops_tls_at … Hf … H) -H #H
 396 elim (drops_inv_skip2 … H) -H #K #W #HK0 #HVW #H destruct
 397 /3 width=5 by drops_inv_gen, ex3_2_intro/
 398 qed-.
 399
 400 (* Basic_2A1: removed theorems 12:
 401               drops_inv_nil drops_inv_cons d1_liftable_liftables
 402               drop_refl_atom_O2 drop_inv_pair1
 403               drop_inv_Y1 drop_Y1 drop_O_Y drop_fwd_Y2
 404               drop_fwd_length_minus2 drop_fwd_length_minus4
 405 *)
 406 (* Basic_1: removed theorems 53:
 407             drop1_gen_pnil drop1_gen_pcons drop1_getl_trans
 408             drop_ctail drop_skip_flat
 409             cimp_flat_sx cimp_flat_dx cimp_bind cimp_getl_conf
 410             drop_clear drop_clear_O drop_clear_S
 411             clear_gen_sort clear_gen_bind clear_gen_flat clear_gen_flat_r
 412             clear_gen_all clear_clear clear_mono clear_trans clear_ctail clear_cle
 413             getl_ctail_clen getl_gen_tail clear_getl_trans getl_clear_trans
 414             getl_clear_bind getl_clear_conf getl_dec getl_drop getl_drop_conf_lt
 415             getl_drop_conf_ge getl_conf_ge_drop getl_drop_conf_rev
 416             drop_getl_trans_lt drop_getl_trans_le drop_getl_trans_ge
 417             getl_drop_trans getl_flt getl_gen_all getl_gen_sort getl_gen_O
 418             getl_gen_S getl_gen_2 getl_gen_flat getl_gen_bind getl_conf_le
 419             getl_trans getl_refl getl_head getl_flat getl_ctail getl_mono
 420 *)