matita/matita/contribs/lambdadelta/basic_2/relocation/drops_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/lifts_lifts.ma".
  16 include "basic_2/relocation/drops_weight.ma".
  17
  18 (* GENERAL SLICING FOR LOCAL ENVIRONMENTS ***********************************)
  19
  20 (* Main properties **********************************************************)
  21
  22 (* Basic_2A1: includes: drop_conf_ge drop_conf_be drop_conf_le *)
  23 theorem drops_conf: ∀L1,L,c1,f1. ⬇*[c1, f1] L1 ≡ L →
  24                     ∀L2,c2,f. ⬇*[c2, f] L1 ≡ L2 →
  25                     ∀f2. f1 ⊚ f2 ≡ f → ⬇*[c2, f2] L ≡ L2.
  26 #L1 #L #c1 #f1 #H elim H -L1 -L -f1
  27 [ #f1 #_ #L2 #c2 #f #HL2 #f2 #Hf12 elim (drops_inv_atom1 … HL2) -c1 -HL2
  28   #H #Hf destruct @drops_atom
  29   #H elim (after_inv_isid3 … Hf12) -Hf12 /2 width=1 by/
  30 | #I #K1 #K #V1 #f1 #_ #IH #L2 #c2 #f #HL2 #f2 #Hf elim (after_inv_nxx … Hf) -Hf [2,3: // ]
  31   #g #Hg #H destruct /3 width=3 by drops_inv_drop1/
  32 | #I #K1 #K #V1 #V #f1 #_ #HV1 #IH #L2 #c2 #f #HL2 #f2 #Hf elim (after_inv_pxx … Hf) -Hf [1,3: * |*:// ]
  33   #g2 #g #Hf #H1 #H2 destruct
  34   [ elim (drops_inv_skip1 … HL2) -HL2 /3 width=6 by drops_skip, lifts_div/
  35   | /4 width=3 by drops_inv_drop1, drops_drop/
  36   ]
  37 ]
  38 qed-.
  39
  40 (* Basic_1: was: drop1_trans *)
  41 (* Basic_2A1: includes: drop_trans_ge drop_trans_le drop_trans_ge_comm
  42                         drops_drop_trans
  43 *)
  44 theorem drops_trans: ∀L1,L,c1,f1. ⬇*[c1, f1] L1 ≡ L →
  45                      ∀L2,c2,f2. ⬇*[c2, f2] L ≡ L2 →
  46                      ∀f. f1 ⊚ f2 ≡ f → ⬇*[c1∧c2, f] L1 ≡ L2.
  47 #L1 #L #c1 #f1 #H elim H -L1 -L -f1
  48 [ #f1 #Hf1 #L2 #c2 #f2 #HL2 #f #Hf elim (drops_inv_atom1 … HL2) -HL2
  49   #H #Hf2 destruct @drops_atom #H elim (andb_inv_true_dx … H) -H
  50   #H1 #H2 lapply (after_isid_inv_sn … Hf ?) -Hf
  51   /3 width=3 by isid_eq_repl_back/
  52 | #I #K1 #K #V1 #f1 #_ #IH #L2 #c2 #f2 #HL2 #f #Hf elim (after_inv_nxx … Hf) -Hf
  53   /3 width=3 by drops_drop/
  54 | #I #K1 #K #V1 #V #f1 #_ #HV1 #IH #L2 #c2 #f2 #HL2 #f #Hf elim (after_inv_pxx … Hf) -Hf [1,3: * |*: // ]
  55   #g2 #g #Hg #H1 #H2 destruct
  56   [ elim (drops_inv_skip1 … HL2) -HL2 /3 width=6 by drops_skip, lifts_trans/
  57   | /4 width=3 by drops_inv_drop1, drops_drop/
  58   ]
  59 ]
  60 qed-.
  61
  62 theorem drops_conf_div: ∀L,K,f1. ⬇*[Ⓣ,f1] L ≡ K → ∀f2. ⬇*[Ⓣ,f2] L ≡ K →
  63                         𝐔⦃f1⦄ → 𝐔⦃f2⦄ → f1 ≗ f2.
  64 #L #K #f1 #H elim H -L -K -f1
  65 [ #f1 #Hf1 #f2 #Hf2 elim (drops_inv_atom1 … Hf2) -Hf2
  66   /3 width=1 by isid_inv_eq_repl/
  67 | #I #L #K #V #f1 #Hf1 #IH #f2 elim (pn_split f2) *
  68   #g2 #H2 #Hf2 #HU1 #HU2 destruct
  69   [ elim (drops_inv_skip1 … Hf2) -IH -HU1 -Hf2 #Y2 #X2 #HY2 #_ #H destruct
  70     lapply (drops_fwd_isid … HY2 ?) -HY2 /2 width=3 by isuni_inv_push/ -HU2
  71     #H destruct elim (drops_inv_x_pair_xy … Hf1)
  72   | /4 width=5 by drops_inv_drop1, isuni_inv_next, eq_next/
  73   ]
  74 | #I #L #K #V #W #f1 #Hf1 #_ #IH #f2 elim (pn_split f2) *
  75   #g2 #H2 #Hf2 #HU1 #HU2 destruct
  76   [ elim (drops_inv_skip1 … Hf2) -Hf2 #Y2 #X2 #HY2 #_ #H destruct -Hf1
  77     /4 width=5 by isuni_fwd_push, eq_push/
  78   | lapply (drops_inv_drop1 … Hf2) -Hf2 -IH -HU2 #Hg2
  79     lapply (drops_fwd_isid … Hf1 ?) -Hf1 /2 width=3 by isuni_inv_push/ -HU1
  80     #H destruct elim (drops_inv_x_pair_xy … Hg2)
  81   ]
  82 ]
  83 qed-.
  84
  85 (* Advanced properties ******************************************************)
  86
  87 (* Basic_2A1: includes: drop_mono *)
  88 lemma drops_mono: ∀L,L1,c1,f. ⬇*[c1, f] L ≡ L1 →
  89                   ∀L2,c2. ⬇*[c2, f] L ≡ L2 → L1 = L2.
  90 #L #L1 #c1 #f lapply (isid_after_dx 𝐈𝐝 … f)
  91 /3 width=8 by drops_conf, drops_fwd_isid/
  92 qed-.
  93
  94 (* Basic_2A1: includes: drop_conf_lt *)
  95 lemma drops_conf_skip1: ∀L,L2,c2,f. ⬇*[c2, f] L ≡ L2 →
  96                         ∀I,K1,V1,c1,f1. ⬇*[c1, f1] L ≡ K1.ⓑ{I}V1 →
  97                         ∀f2. f1 ⊚ ↑f2 ≡ f →
  98                         ∃∃K2,V2. L2 = K2.ⓑ{I}V2 &
  99                                  ⬇*[c2, f2] K1 ≡ K2 & ⬆*[f2] V2 ≡ V1.
 100 #L #L2 #c2 #f #H2 #I #K1 #V1 #c1 #f1 #H1 #f2 #Hf lapply (drops_conf … H1 … H2 … Hf) -L -Hf
 101 #H elim (drops_inv_skip1 … H) -H /2 width=5 by ex3_2_intro/
 102 qed-.
 103
 104 (* Basic_2A1: includes: drop_trans_lt *)
 105 lemma drops_trans_skip2: ∀L1,L,c1,f1. ⬇*[c1, f1] L1 ≡ L →
 106                          ∀I,K2,V2,c2,f2. ⬇*[c2, f2] L ≡ K2.ⓑ{I}V2 →
 107                          ∀f. f1 ⊚ f2 ≡ ↑f →
 108                          ∃∃K1,V1. L1 = K1.ⓑ{I}V1 &
 109                                   ⬇*[c1∧c2, f] K1 ≡ K2 & ⬆*[f] V2 ≡ V1.
 110 #L1 #L #c1 #f1 #H1 #I #K2 #V2 #c2 #f2 #H2 #f #Hf
 111 lapply (drops_trans … H1 … H2 … Hf) -L -Hf
 112 #H elim (drops_inv_skip2 … H) -H /2 width=5 by ex3_2_intro/
 113 qed-.
 114
 115 (* Basic_2A1: includes: drops_conf_div *)
 116 lemma drops_conf_div_pair: ∀I1,I2,L,K,V1,V2,f1,f2.
 117                            ⬇*[Ⓣ,f1] L ≡ K.ⓑ{I1}V1 → ⬇*[Ⓣ,f2] L ≡ K.ⓑ{I2}V2 →
 118                            𝐔⦃f1⦄ → 𝐔⦃f2⦄ → ∧∧ f1 ≗ f2 & I1 = I2 & V1 = V2.
 119 #I1 #I2 #L #K #V1 #V2 #f1 #f2 #Hf1 #Hf2 #HU1 #HU2
 120 lapply (drops_isuni_fwd_drop2 … Hf1) // #H1
 121 lapply (drops_isuni_fwd_drop2 … Hf2) // #H2
 122 lapply (drops_conf_div … H1 … H2 ??) /2 width=3 by isuni_next/ -H1 -H2 -HU1 -HU2 #H
 123 lapply (eq_inv_nn … H ????) -H [5: |*: // ] #H12
 124 lapply (drops_eq_repl_back … Hf1 … H12) -Hf1 #H0
 125 lapply (drops_mono … H0 … Hf2) -L #H
 126 destruct /2 width=1 by and3_intro/
 127 qed-.