matita/matita/contribs/lambdadelta/basic_2/relocation/drops_lstar.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/lib/lstar.ma".
  16 include "basic_2/relocation/lreq_lreq.ma".
  17
  18 (* GENERIC SLICING FOR LOCAL ENVIRONMENTS ***********************************)
  19
  20 (* Properties with reflexive and transitive closure *************************)
  21
  22 (* Basic_2A1: was: d_liftable_LTC *)
  23 lemma d2_liftable_sn_LTC: ∀R. d_liftable2_sn R → d_liftable2_sn (LTC … R).
  24 #R #HR #K #T1 #T2 #H elim H -T2
  25 [ #T2 #HT12 #b #f #L #HLK #U1 #HTU1
  26   elim (HR … HT12 … HLK … HTU1) /3 width=3 by inj, ex2_intro/
  27 | #T #T2 #_ #HT2 #IHT1 #b #f #L #HLK #U1 #HTU1
  28   elim (IHT1 … HLK … HTU1) -T1 #U #HTU #HU1
  29   elim (HR … HT2 … HLK … HTU) -HR -K -T /3 width=5 by step, ex2_intro/
  30 ]
  31 qed-.
  32
  33 (* Basic_2A1: was: d_deliftable_sn_LTC *)
  34 lemma d2_deliftable_sn_LTC: ∀R. d_deliftable2_sn R → d_deliftable2_sn (LTC … R).
  35 #R #HR #L #U1 #U2 #H elim H -U2
  36 [ #U2 #HU12 #b #f #K #HLK #T1 #HTU1
  37   elim (HR … HU12 … HLK … HTU1) -HR -L -U1 /3 width=3 by inj, ex2_intro/
  38 | #U #U2 #_ #HU2 #IHU1 #b #f #K #HLK #T1 #HTU1
  39   elim (IHU1 … HLK … HTU1) -IHU1 -U1 #T #HTU #HT1
  40   elim (HR … HU2 … HLK … HTU) -HR -L -U /3 width=5 by step, ex2_intro/
  41 ]
  42 qed-.
  43
  44 lemma co_dropable_sn_TC: ∀R. co_dropable_sn R → co_dropable_sn (LTC … R).
  45 #R #HR #b #f #L1 #K1 #HLK1 #Hf #f2 #L2 #H elim H -L2
  46 [ #L2 #HL12 #f1 #H elim (HR … HLK1 … Hf … HL12 … H) -HR -Hf -f2 -L1
  47   /3 width=3 by inj, ex2_intro/
  48 | #L #L2 #_ #HL2 #IH #f1 #H elim (IH … H) -IH
  49   #K #HK1 #HLK elim (HR … HLK … HL2 … H) -HR -f2 -L
  50   /3 width=3 by step, ex2_intro/
  51 ]
  52 qed-.
  53
  54 (* Basic_2A1: was: d_liftable_llstar *)
  55 lemma d2_liftable_sn_llstar: ∀R. d_liftable2_sn R → ∀d. d_liftable2_sn (llstar … R d).
  56 #R #HR #d #K #T1 #T2 #H @(lstar_ind_r … d T2 H) -d -T2
  57 [ #b #f #L #_ #U1 #HTU1 -HR -b -K /2 width=3 by ex2_intro/
  58 | #l #T #T2 #_ #HT2 #IHT1 #b #f #L #HLK #U1 #HTU1
  59   elim (IHT1 … HLK … HTU1) -T1 #U #HTU #HU1
  60   elim (HR … HT2 … HLK … HTU) -T /3 width=5 by lstar_dx, ex2_intro/
  61 ]
  62 qed-.
  63
  64 (* Basic_2A1: was: d_deliftable_sn_llstar *)
  65 lemma d2_deliftable_sn_llstar: ∀R. d_deliftable2_sn R →
  66                                ∀d. d_deliftable2_sn (llstar … R d).
  67 #R #HR #l #L #U1 #U2 #H @(lstar_ind_r … l U2 H) -l -U2
  68 [ /2 width=3 by lstar_O, ex2_intro/
  69 | #l #U #U2 #_ #HU2 #IHU1 #b #f #K #HLK #T1 #HTU1
  70   elim (IHU1 … HLK … HTU1) -IHU1 -U1 #T #HTU #HT1
  71   elim (HR … HU2 … HLK … HTU) -HR -L -U /3 width=5 by lstar_dx, ex2_intro/
  72 ]
  73 qed-.
  74
  75 lemma co_dropable_dx_TC: ∀R. co_dropable_dx R → co_dropable_dx (LTC … R).
  76 #R #HR #f2 #L1 #L2 #H elim H -L2
  77 [ #L2 #HL12 #b #f #K2 #HLK2 #Hf #f1 #Hf2 elim (HR … HL12 … HLK2 … Hf … Hf2) -HR -Hf -f2 -L2
  78   /3 width=3 by inj, ex2_intro/
  79 | #L #L2 #_ #HL2 #IHL1 #b #f #K2 #HLK2 #Hf #f1 #Hf2 elim (HR … HL2 … HLK2 … Hf … Hf2) -HR -L2
  80   #K #HLK #HK2 elim (IHL1 … HLK … Hf … Hf2) -Hf -f2 -L
  81   /3 width=5 by step, ex2_intro/
  82 ]
  83 qed-.
  84
  85 lemma co_dedropable_sn_TC: ∀R. co_dedropable_sn R → co_dedropable_sn (LTC … R).
  86 #R #HR #b #f #L1 #K1 #HLK1 #f1 #K2 #H elim H -K2
  87 [ #K2 #HK12 #f2 #Hf elim (HR … HLK1 … HK12 … Hf) -HR -f1 -K1
  88   /3 width=4 by inj, ex3_intro/
  89 | #K #K2 #_ #HK2 #IH #f2 #Hf elim (IH … Hf) -IH -K1
  90   #L #H1L1 #HLK #H2L1 elim (HR … HLK … HK2 … Hf) -HR -f1 -K
  91   /3 width=6 by lreq_trans, step, ex3_intro/
  92 ]
  93 qed-.