matita/matita/contribs/lambdadelta/basic_2/relocation/drops_length.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/syntax/lenv_length.ma".
  16 include "basic_2/relocation/drops.ma".
  17
  18 (* GENERIC SLICING FOR LOCAL ENVIRONMENTS ***********************************)
  19
  20 (* Forward lemmas with length for local environments ************************)
  21
  22 (* Basic_2A1: includes: drop_fwd_length_le4 *)
  23 lemma drops_fwd_length_le4: ∀b,f,L1,L2. ⬇*[b, f] L1 ≘ L2 → |L2| ≤ |L1|.
  24 #b #f #L1 #L2 #H elim H -f -L1 -L2 /2 width=1 by le_S, le_S_S/
  25 qed-.
  26
  27 (* Basic_2A1: includes: drop_fwd_length_eq1 *)
  28 theorem drops_fwd_length_eq1: ∀b1,b2,f,L1,K1. ⬇*[b1, f] L1 ≘ K1 →
  29                               ∀L2,K2. ⬇*[b2, f] L2 ≘ K2 →
  30                               |L1| = |L2| → |K1| = |K2|.
  31 #b1 #b2 #f #L1 #K1 #HLK1 elim HLK1 -f -L1 -K1
  32 [ #f #_ #L2 #K2 #HLK2 #H lapply (length_inv_zero_sn … H) -H
  33   #H destruct elim (drops_inv_atom1 … HLK2) -HLK2 //
  34 | #f #I1 #L1 #K1 #_ #IH #X2 #K2 #HX #H elim (length_inv_succ_sn … H) -H
  35   #I2 #L2 #H12 #H destruct lapply (drops_inv_drop1 … HX) -HX
  36   #HLK2 @(IH … HLK2 H12) (**) (* auto fails *)
  37 | #f #I1 #I2 #L1 #K1 #_ #_ #IH #X2 #Y2 #HX #H elim (length_inv_succ_sn … H) -H
  38   #I2 #L2 #H12 #H destruct elim (drops_inv_skip1 … HX) -HX
  39   #I2 #K2 #HLK2 #_ #H destruct
  40   lapply (IH … HLK2 H12) -f >length_bind >length_bind /2 width=1 by/ (**) (* full auto fails *)
  41 ]
  42 qed-.
  43
  44 (* forward lemmas with finite colength assignment ***************************)
  45
  46 lemma drops_fwd_fcla: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≘ L2 →
  47                       ∃∃n. 𝐂⦃f⦄ ≘ n & |L1| = |L2| + n.
  48 #f #L1 #L2 #H elim H -f -L1 -L2
  49 [ /4 width=3 by fcla_isid, ex2_intro/
  50 | #f #I #L1 #L2 #_ * >length_bind /3 width=3 by fcla_next, ex2_intro, eq_f/
  51 | #f #I1 #I2 #L1 #L2 #_ #_ * >length_bind >length_bind /3 width=3 by fcla_push, ex2_intro/
  52 ]
  53 qed-.
  54
  55 (* Basic_2A1: includes: drop_fwd_length *)
  56 lemma drops_fcla_fwd: ∀f,L1,L2,n. ⬇*[Ⓣ, f] L1 ≘ L2 → 𝐂⦃f⦄ ≘ n →
  57                       |L1| = |L2| + n.
  58 #f #l1 #l2 #n #Hf #Hn elim (drops_fwd_fcla … Hf) -Hf
  59 #k #Hm #H <(fcla_mono … Hm … Hn) -f //
  60 qed-.
  61
  62 lemma drops_fwd_fcla_le2: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≘ L2 →
  63                           ∃∃n. 𝐂⦃f⦄ ≘ n & n ≤ |L1|.
  64 #f #L1 #L2 #H elim (drops_fwd_fcla … H) -H /2 width=3 by ex2_intro/
  65 qed-.
  66
  67 (* Basic_2A1: includes: drop_fwd_length_le2 *)
  68 lemma drops_fcla_fwd_le2: ∀f,L1,L2,n. ⬇*[Ⓣ, f] L1 ≘ L2 → 𝐂⦃f⦄ ≘ n →
  69                           n ≤ |L1|.
  70 #f #L1 #L2 #n #H #Hn elim (drops_fwd_fcla_le2 … H) -H
  71 #k #Hm #H <(fcla_mono … Hm … Hn) -f //
  72 qed-.
  73
  74 lemma drops_fwd_fcla_lt2: ∀f,L1,I2,K2. ⬇*[Ⓣ, f] L1 ≘ K2.ⓘ{I2} →
  75                           ∃∃n. 𝐂⦃f⦄ ≘ n & n < |L1|.
  76 #f #L1 #I2 #K2 #H elim (drops_fwd_fcla … H) -H
  77 #n #Hf #H >H -L1 /3 width=3 by le_S_S, ex2_intro/
  78 qed-.
  79
  80 (* Basic_2A1: includes: drop_fwd_length_lt2 *)
  81 lemma drops_fcla_fwd_lt2: ∀f,L1,I2,K2,n.
  82                           ⬇*[Ⓣ, f] L1 ≘ K2.ⓘ{I2} → 𝐂⦃f⦄ ≘ n →
  83                           n < |L1|.
  84 #f #L1 #I2 #K2 #n #H #Hn elim (drops_fwd_fcla_lt2 … H) -H
  85 #k #Hm #H <(fcla_mono … Hm … Hn) -f //
  86 qed-.
  87
  88 (* Basic_2A1: includes: drop_fwd_length_lt4 *)
  89 lemma drops_fcla_fwd_lt4: ∀f,L1,L2,n. ⬇*[Ⓣ, f] L1 ≘ L2 → 𝐂⦃f⦄ ≘ n → 0 < n →
  90                           |L2| < |L1|.
  91 #f #L1 #L2 #n #H #Hf #Hn lapply (drops_fcla_fwd … H Hf) -f
  92 /2 width=1 by lt_minus_to_plus_r/ qed-.
  93
  94 (* Basic_2A1: includes: drop_inv_length_eq *)
  95 lemma drops_inv_length_eq: ∀f,L1,L2. ⬇*[Ⓣ, f] L1 ≘ L2 → |L1| = |L2| → 𝐈⦃f⦄.
  96 #f #L1 #L2 #H #HL12 elim (drops_fwd_fcla … H) -H
  97 #n #Hn <HL12 -L2 #H lapply (discr_plus_x_xy … H) -H
  98 /2 width=3 by fcla_inv_xp/
  99 qed-.
 100
 101 (* Basic_2A1: includes: drop_fwd_length_eq2 *)
 102 theorem drops_fwd_length_eq2: ∀f,L1,L2,K1,K2. ⬇*[Ⓣ, f] L1 ≘ K1 → ⬇*[Ⓣ, f] L2 ≘ K2 →
 103                               |K1| = |K2| → |L1| = |L2|.
 104 #f #L1 #L2 #K1 #K2 #HLK1 #HLK2 #HL12
 105 elim (drops_fwd_fcla … HLK1) -HLK1 #n1 #Hn1 #H1 >H1 -L1
 106 elim (drops_fwd_fcla … HLK2) -HLK2 #n2 #Hn2 #H2 >H2 -L2
 107 <(fcla_mono … Hn2 … Hn1) -f //
 108 qed-.
 109
 110 theorem drops_conf_div: ∀f1,f2,L1,L2. ⬇*[Ⓣ, f1] L1 ≘ L2 → ⬇*[Ⓣ, f2] L1 ≘ L2 →
 111                         ∃∃n. 𝐂⦃f1⦄ ≘ n & 𝐂⦃f2⦄ ≘ n.
 112 #f1 #f2 #L1 #L2 #H1 #H2
 113 elim (drops_fwd_fcla … H1) -H1 #n1 #Hf1 #H1
 114 elim (drops_fwd_fcla … H2) -H2 #n2 #Hf2 >H1 -L1 #H
 115 lapply (injective_plus_r … H) -L2 #H destruct /2 width=3 by ex2_intro/
 116 qed-.
 117
 118 theorem drops_conf_div_fcla: ∀f1,f2,L1,L2,n1,n2.
 119                              ⬇*[Ⓣ, f1] L1 ≘ L2 → ⬇*[Ⓣ, f2] L1 ≘ L2 → 𝐂⦃f1⦄ ≘ n1 → 𝐂⦃f2⦄ ≘ n2 →
 120                              n1 = n2.
 121 #f1 #f2 #L1 #L2 #n1 #n2 #Hf1 #Hf2 #Hn1 #Hn2
 122 lapply (drops_fcla_fwd … Hf1 Hn1) -f1 #H1
 123 lapply (drops_fcla_fwd … Hf2 Hn2) -f2 >H1 -L1
 124 /2 width=1 by injective_plus_r/
 125 qed-.