matita/matita/contribs/lambdadelta/basic_2/relocation/drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/rdropstar_3.ma".
  16 include "basic_2/notation/relations/rdropstar_4.ma".
  17 include "basic_2/relocation/lreq.ma".
  18 include "basic_2/relocation/lifts.ma".
  19
  20 (* GENERIC SLICING FOR LOCAL ENVIRONMENTS ***********************************)
  21
  22 (* Basic_1: includes: drop_skip_bind drop1_skip_bind *)
  23 (* Basic_2A1: includes: drop_atom drop_pair drop_drop drop_skip
  24                         drop_refl_atom_O2 drop_drop_lt drop_skip_lt
  25 *)
  26 inductive drops (b:bool): rtmap → relation lenv ≝
  27 | drops_atom: ∀f. (b = Ⓣ → 𝐈⦃f⦄) → drops b (f) (⋆) (⋆)
  28 | drops_drop: ∀f,I,L1,L2,V. drops b f L1 L2 → drops b (⫯f) (L1.ⓑ{I}V) L2
  29 | drops_skip: ∀f,I,L1,L2,V1,V2.
  30               drops b f L1 L2 → ⬆*[f] V2 ≡ V1 →
  31               drops b (↑f) (L1.ⓑ{I}V1) (L2.ⓑ{I}V2)
  32 .
  33
  34 interpretation "uniform slicing (local environment)"
  35    'RDropStar i L1 L2 = (drops true (uni i) L1 L2).
  36
  37 interpretation "generic slicing (local environment)"
  38    'RDropStar b f L1 L2 = (drops b f L1 L2).
  39
  40 definition d_liftable1: relation2 lenv term → predicate bool ≝
  41                         λR,b. ∀f,L,K. ⬇*[b, f] L ≡ K →
  42                         ∀T,U. ⬆*[f] T ≡ U → R K T → R L U.
  43
  44 definition d_liftable2: predicate (lenv → relation term) ≝
  45                         λR. ∀K,T1,T2. R K T1 T2 → ∀b,f,L. ⬇*[b, f] L ≡ K →
  46                         ∀U1. ⬆*[f] T1 ≡ U1 →
  47                         ∃∃U2. ⬆*[f] T2 ≡ U2 & R L U1 U2.
  48
  49 definition d_deliftable2_sn: predicate (lenv → relation term) ≝
  50                              λR. ∀L,U1,U2. R L U1 U2 → ∀b,f,K. ⬇*[b, f] L ≡ K →
  51                              ∀T1. ⬆*[f] T1 ≡ U1 →
  52                              ∃∃T2. ⬆*[f] T2 ≡ U2 & R K T1 T2.
  53
  54 definition dropable_sn: predicate (rtmap → relation lenv) ≝
  55                         λR. ∀b,f,L1,K1. ⬇*[b, f] L1 ≡ K1 → ∀f2,L2. R f2 L1 L2 →
  56                         ∀f1. f ⊚ f1 ≡ f2 →
  57                         ∃∃K2. R f1 K1 K2 & ⬇*[b, f] L2 ≡ K2.
  58
  59 definition dropable_dx: predicate (rtmap → relation lenv) ≝
  60                         λR. ∀f2,L1,L2. R f2 L1 L2 →
  61                         ∀b,f,K2. ⬇*[b, f] L2 ≡ K2 →  𝐔⦃f⦄ →
  62                         ∀f1. f ⊚ f1 ≡ f2 →
  63                         ∃∃K1. ⬇*[b, f] L1 ≡ K1 & R f1 K1 K2.
  64
  65 definition dedropable_sn: predicate (rtmap → relation lenv) ≝
  66                           λR. ∀b,f,L1,K1. ⬇*[b, f] L1 ≡ K1 → ∀f1,K2. R f1 K1 K2 →
  67                           ∀f2. f ⊚ f1 ≡ f2 →
  68                           ∃∃L2. R f2 L1 L2 & ⬇*[b, f] L2 ≡ K2 & L1 ≡[f] L2.
  69
  70 (* Basic properties *********************************************************)
  71
  72 lemma drops_atom_F: ∀f. ⬇*[Ⓕ, f] ⋆ ≡ ⋆.
  73 #f @drops_atom #H destruct
  74 qed.
  75
  76 lemma drops_eq_repl_back: ∀b,L1,L2. eq_repl_back … (λf. ⬇*[b, f] L1 ≡ L2).
  77 #b #L1 #L2 #f1 #H elim H -f1 -L1 -L2
  78 [ /4 width=3 by drops_atom, isid_eq_repl_back/
  79 | #f1 #I #L1 #L2 #V #_ #IH #f2 #H elim (eq_inv_nx … H) -H
  80   /3 width=3 by drops_drop/
  81 | #f1 #I #L1 #L2 #V1 #v2 #_ #HV #IH #f2 #H elim (eq_inv_px … H) -H
  82   /3 width=3 by drops_skip, lifts_eq_repl_back/
  83 ]
  84 qed-.
  85
  86 lemma drops_eq_repl_fwd: ∀b,L1,L2. eq_repl_fwd … (λf. ⬇*[b, f] L1 ≡ L2).
  87 #b #L1 #L2 @eq_repl_sym /2 width=3 by drops_eq_repl_back/ (**) (* full auto fails *)
  88 qed-.
  89
  90 (* Basic_2A1: includes: drop_FT *)
  91 lemma drops_TF: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → ⬇*[Ⓕ, f] L1 ≡ L2.
  92 #f #L1 #L2 #H elim H -f -L1 -L2
  93 /3 width=1 by drops_atom, drops_drop, drops_skip/
  94 qed.
  95
  96 (* Basic_2A1: includes: drop_gen *)
  97 lemma drops_gen: ∀b,f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → ⬇*[b, f] L1 ≡ L2.
  98 * /2 width=1 by drops_TF/
  99 qed-.
 100
 101 (* Basic_2A1: includes: drop_T *)
 102 lemma drops_F: ∀b,f,L1,L2. ⬇*[b, f] L1 ≡ L2 → ⬇*[Ⓕ, f] L1 ≡ L2.
 103 * /2 width=1 by drops_TF/
 104 qed-.
 105
 106 (* Basic inversion lemmas ***************************************************)
 107
 108 fact drops_inv_atom1_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → X = ⋆ →
 109                           Y = ⋆ ∧ (b = Ⓣ → 𝐈⦃f⦄).
 110 #b #f #X #Y * -f -X -Y
 111 [ /3 width=1 by conj/
 112 | #f #I #L1 #L2 #V #_ #H destruct
 113 | #f #I #L1 #L2 #V1 #V2 #_ #_ #H destruct
 114 ]
 115 qed-.
 116
 117 (* Basic_1: includes: drop_gen_sort *)
 118 (* Basic_2A1: includes: drop_inv_atom1 *)
 119 lemma drops_inv_atom1: ∀b,f,Y. ⬇*[b, f] ⋆ ≡ Y → Y = ⋆ ∧ (b = Ⓣ → 𝐈⦃f⦄).
 120 /2 width=3 by drops_inv_atom1_aux/ qed-.
 121
 122 fact drops_inv_drop1_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → ∀g,I,K,V. X = K.ⓑ{I}V → f = ⫯g →
 123                           ⬇*[b, g] K ≡ Y.
 124 #b #f #X #Y * -f -X -Y
 125 [ #f #Hf #g #J #K #W #H destruct
 126 | #f #I #L1 #L2 #V #HL #g #J #K #W #H1 #H2 <(injective_next … H2) -g destruct //
 127 | #f #I #L1 #L2 #V1 #V2 #_ #_ #g #J #K #W #_ #H2 elim (discr_push_next … H2)
 128 ]
 129 qed-.
 130
 131 (* Basic_1: includes: drop_gen_drop *)
 132 (* Basic_2A1: includes: drop_inv_drop1_lt drop_inv_drop1 *)
 133 lemma drops_inv_drop1: ∀b,f,I,K,Y,V. ⬇*[b, ⫯f] K.ⓑ{I}V ≡ Y → ⬇*[b, f] K ≡ Y.
 134 /2 width=7 by drops_inv_drop1_aux/ qed-.
 135
 136 fact drops_inv_skip1_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → ∀g,I,K1,V1. X = K1.ⓑ{I}V1 → f = ↑g →
 137                           ∃∃K2,V2. ⬇*[b, g] K1 ≡ K2 & ⬆*[g] V2 ≡ V1 & Y = K2.ⓑ{I}V2.
 138 #b #f #X #Y * -f -X -Y
 139 [ #f #Hf #g #J #K1 #W1 #H destruct
 140 | #f #I #L1 #L2 #V #_ #g #J #K1 #W1 #_ #H2 elim (discr_next_push … H2)
 141 | #f #I #L1 #L2 #V1 #V2 #HL #HV #g #J #K1 #W1 #H1 #H2 <(injective_push … H2) -g destruct
 142   /2 width=5 by ex3_2_intro/
 143 ]
 144 qed-.
 145
 146 (* Basic_1: includes: drop_gen_skip_l *)
 147 (* Basic_2A1: includes: drop_inv_skip1 *)
 148 lemma drops_inv_skip1: ∀b,f,I,K1,V1,Y. ⬇*[b, ↑f] K1.ⓑ{I}V1 ≡ Y →
 149                        ∃∃K2,V2. ⬇*[b, f] K1 ≡ K2 & ⬆*[f] V2 ≡ V1 & Y = K2.ⓑ{I}V2.
 150 /2 width=5 by drops_inv_skip1_aux/ qed-.
 151
 152 fact drops_inv_skip2_aux: ∀b,f,X,Y. ⬇*[b, f] X ≡ Y → ∀g,I,K2,V2. Y = K2.ⓑ{I}V2 → f = ↑g →
 153                           ∃∃K1,V1. ⬇*[b, g] K1 ≡ K2 & ⬆*[g] V2 ≡ V1 & X = K1.ⓑ{I}V1.
 154 #b #f #X #Y * -f -X -Y
 155 [ #f #Hf #g #J #K2 #W2 #H destruct
 156 | #f #I #L1 #L2 #V #_ #g #J #K2 #W2 #_ #H2 elim (discr_next_push … H2)
 157 | #f #I #L1 #L2 #V1 #V2 #HL #HV #g #J #K2 #W2 #H1 #H2 <(injective_push … H2) -g destruct
 158   /2 width=5 by ex3_2_intro/
 159 ]
 160 qed-.
 161
 162 (* Basic_1: includes: drop_gen_skip_r *)
 163 (* Basic_2A1: includes: drop_inv_skip2 *)
 164 lemma drops_inv_skip2: ∀b,f,I,X,K2,V2. ⬇*[b, ↑f] X ≡ K2.ⓑ{I}V2 →
 165                        ∃∃K1,V1. ⬇*[b, f] K1 ≡ K2 & ⬆*[f] V2 ≡ V1 & X = K1.ⓑ{I}V1.
 166 /2 width=5 by drops_inv_skip2_aux/ qed-.
 167
 168 (* Basic forward lemmas *****************************************************)
 169
 170 fact drops_fwd_drop2_aux: ∀b,f2,X,Y. ⬇*[b, f2] X ≡ Y → ∀I,K,V. Y = K.ⓑ{I}V →
 171                           ∃∃f1,f. 𝐈⦃f1⦄ & f2 ⊚ ⫯f1 ≡ f & ⬇*[b, f] X ≡ K.
 172 #b #f2 #X #Y #H elim H -f2 -X -Y
 173 [ #f2 #Hf2 #J #K #W #H destruct
 174 | #f2 #I #L1 #L2 #V #_ #IHL #J #K #W #H elim (IHL … H) -IHL
 175   /3 width=7 by after_next, ex3_2_intro, drops_drop/
 176 | #f2 #I #L1 #L2 #V1 #V2 #HL #_ #_ #J #K #W #H destruct
 177   lapply (after_isid_dx 𝐈𝐝 … f2) /3 width=9 by after_push, ex3_2_intro, drops_drop/
 178 ]
 179 qed-.
 180
 181 lemma drops_fwd_drop2: ∀b,f2,I,X,K,V. ⬇*[b, f2] X ≡ K.ⓑ{I}V →
 182                        ∃∃f1,f. 𝐈⦃f1⦄ & f2 ⊚ ⫯f1 ≡ f & ⬇*[b, f] X ≡ K.
 183 /2 width=5 by drops_fwd_drop2_aux/ qed-.
 184
 185 (* Properties with test for identity ****************************************)
 186
 187 (* Basic_2A1: includes: drop_refl *)
 188 lemma drops_refl: ∀b,L,f. 𝐈⦃f⦄ → ⬇*[b, f] L ≡ L.
 189 #b #L elim L -L /2 width=1 by drops_atom/
 190 #L #I #V #IHL #f #Hf elim (isid_inv_gen … Hf) -Hf
 191 /3 width=1 by drops_skip, lifts_refl/
 192 qed.
 193
 194 (* Forward lemmas test for identity *****************************************)
 195
 196 (* Basic_1: includes: drop_gen_refl *)
 197 (* Basic_2A1: includes: drop_inv_O2 *)
 198 lemma drops_fwd_isid: ∀b,f,L1,L2. ⬇*[b, f] L1 ≡ L2 → 𝐈⦃f⦄ → L1 = L2.
 199 #b #f #L1 #L2 #H elim H -f -L1 -L2 //
 200 [ #f #I #L1 #L2 #V #_ #_ #H elim (isid_inv_next … H) //
 201 | /5 width=5 by isid_inv_push, lifts_fwd_isid, eq_f3, sym_eq/
 202 ]
 203 qed-.
 204
 205
 206 lemma drops_after_fwd_drop2: ∀b,f2,I,X,K,V. ⬇*[b, f2] X ≡ K.ⓑ{I}V →
 207                              ∀f1,f. 𝐈⦃f1⦄ → f2 ⊚ ⫯f1 ≡ f → ⬇*[b, f] X ≡ K.
 208 #b #f2 #I #X #K #V #H #f1 #f #Hf1 #Hf elim (drops_fwd_drop2 … H) -H
 209 #g1 #g #Hg1 #Hg #HK lapply (after_mono_eq … Hg … Hf ??) -Hg -Hf
 210 /3 width=5 by drops_eq_repl_back, isid_inv_eq_repl, eq_next/
 211 qed-.
 212
 213 (* Forward lemmas with test for finite colength *****************************)
 214
 215 lemma drops_fwd_isfin: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → 𝐅⦃f⦄.
 216 #f #L1 #L2 #H elim H -f -L1 -L2
 217 /3 width=1 by isfin_next, isfin_push, isfin_isid/
 218 qed-.
 219
 220 (* Properties with uniform relocations **************************************)
 221
 222 lemma drops_uni_ex: ∀L,i. ⬇*[Ⓕ, 𝐔❴i❵] L ≡ ⋆ ∨ ∃∃I,K,V. ⬇*[i] L ≡ K.ⓑ{I}V.
 223 #L elim L -L /2 width=1 by or_introl/
 224 #L #I #V #IH * /4 width=4 by drops_refl, ex1_3_intro, or_intror/
 225 #i elim (IH i) -IH /3 width=1 by drops_drop, or_introl/
 226 * /4 width=4 by drops_drop, ex1_3_intro, or_intror/
 227 qed-.
 228
 229 (* Basic_2A1: includes: drop_split *)
 230 lemma drops_split_trans: ∀b,f,L1,L2. ⬇*[b, f] L1 ≡ L2 → ∀f1,f2. f1 ⊚ f2 ≡ f → 𝐔⦃f1⦄ →
 231                          ∃∃L. ⬇*[b, f1] L1 ≡ L & ⬇*[b, f2] L ≡ L2.
 232 #b #f #L1 #L2 #H elim H -f -L1 -L2
 233 [ #f #H0f #f1 #f2 #Hf #Hf1 @(ex2_intro … (⋆)) @drops_atom
 234   #H lapply (H0f H) -b
 235   #H elim (after_inv_isid3 … Hf H) -f //
 236 | #f #I #L1 #L2 #V #HL12 #IHL12 #f1 #f2 #Hf #Hf1 elim (after_inv_xxn … Hf) -Hf [1,3: * |*: // ]
 237   [ #g1 #g2 #Hf #H1 #H2 destruct
 238     lapply (isuni_inv_push … Hf1 ??) -Hf1 [1,2: // ] #Hg1
 239     elim (IHL12 … Hf) -f
 240     /4 width=5 by drops_drop, drops_skip, lifts_refl, isuni_isid, ex2_intro/
 241   | #g1 #Hf #H destruct elim (IHL12 … Hf) -f
 242     /3 width=5 by ex2_intro, drops_drop, isuni_inv_next/
 243   ]
 244 | #f #I #L1 #L2 #V1 #V2 #_ #HV21 #IHL12 #f1 #f2 #Hf #Hf1 elim (after_inv_xxp … Hf) -Hf [2,3: // ]
 245   #g1 #g2 #Hf #H1 #H2 destruct elim (lifts_split_trans … HV21 … Hf) -HV21
 246   elim (IHL12 … Hf) -f /3 width=5 by ex2_intro, drops_skip, isuni_fwd_push/
 247 ]
 248 qed-.
 249
 250 lemma drops_split_div: ∀b,f1,L1,L. ⬇*[b, f1] L1 ≡ L → ∀f2,f. f1 ⊚ f2 ≡ f → 𝐔⦃f2⦄ →
 251                        ∃∃L2. ⬇*[Ⓕ, f2] L ≡ L2 & ⬇*[Ⓕ, f] L1 ≡ L2.
 252 #b #f1 #L1 #L #H elim H -f1 -L1 -L
 253 [ #f1 #Hf1 #f2 #f #Hf #Hf2 @(ex2_intro … (⋆)) @drops_atom #H destruct
 254 | #f1 #I #L1 #L #V #HL1 #IH #f2 #f #Hf #Hf2 elim (after_inv_nxx … Hf) -Hf [2,3: // ]
 255   #g #Hg #H destruct elim (IH … Hg) -IH -Hg /3 width=5 by drops_drop, ex2_intro/
 256 | #f1 #I #L1 #L #V1 #V #HL1 #HV1 #IH #f2 #f #Hf #Hf2
 257   elim (after_inv_pxx … Hf) -Hf [1,3: * |*: // ]
 258   #g2 #g #Hg #H2 #H0 destruct
 259   [ lapply (isuni_inv_push … Hf2 ??) -Hf2 [1,2: // ] #Hg2 -IH
 260     lapply (after_isid_inv_dx … Hg … Hg2) -Hg #Hg
 261     /5 width=7 by drops_eq_repl_back, drops_F, drops_refl, drops_skip, lifts_eq_repl_back, isid_push, ex2_intro/
 262   | lapply (isuni_inv_next … Hf2 ??) -Hf2 [1,2: // ] #Hg2 -HL1 -HV1
 263     elim (IH … Hg) -f1 /3 width=3 by drops_drop, ex2_intro/
 264   ]
 265 ]
 266 qed-.
 267
 268 (* Inversion lemmas with test for uniformity ********************************)
 269
 270 lemma drops_inv_isuni: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≡ L2 → 𝐔⦃f⦄ →
 271                        (𝐈⦃f⦄ ∧ L1 = L2) ∨
 272                        ∃∃g,I,K,V. ⬇*[Ⓣ, g] K ≡ L2 & 𝐔⦃g⦄ & L1 = K.ⓑ{I}V & f = ⫯g.
 273 #f #L1 #L2 * -f -L1 -L2
 274 [ /4 width=1 by or_introl, conj/
 275 | /4 width=8 by isuni_inv_next, ex4_4_intro, or_intror/
 276 | /7 width=6 by drops_fwd_isid, lifts_fwd_isid, isuni_inv_push, isid_push, or_introl, conj, eq_f3, sym_eq/
 277 ]
 278 qed-.
 279
 280 (* Basic_2A1: was: drop_inv_O1_pair1 *)
 281 lemma drops_inv_pair1_isuni: ∀b,f,I,K,L2,V. 𝐔⦃f⦄ → ⬇*[b, f] K.ⓑ{I}V ≡ L2 →
 282                              (𝐈⦃f⦄ ∧ L2 = K.ⓑ{I}V) ∨
 283                              ∃∃g. 𝐔⦃g⦄ & ⬇*[b, g] K ≡ L2 & f = ⫯g.
 284 #b #f #I #K #L2 #V #Hf #H elim (isuni_split … Hf) -Hf * #g #Hg #H0 destruct
 285 [ lapply (drops_inv_skip1 … H) -H * #Y #X #HY #HX #H destruct
 286   <(drops_fwd_isid … HY Hg) -Y >(lifts_fwd_isid … HX Hg) -X
 287   /4 width=3 by isid_push, or_introl, conj/
 288 | lapply (drops_inv_drop1 … H) -H /3 width=4 by ex3_intro, or_intror/
 289 ]
 290 qed-.
 291
 292 (* Basic_2A1: was: drop_inv_O1_pair2 *)
 293 lemma drops_inv_pair2_isuni: ∀b,f,I,K,V,L1. 𝐔⦃f⦄ → ⬇*[b, f] L1 ≡ K.ⓑ{I}V →
 294                              (𝐈⦃f⦄ ∧ L1 = K.ⓑ{I}V) ∨
 295                              ∃∃g,I1,K1,V1. 𝐔⦃g⦄ & ⬇*[b, g] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1 & f = ⫯g.
 296 #b #f #I #K #V *
 297 [ #Hf #H elim (drops_inv_atom1 … H) -H #H destruct
 298 | #L1 #I1 #V1 #Hf #H elim (drops_inv_pair1_isuni … Hf H) -Hf -H *
 299   [ #Hf #H destruct /3 width=1 by or_introl, conj/
 300   | /3 width=8 by ex4_4_intro, or_intror/
 301   ]
 302 ]
 303 qed-.
 304
 305 lemma drops_inv_pair2_isuni_next: ∀b,f,I,K,V,L1. 𝐔⦃f⦄ → ⬇*[b, ⫯f] L1 ≡ K.ⓑ{I}V →
 306                                   ∃∃I1,K1,V1. ⬇*[b, f] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1.
 307 #b #f #I #K #V #L1 #Hf #H elim (drops_inv_pair2_isuni … H) -H /2 width=3 by isuni_next/ -Hf *
 308 [ #H elim (isid_inv_next … H) -H //
 309 | /2 width=5 by ex2_3_intro/
 310 ]
 311 qed-.
 312
 313 fact drops_inv_TF_aux: ∀f,L1,L2. ⬇*[Ⓕ, f] L1 ≡ L2 → 𝐔⦃f⦄ →
 314                        ∀I,K,V. L2 = K.ⓑ{I}V →
 315                        ⬇*[Ⓣ, f] L1 ≡ K.ⓑ{I}V.
 316 #f #L1 #L2 #H elim H -f -L1 -L2
 317 [ #f #_ #_ #J #K #W #H destruct
 318 | #f #I #L1 #L2 #V #_ #IH #Hf #J #K #W #H destruct
 319   /4 width=3 by drops_drop, isuni_inv_next/
 320 | #f #I #L1 #L2 #V1 #V2 #HL12 #HV21 #_ #Hf #J #K #W #H destruct
 321   lapply (isuni_inv_push … Hf ??) -Hf [1,2: // ] #Hf
 322   <(drops_fwd_isid … HL12) -K // <(lifts_fwd_isid … HV21) -V1
 323   /3 width=3 by drops_refl, isid_push/
 324 ]
 325 qed-.
 326
 327 (* Basic_2A1: includes: drop_inv_FT *)
 328 lemma drops_inv_TF: ∀f,I,L,K,V. ⬇*[Ⓕ, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 329                     ⬇*[Ⓣ, f] L ≡ K.ⓑ{I}V.
 330 /2 width=3 by drops_inv_TF_aux/ qed-.
 331
 332 (* Basic_2A1: includes: drop_inv_gen *)
 333 lemma drops_inv_gen: ∀b,f,I,L,K,V. ⬇*[b, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 334                      ⬇*[Ⓣ, f] L ≡ K.ⓑ{I}V.
 335 * /2 width=1 by drops_inv_TF/
 336 qed-.
 337
 338 (* Basic_2A1: includes: drop_inv_T *)
 339 lemma drops_inv_F: ∀b,f,I,L,K,V. ⬇*[Ⓕ, f] L ≡ K.ⓑ{I}V → 𝐔⦃f⦄ →
 340                    ⬇*[b, f] L ≡ K.ⓑ{I}V.
 341 * /2 width=1 by drops_inv_TF/
 342 qed-.
 343
 344 (* Forward lemmas with test for uniformity **********************************)
 345
 346 (* Basic_1: was: drop_S *)
 347 (* Basic_2A1: was: drop_fwd_drop2 *)
 348 lemma drops_isuni_fwd_drop2: ∀b,f,I,X,K,V. 𝐔⦃f⦄ → ⬇*[b, f] X ≡ K.ⓑ{I}V → ⬇*[b, ⫯f] X ≡ K.
 349 /3 width=7 by drops_after_fwd_drop2, after_isid_isuni/ qed-.
 350
 351 (* Inversion lemmas with uniform relocations ********************************)
 352
 353 lemma drops_inv_atom2: ∀b,L,f. ⬇*[b, f] L ≡ ⋆ →
 354                        ∃∃n,f1. ⬇*[b, 𝐔❴n❵] L ≡ ⋆ & 𝐔❴n❵ ⊚ f1 ≡ f.
 355 #b #L elim L -L
 356 [ /3 width=4 by drops_atom, after_isid_sn, ex2_2_intro/
 357 | #L #I #V #IH #f #H elim (pn_split f) * #g #H0 destruct
 358   [ elim (drops_inv_skip1 … H) -H #K #W #_ #_ #H destruct
 359   | lapply (drops_inv_drop1 … H) -H #HL
 360     elim (IH … HL) -IH -HL /3 width=8 by drops_drop, after_next, ex2_2_intro/
 361   ]
 362 ]
 363 qed-.
 364
 365 lemma drops_inv_succ: ∀l,L1,L2. ⬇*[⫯l] L1 ≡ L2 →
 366                       ∃∃I,K,V. ⬇*[l] K ≡ L2 & L1 = K.ⓑ{I}V.
 367 #l #L1 #L2 #H elim (drops_inv_isuni … H) -H // *
 368 [ #H elim (isid_inv_next … H) -H //
 369 | /2 width=5 by ex2_3_intro/
 370 ]
 371 qed-.
 372
 373 (* Properties with application **********************************************)
 374
 375 lemma drops_tls_at: ∀f,i1,i2. @⦃i1,f⦄ ≡ i2 →
 376                     ∀b,L1,L2. ⬇*[b,⫱*[i2]f] L1 ≡ L2 →
 377                     ⬇*[b,↑⫱*[⫯i2]f] L1 ≡ L2.
 378 /3 width=3 by drops_eq_repl_fwd, at_inv_tls/ qed-.
 379
 380 lemma drops_split_trans_pair2: ∀b,f,I,L,K0,V. ⬇*[b, f] L ≡ K0.ⓑ{I}V → ∀n. @⦃O, f⦄ ≡ n →
 381                                ∃∃K,W. ⬇*[n]L ≡ K.ⓑ{I}W & ⬇*[b, ⫱*[⫯n]f] K ≡ K0 & ⬆*[⫱*[⫯n]f] V ≡ W.
 382 #b #f #I #L #K0 #V #H #n #Hf
 383 elim (drops_split_trans … H) -H [ |5: @(after_uni_dx … Hf) |2,3: skip ] /2 width=1 by after_isid_dx/ #Y #HLY #H
 384 lapply (drops_tls_at … Hf … H) -H #H
 385 elim (drops_inv_skip2 … H) -H #K #W #HK0 #HVW #H destruct
 386 /3 width=5 by drops_inv_gen, ex3_2_intro/
 387 qed-.
 388
 389 (* Basic_2A1: removed theorems 12:
 390               drops_inv_nil drops_inv_cons d1_liftable_liftables
 391               drop_refl_atom_O2 drop_inv_pair1
 392               drop_inv_Y1 drop_Y1 drop_O_Y drop_fwd_Y2
 393               drop_fwd_length_minus2 drop_fwd_length_minus4
 394 *)
 395 (* Basic_1: removed theorems 53:
 396             drop1_gen_pnil drop1_gen_pcons drop1_getl_trans
 397             drop_ctail drop_skip_flat
 398             cimp_flat_sx cimp_flat_dx cimp_bind cimp_getl_conf
 399             drop_clear drop_clear_O drop_clear_S
 400             clear_gen_sort clear_gen_bind clear_gen_flat clear_gen_flat_r
 401             clear_gen_all clear_clear clear_mono clear_trans clear_ctail clear_cle
 402             getl_ctail_clen getl_gen_tail clear_getl_trans getl_clear_trans
 403             getl_clear_bind getl_clear_conf getl_dec getl_drop getl_drop_conf_lt
 404             getl_drop_conf_ge getl_conf_ge_drop getl_drop_conf_rev
 405             drop_getl_trans_lt drop_getl_trans_le drop_getl_trans_ge
 406             getl_drop_trans getl_flt getl_gen_all getl_gen_sort getl_gen_O
 407             getl_gen_S getl_gen_2 getl_gen_flat getl_gen_bind getl_conf_le
 408             getl_trans getl_refl getl_head getl_flat getl_ctail getl_mono
 409 *)