matita/matita/contribs/lambdadelta/basic_2/relocation/drops_lreq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/drops_ceq.ma".
  16 include "basic_2/relocation/drops_lexs.ma".
  17
  18 (* GENERIC SLICING FOR LOCAL ENVIRONMENTS ***********************************)
  19
  20 (* Properties with ranged equivalence for local environments ****************)
  21
  22 lemma lreq_co_dedropable: co_dedropable_sn lreq.
  23 @lexs_liftable_co_dedropable
  24 /2 width=6 by cfull_lift, ceq_lift, cfull_refl, ceq_refl/
  25 qed-.
  26
  27 lemma lreq_co_dropable_sn: co_dropable_sn lreq.
  28 @lexs_co_dropable_sn qed-.
  29
  30 lemma lreq_co_dropable_dx: co_dropable_dx lreq.
  31 @lexs_co_dropable_dx qed-.
  32
  33 (* Basic_2A1: includes: lreq_drop_trans_be *)
  34 lemma lreq_drops_trans_next: ∀f2,L1,L2. L1 ≡[f2] L2 →
  35                              ∀b,f,I,K2,V. ⬇*[b,f] L2 ≡ K2.ⓑ{I}V → 𝐔⦃f⦄ →
  36                              ∀f1. f ~⊚ ⫯f1 ≡ f2 →
  37                              ∃∃K1. ⬇*[b,f] L1 ≡ K1.ⓑ{I}V & K1 ≡[f1] K2.
  38 #f2 #L1 #L2 #HL12 #b #f #I #K1 #V #HLK1 #Hf #f1 #Hf2
  39 elim (lexs_drops_trans_next … HL12 … HLK1 Hf … Hf2) -f2 -L2 -Hf
  40 /2 width=3 by ex2_intro/
  41 qed-.
  42
  43 (* Basic_2A1: includes: lreq_drop_conf_be *)
  44 lemma lreq_drops_conf_next: ∀f2,L1,L2. L1 ≡[f2] L2 →
  45                             ∀b,f,I,K1,V. ⬇*[b,f] L1 ≡ K1.ⓑ{I}V → 𝐔⦃f⦄ →
  46                             ∀f1. f ~⊚ ⫯f1 ≡ f2 →
  47                             ∃∃K2. ⬇*[b,f] L2 ≡ K2.ⓑ{I}V & K1 ≡[f1] K2.
  48 #f2 #L1 #L2 #HL12 #b #f #I #K1 #V #HLK1 #Hf #f1 #Hf2
  49 elim (lreq_drops_trans_next … (lreq_sym … HL12) … HLK1 … Hf2) // -f2 -L1 -Hf
  50 /3 width=3 by lreq_sym, ex2_intro/
  51 qed-.
  52
  53 lemma drops_lreq_trans_next: ∀f1,K1,K2. K1 ≡[f1] K2 →
  54                              ∀b,f,I,L1,V. ⬇*[b,f] L1.ⓑ{I}V ≡ K1 →
  55                              ∀f2. f ~⊚ f1 ≡ ⫯f2 →
  56                              ∃∃L2. ⬇*[b,f] L2.ⓑ{I}V ≡ K2 & L1 ≡[f2] L2 & L1.ⓑ{I}V ≡[f] L2.ⓑ{I}V.
  57 #f1 #K1 #K2 #HK12 #b #f #I #L1 #V #HLK1 #f2 #Hf2
  58 elim (drops_lexs_trans_next … HK12 … HLK1 … Hf2) -f1 -K1
  59 /2 width=6 by cfull_lift, ceq_lift, cfull_refl, ceq_refl, ex3_intro/
  60 qed-.