matita/matita/contribs/lambdadelta/basic_2/relocation/drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/rdropstar_3.ma".
  16 include "basic_2/notation/relations/rdropstar_4.ma".
  17 include "basic_2/relocation/lreq.ma".
  18 include "basic_2/relocation/lifts.ma".
  19
  20 (* GENERIC SLICING FOR LOCAL ENVIRONMENTS ***********************************)
  21
  22 (* Basic_1: includes: drop_skip_bind drop1_skip_bind *)
  23 (* Basic_2A1: includes: drop_atom drop_pair drop_drop drop_skip
  24                         drop_refl_atom_O2 drop_drop_lt drop_skip_lt
  25 *)
  26 inductive drops (c:bool): rtmap → relation lenv ≝
  27 | drops_atom: ∀f. (c = Ⓣ → 𝐈⦃f⦄) → drops c (f) (⋆) (⋆)
  28 | drops_drop: ∀I,L1,L2,V,f. drops c f L1 L2 → drops c (⫯f) (L1.ⓑ{I}V) L2
  29 | drops_skip: ∀I,L1,L2,V1,V2,f.
  30               drops c f L1 L2 → ⬆*[f] V2 ≡ V1 →
  31               drops c (↑f) (L1.ⓑ{I}V1) (L2.ⓑ{I}V2)
  32 .
  33
  34 interpretation "uniform slicing (local environment)"
  35    'RDropStar i L1 L2 = (drops true (uni i) L1 L2).
  36
  37 interpretation "generic slicing (local environment)"
  38    'RDropStar c f L1 L2 = (drops c f L1 L2).
  39
  40 definition d_liftable1: relation2 lenv term → predicate bool ≝
  41                         λR,c. ∀L,K,f. ⬇*[c, f] L ≡ K →
  42                         ∀T,U. ⬆*[f] T ≡ U → R K T → R L U.
  43
  44 definition d_liftable2: predicate (lenv → relation term) ≝
  45                         λR. ∀K,T1,T2. R K T1 T2 → ∀L,c,f. ⬇*[c, f] L ≡ K →
  46                         ∀U1. ⬆*[f] T1 ≡ U1 →
  47                         ∃∃U2. ⬆*[f] T2 ≡ U2 & R L U1 U2.
  48
  49 definition d_deliftable2_sn: predicate (lenv → relation term) ≝
  50                              λR. ∀L,U1,U2. R L U1 U2 → ∀K,c,f. ⬇*[c, f] L ≡ K →
  51                              ∀T1. ⬆*[f] T1 ≡ U1 →
  52                              ∃∃T2. ⬆*[f] T2 ≡ U2 & R K T1 T2.
  53
  54 definition dropable_sn: predicate (rtmap → relation lenv) ≝
  55                         λR. ∀L1,K1,c,f. ⬇*[c, f] L1 ≡ K1 → ∀L2,f2. R f2 L1 L2 →
  56                         ∀f1. f ⊚ f1 ≡ f2 →
  57                         ∃∃K2. R f1 K1 K2 & ⬇*[c, f] L2 ≡ K2.
  58
  59 definition dropable_dx: predicate (rtmap → relation lenv) ≝
  60                         λR. ∀L1,L2,f2. R f2 L1 L2 →
  61                         ∀K2,c,f. ⬇*[c, f] L2 ≡ K2 →  𝐔⦃f⦄ →
  62                         ∀f1. f ⊚ f1 ≡ f2 →
  63                         ∃∃K1. ⬇*[c, f] L1 ≡ K1 & R f1 K1 K2.
  64
  65 definition dedropable_sn: predicate (rtmap → relation lenv) ≝
  66                           λR. ∀L1,K1,c,f. ⬇*[c, f] L1 ≡ K1 → ∀K2,f1. R f1 K1 K2 →
  67                           ∀f2. f ⊚ f1 ≡ f2 →
  68                           ∃∃L2. R f2 L1 L2 & ⬇*[c, f] L2 ≡ K2 & L1 ≡[f] L2.
  69
  70 (* Basic properties *********************************************************)
  71
  72 lemma drops_eq_repl_back: ∀L1,L2,c. eq_repl_back … (λf. ⬇*[c, f] L1 ≡ L2).
  73 #L1 #L2 #c #f1 #H elim H -L1 -L2 -f1
  74 [ /4 width=3 by drops_atom, isid_eq_repl_back/
  75 | #I #L1 #L2 #V #f1 #_ #IH #f2 #H elim (eq_inv_nx … H) -H
  76   /3 width=3 by drops_drop/
  77 | #I #L1 #L2 #V1 #v2 #f1 #_ #HV #IH #f2 #H elim (eq_inv_px … H) -H
  78   /3 width=3 by drops_skip, lifts_eq_repl_back/
  79 ]
  80 qed-.
  81
  82 lemma drops_eq_repl_fwd: ∀L1,L2,c. eq_repl_fwd … (λf. ⬇*[c, f] L1 ≡ L2).
  83 #L1 #L2 #c @eq_repl_sym /2 width=3 by drops_eq_repl_back/ (**) (* full auto fails *)
  84 qed-.
  85
  86 lemma drops_inv_tls_at: ∀f,i1,i2. @⦃i1,f⦄ ≡ i2 →
  87                         ∀c, L1,L2. ⬇*[c,⫱*[i2]f] L1 ≡ L2 →
  88                         ⬇*[c,↑⫱*[⫯i2]f] L1 ≡ L2.
  89 /3 width=3 by drops_eq_repl_fwd, at_inv_tls/ qed-.
  90
  91 (* Basic_2A1: includes: drop_FT *)
  92 lemma drops_TF: ∀L1,L2,f. ⬇*[Ⓣ, f] L1 ≡ L2 → ⬇*[Ⓕ, f] L1 ≡ L2.
  93 #L1 #L2 #f #H elim H -L1 -L2 -f
  94 /3 width=1 by drops_atom, drops_drop, drops_skip/
  95 qed.
  96
  97 (* Basic_2A1: includes: drop_gen *)
  98 lemma drops_gen: ∀L1,L2,c,f. ⬇*[Ⓣ, f] L1 ≡ L2 → ⬇*[c, f] L1 ≡ L2.
  99 #L1 #L2 * /2 width=1 by drops_TF/
 100 qed-.
 101
 102 (* Basic_2A1: includes: drop_T *)
 103 lemma drops_F: ∀L1,L2,c,f. ⬇*[c, f] L1 ≡ L2 → ⬇*[Ⓕ, f] L1 ≡ L2.
 104 #L1 #L2 * /2 width=1 by drops_TF/
 105 qed-.
 106
 107 (* Basic_2A1: includes: drop_refl *)
 108 lemma drops_refl: ∀c,L,f. 𝐈⦃f⦄ → ⬇*[c, f] L ≡ L.
 109 #c #L elim L -L /2 width=1 by drops_atom/
 110 #L #I #V #IHL #f #Hf elim (isid_inv_gen … Hf) -Hf
 111 /3 width=1 by drops_skip, lifts_refl/
 112 qed.
 113
 114 (* Basic_2A1: includes: drop_split *)
 115 lemma drops_split_trans: ∀L1,L2,f,c. ⬇*[c, f] L1 ≡ L2 → ∀f1,f2. f1 ⊚ f2 ≡ f → 𝐔⦃f1⦄ →
 116                          ∃∃L. ⬇*[c, f1] L1 ≡ L & ⬇*[c, f2] L ≡ L2.
 117 #L1 #L2 #f #c #H elim H -L1 -L2 -f
 118 [ #f #Hc #f1 #f2 #Hf #Hf1 @(ex2_intro … (⋆)) @drops_atom
 119   #H lapply (Hc H) -c
 120   #H elim (after_inv_isid3 … Hf H) -f //
 121 | #I #L1 #L2 #V #f #HL12 #IHL12 #f1 #f2 #Hf #Hf1 elim (after_inv_xxn … Hf) -Hf [1,3: * |*: // ]
 122   [ #g1 #g2 #Hf #H1 #H2 destruct
 123     lapply (isuni_inv_push … Hf1 ??) -Hf1 [1,2: // ] #Hg1
 124     elim (IHL12 … Hf) -f
 125     /4 width=5 by drops_drop, drops_skip, lifts_refl, isuni_isid, ex2_intro/
 126   | #g1 #Hf #H destruct elim (IHL12 … Hf) -f
 127     /3 width=5 by ex2_intro, drops_drop, isuni_inv_next/
 128   ]
 129 | #I #L1 #L2 #V1 #V2 #f #_ #HV21 #IHL12 #f1 #f2 #Hf #Hf1 elim (after_inv_xxp … Hf) -Hf [2,3: // ]
 130   #g1 #g2 #Hf #H1 #H2 destruct elim (lifts_split_trans … HV21 … Hf) -HV21
 131   elim (IHL12 … Hf) -f /3 width=5 by ex2_intro, drops_skip, isuni_fwd_push/
 132 ]
 133 qed-.
 134
 135 lemma drops_split_div: ∀L1,L,f1,c. ⬇*[c, f1] L1 ≡ L → ∀f2,f. f1 ⊚ f2 ≡ f → 𝐔⦃f2⦄ →
 136                        ∃∃L2. ⬇*[Ⓕ, f2] L ≡ L2 & ⬇*[Ⓕ, f] L1 ≡ L2.
 137 #L1 #L #f1 #c #H elim H -L1 -L -f1
 138 [ #f1 #Hc #f2 #f #Hf #Hf2 @(ex2_intro … (⋆)) @drops_atom #H destruct
 139 | #I #L1 #L #V #f1 #HL1 #IH #f2 #f #Hf #Hf2 elim (after_inv_nxx … Hf) -Hf [2,3: // ]
 140   #g #Hg #H destruct elim (IH … Hg) -IH -Hg /3 width=5 by drops_drop, ex2_intro/
 141 | #I #L1 #L #V1 #V #f1 #HL1 #HV1 #IH #f2 #f #Hf #Hf2
 142   elim (after_inv_pxx … Hf) -Hf [1,3: * |*: // ]
 143   #g2 #g #Hg #H2 #H0 destruct
 144   [ lapply (isuni_inv_push … Hf2 ??) -Hf2 [1,2: // ] #Hg2 -IH
 145     lapply (after_isid_inv_dx … Hg … Hg2) -Hg #Hg
 146     /5 width=7 by drops_eq_repl_back, drops_F, drops_refl, drops_skip, lifts_eq_repl_back, isid_push, ex2_intro/
 147   | lapply (isuni_inv_next … Hf2 ??) -Hf2 [1,2: // ] #Hg2 -HL1 -HV1
 148     elim (IH … Hg) -f1 /3 width=3 by drops_drop, ex2_intro/
 149   ]
 150 ]
 151 qed-.
 152
 153 (* Basic forward lemmas *****************************************************)
 154
 155 (* Basic_1: includes: drop_gen_refl *)
 156 (* Basic_2A1: includes: drop_inv_O2 *)
 157 lemma drops_fwd_isid: ∀L1,L2,c,f. ⬇*[c, f] L1 ≡ L2 → 𝐈⦃f⦄ → L1 = L2.
 158 #L1 #L2 #c #f #H elim H -L1 -L2 -f //
 159 [ #I #L1 #L2 #V #f #_ #_ #H elim (isid_inv_next … H) //
 160 | /5 width=5 by isid_inv_push, lifts_fwd_isid, eq_f3, sym_eq/
 161 ]
 162 qed-.
 163
 164 fact drops_fwd_drop2_aux: ∀X,Y,c,f2. ⬇*[c, f2] X ≡ Y → ∀I,K,V. Y = K.ⓑ{I}V →
 165                           ∃∃f1,f. 𝐈⦃f1⦄ & f2 ⊚ ⫯f1 ≡ f & ⬇*[c, f] X ≡ K.
 166 #X #Y #c #f2 #H elim H -X -Y -f2
 167 [ #f2 #Ht2 #J #K #W #H destruct
 168 | #I #L1 #L2 #V #f2 #_ #IHL #J #K #W #H elim (IHL … H) -IHL
 169   /3 width=7 by after_next, ex3_2_intro, drops_drop/
 170 | #I #L1 #L2 #V1 #V2 #f2 #HL #_ #_ #J #K #W #H destruct
 171   lapply (isid_after_dx 𝐈𝐝 … f2) /3 width=9 by after_push, ex3_2_intro, drops_drop/
 172 ]
 173 qed-.
 174
 175 lemma drops_fwd_drop2: ∀I,X,K,V,c,f2. ⬇*[c, f2] X ≡ K.ⓑ{I}V →
 176                        ∃∃f1,f. 𝐈⦃f1⦄ & f2 ⊚ ⫯f1 ≡ f & ⬇*[c, f] X ≡ K.
 177 /2 width=5 by drops_fwd_drop2_aux/ qed-.
 178
 179 lemma drops_after_fwd_drop2: ∀I,X,K,V,c,f2. ⬇*[c, f2] X ≡ K.ⓑ{I}V →
 180                              ∀f1,f. 𝐈⦃f1⦄ → f2 ⊚ ⫯f1 ≡ f → ⬇*[c, f] X ≡ K.
 181 #I #X #K #V #c #f2 #H #f1 #f #Hf1 #Hf elim (drops_fwd_drop2 … H) -H
 182 #g1 #g #Hg1 #Hg #HK lapply (after_mono_eq … Hg … Hf ??) -Hg -Hf
 183 /3 width=5 by drops_eq_repl_back, isid_inv_eq_repl, eq_next/
 184 qed-.
 185
 186 (* Basic_1: was: drop_S *)
 187 (* Basic_2A1: was: drop_fwd_drop2 *)
 188 lemma drops_isuni_fwd_drop2: ∀I,X,K,V,c,f. 𝐔⦃f⦄ → ⬇*[c, f] X ≡ K.ⓑ{I}V → ⬇*[c, ⫯f] X ≡ K.
 189 /3 width=7 by drops_after_fwd_drop2, after_isid_isuni/ qed-.
 190
 191 (* Forward lemmas with test for finite colength *****************************)
 192
 193 lemma drops_fwd_isfin: ∀L1,L2,f. ⬇*[Ⓣ, f] L1 ≡ L2 → 𝐅⦃f⦄.
 194 #L1 #L2 #f #H elim H -L1 -L2 -f
 195 /3 width=1 by isfin_next, isfin_push, isfin_isid/
 196 qed-.
 197
 198 (* Basic inversion lemmas ***************************************************)
 199
 200 fact drops_inv_atom1_aux: ∀X,Y,c,f. ⬇*[c, f] X ≡ Y → X = ⋆ →
 201                           Y = ⋆ ∧ (c = Ⓣ → 𝐈⦃f⦄).
 202 #X #Y #c #f * -X -Y -f
 203 [ /3 width=1 by conj/
 204 | #I #L1 #L2 #V #f #_ #H destruct
 205 | #I #L1 #L2 #V1 #V2 #f #_ #_ #H destruct
 206 ]
 207 qed-.
 208
 209 (* Basic_1: includes: drop_gen_sort *)
 210 (* Basic_2A1: includes: drop_inv_atom1 *)
 211 lemma drops_inv_atom1: ∀Y,c,f. ⬇*[c, f] ⋆ ≡ Y → Y = ⋆ ∧ (c = Ⓣ → 𝐈⦃f⦄).
 212 /2 width=3 by drops_inv_atom1_aux/ qed-.
 213
 214 fact drops_inv_drop1_aux: ∀X,Y,c,f. ⬇*[c, f] X ≡ Y → ∀I,K,V,g. X = K.ⓑ{I}V → f = ⫯g →
 215                           ⬇*[c, g] K ≡ Y.
 216 #X #Y #c #f * -X -Y -f
 217 [ #f #Ht #J #K #W #g #H destruct
 218 | #I #L1 #L2 #V #f #HL #J #K #W #g #H1 #H2 <(injective_next … H2) -g destruct //
 219 | #I #L1 #L2 #V1 #V2 #f #_ #_ #J #K #W #g #_ #H2 elim (discr_push_next … H2)
 220 ]
 221 qed-.
 222
 223 (* Basic_1: includes: drop_gen_drop *)
 224 (* Basic_2A1: includes: drop_inv_drop1_lt drop_inv_drop1 *)
 225 lemma drops_inv_drop1: ∀I,K,Y,V,c,f. ⬇*[c, ⫯f] K.ⓑ{I}V ≡ Y → ⬇*[c, f] K ≡ Y.
 226 /2 width=7 by drops_inv_drop1_aux/ qed-.
 227
 228
 229 fact drops_inv_skip1_aux: ∀X,Y,c,f. ⬇*[c, f] X ≡ Y → ∀I,K1,V1,g. X = K1.ⓑ{I}V1 → f = ↑g →
 230                           ∃∃K2,V2. ⬇*[c, g] K1 ≡ K2 & ⬆*[g] V2 ≡ V1 & Y = K2.ⓑ{I}V2.
 231 #X #Y #c #f * -X -Y -f
 232 [ #f #Ht #J #K1 #W1 #g #H destruct
 233 | #I #L1 #L2 #V #f #_ #J #K1 #W1 #g #_ #H2 elim (discr_next_push … H2)
 234 | #I #L1 #L2 #V1 #V2 #f #HL #HV #J #K1 #W1 #g #H1 #H2 <(injective_push … H2) -g destruct
 235   /2 width=5 by ex3_2_intro/
 236 ]
 237 qed-.
 238
 239 (* Basic_1: includes: drop_gen_skip_l *)
 240 (* Basic_2A1: includes: drop_inv_skip1 *)
 241 lemma drops_inv_skip1: ∀I,K1,V1,Y,c,f. ⬇*[c, ↑f] K1.ⓑ{I}V1 ≡ Y →
 242                        ∃∃K2,V2. ⬇*[c, f] K1 ≡ K2 & ⬆*[f] V2 ≡ V1 & Y = K2.ⓑ{I}V2.
 243 /2 width=5 by drops_inv_skip1_aux/ qed-.
 244
 245 fact drops_inv_skip2_aux: ∀X,Y,c,f. ⬇*[c, f] X ≡ Y → ∀I,K2,V2,g. Y = K2.ⓑ{I}V2 → f = ↑g →
 246                           ∃∃K1,V1. ⬇*[c, g] K1 ≡ K2 & ⬆*[g] V2 ≡ V1 & X = K1.ⓑ{I}V1.
 247 #X #Y #c #f * -X -Y -f
 248 [ #f #Ht #J #K2 #W2 #g #H destruct
 249 | #I #L1 #L2 #V #f #_ #J #K2 #W2 #g #_ #H2 elim (discr_next_push … H2)
 250 | #I #L1 #L2 #V1 #V2 #f #HL #HV #J #K2 #W2 #g #H1 #H2 <(injective_push … H2) -g destruct
 251   /2 width=5 by ex3_2_intro/
 252 ]
 253 qed-.
 254
 255 (* Basic_1: includes: drop_gen_skip_r *)
 256 (* Basic_2A1: includes: drop_inv_skip2 *)
 257 lemma drops_inv_skip2: ∀I,X,K2,V2,c,f. ⬇*[c, ↑f] X ≡ K2.ⓑ{I}V2 →
 258                        ∃∃K1,V1. ⬇*[c, f] K1 ≡ K2 & ⬆*[f] V2 ≡ V1 & X = K1.ⓑ{I}V1.
 259 /2 width=5 by drops_inv_skip2_aux/ qed-.
 260
 261 fact drops_inv_TF_aux: ∀L1,L2,f. ⬇*[Ⓕ, f] L1 ≡ L2 → 𝐔⦃f⦄ →
 262                        ∀I,K,V. L2 = K.ⓑ{I}V →
 263                        ⬇*[Ⓣ, f] L1 ≡ K.ⓑ{I}V.
 264 #L1 #L2 #f #H elim H -L1 -L2 -f
 265 [ #f #_ #_ #J #K #W #H destruct
 266 | #I #L1 #L2 #V #f #_ #IH #Hf #J #K #W #H destruct
 267   /4 width=3 by drops_drop, isuni_inv_next/
 268 | #I #L1 #L2 #V1 #V2 #f #HL12 #HV21 #_ #Hf #J #K #W #H destruct
 269   lapply (isuni_inv_push … Hf ??) -Hf [1,2: // ] #Hf
 270   <(drops_fwd_isid … HL12) -K // <(lifts_fwd_isid … HV21) -V1
 271   /3 width=3 by drops_refl, isid_push/
 272 ]
 273 qed-.
 274
 275 (* Basic_2A1: includes: drop_inv_FT *)
 276 lemma drops_inv_TF: ∀I,L,K,V,f. ⬇*[Ⓕ, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 277                     ⬇*[Ⓣ, f] L ≡ K.ⓑ{I}V.
 278 /2 width=3 by drops_inv_TF_aux/ qed-.
 279
 280 (* Advanced inversion lemmas ************************************************)
 281
 282 (* Basic_2A1: includes: drop_inv_gen *)
 283 lemma drops_inv_gen: ∀I,L,K,V,c,f. ⬇*[c, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 284                      ⬇*[Ⓣ, f] L ≡ K.ⓑ{I}V.
 285 #I #L #K #V * /2 width=1 by drops_inv_TF/
 286 qed-.
 287
 288 (* Basic_2A1: includes: drop_inv_T *)
 289 lemma drops_inv_F: ∀I,L,K,V,c,f. ⬇*[Ⓕ, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 290                    ⬇*[c, f] L ≡ K.ⓑ{I}V.
 291 #I #L #K #V * /2 width=1 by drops_inv_TF/
 292 qed-.
 293
 294 (* Inversion lemmas with test for uniformity ********************************)
 295
 296 lemma drops_inv_isuni: ∀L1,L2,f. ⬇*[Ⓣ, f] L1 ≡ L2 → 𝐔⦃f⦄ →
 297                        (𝐈⦃f⦄ ∧ L1 = L2) ∨
 298                        ∃∃I,K,V,g. ⬇*[Ⓣ, g] K ≡ L2 & 𝐔⦃g⦄ & L1 = K.ⓑ{I}V & f = ⫯g.
 299 #L1 #L2 #f * -L1 -L2 -f
 300 [ /4 width=1 by or_introl, conj/
 301 | /4 width=8 by isuni_inv_next, ex4_4_intro, or_intror/
 302 | /7 width=6 by drops_fwd_isid, lifts_fwd_isid, isuni_inv_push, isid_push, or_introl, conj, eq_f3, sym_eq/
 303 ]
 304 qed-.
 305
 306 (* Basic_2A1: was: drop_inv_O1_pair1 *)
 307 lemma drops_inv_pair1_isuni: ∀I,K,L2,V,c,f. 𝐔⦃f⦄ → ⬇*[c, f] K.ⓑ{I}V ≡ L2 →
 308                              (𝐈⦃f⦄ ∧ L2 = K.ⓑ{I}V) ∨
 309                              ∃∃g. 𝐔⦃g⦄ & ⬇*[c, g] K ≡ L2 & f = ⫯g.
 310 #I #K #L2 #V #c #f #Hf #H elim (isuni_split … Hf) -Hf * #g #Hg #H0 destruct
 311 [ lapply (drops_inv_skip1 … H) -H * #Y #X #HY #HX #H destruct
 312   <(drops_fwd_isid … HY Hg) -Y >(lifts_fwd_isid … HX Hg) -X
 313   /4 width=3 by isid_push, or_introl, conj/
 314 | lapply (drops_inv_drop1 … H) -H /3 width=4 by ex3_intro, or_intror/
 315 ]
 316 qed-.
 317
 318 (* Basic_2A1: was: drop_inv_O1_pair2 *)
 319 lemma drops_inv_pair2_isuni: ∀I,K,V,c,f,L1. 𝐔⦃f⦄ → ⬇*[c, f] L1 ≡ K.ⓑ{I}V →
 320                              (𝐈⦃f⦄ ∧ L1 = K.ⓑ{I}V) ∨
 321                              ∃∃I1,K1,V1,g. 𝐔⦃g⦄ & ⬇*[c, g] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1 & f = ⫯g.
 322 #I #K #V #c #f *
 323 [ #Hf #H elim (drops_inv_atom1 … H) -H #H destruct
 324 | #L1 #I1 #V1 #Hf #H elim (drops_inv_pair1_isuni … Hf H) -Hf -H *
 325   [ #Hf #H destruct /3 width=1 by or_introl, conj/
 326   | /3 width=8 by ex4_4_intro, or_intror/
 327   ]
 328 ]
 329 qed-.
 330
 331 lemma drops_inv_pair2_isuni_next: ∀I,K,V,c,f,L1. 𝐔⦃f⦄ → ⬇*[c, ⫯f] L1 ≡ K.ⓑ{I}V →
 332                                   ∃∃I1,K1,V1. ⬇*[c, f] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1.
 333 #I #K #V #c #f #L1 #Hf #H elim (drops_inv_pair2_isuni … H) -H /2 width=3 by isuni_next/ -Hf *
 334 [ #H elim (isid_inv_next … H) -H //
 335 | /2 width=5 by ex2_3_intro/
 336 ]
 337 qed-.
 338
 339 (* Inversion lemmas with uniform relocations ********************************)
 340
 341 lemma drops_inv_succ: ∀L1,L2,l. ⬇*[⫯l] L1 ≡ L2 →
 342                       ∃∃I,K,V. ⬇*[l] K ≡ L2 & L1 = K.ⓑ{I}V.
 343 #L1 #L2 #l #H elim (drops_inv_isuni … H) -H // *
 344 [ #H elim (isid_inv_next … H) -H //
 345 | /2 width=5 by ex2_3_intro/
 346 ]
 347 qed-.
 348
 349 (* Basic_2A1: removed theorems 12:
 350               drops_inv_nil drops_inv_cons d1_liftable_liftables
 351               drop_refl_atom_O2 drop_inv_pair1
 352               drop_inv_Y1 drop_Y1 drop_O_Y drop_fwd_Y2
 353               drop_fwd_length_minus2 drop_fwd_length_minus4
 354 *)
 355 (* Basic_1: removed theorems 53:
 356             drop1_gen_pnil drop1_gen_pcons drop1_getl_trans
 357             drop_ctail drop_skip_flat
 358             cimp_flat_sx cimp_flat_dx cimp_bind cimp_getl_conf
 359             drop_clear drop_clear_O drop_clear_S
 360             clear_gen_sort clear_gen_bind clear_gen_flat clear_gen_flat_r
 361             clear_gen_all clear_clear clear_mono clear_trans clear_ctail clear_cle
 362             getl_ctail_clen getl_gen_tail clear_getl_trans getl_clear_trans
 363             getl_clear_bind getl_clear_conf getl_dec getl_drop getl_drop_conf_lt
 364             getl_drop_conf_ge getl_conf_ge_drop getl_drop_conf_rev
 365             drop_getl_trans_lt drop_getl_trans_le drop_getl_trans_ge
 366             getl_drop_trans getl_flt getl_gen_all getl_gen_sort getl_gen_O
 367             getl_gen_S getl_gen_2 getl_gen_flat getl_gen_bind getl_conf_le
 368             getl_trans getl_refl getl_head getl_flat getl_ctail getl_mono
 369 *)