matita/matita/contribs/lambdadelta/basic_2/relocation/fsupq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/fsup.ma".
  16
  17 (* OPTIONAL SUPCLOSURE ******************************************************)
  18
  19 inductive fsupq: bi_relation lenv term ≝
  20 | fsupq_refl   : ∀L,T. fsupq L T L T
  21 | fsupq_lref_O : ∀I,L,V. fsupq (L.ⓑ{I}V) (#0) L V
  22 | fsupq_pair_sn: ∀I,L,V,T. fsupq L (②{I}V.T) L V
  23 | fsupq_bind_dx: ∀a,I,L,V,T. fsupq L (ⓑ{a,I}V.T) (L.ⓑ{I}V) T
  24 | fsupq_flat_dx: ∀I,L,V,T.   fsupq L (ⓕ{I}V.T) L T
  25 | fsupq_ldrop  : ∀L1,K1,K2,T1,T2,U1,d,e.
  26                 ⇩[d, e] L1 ≡ K1 → ⇧[d, e] T1 ≡ U1 →
  27                 fsupq K1 T1 K2 T2 → fsupq L1 U1 K2 T2
  28 .
  29
  30 interpretation
  31    "optional structural successor (closure)"
  32    'SupTermOpt L1 T1 L2 T2 = (fsupq L1 T1 L2 T2).
  33
  34 (* Basic properties *********************************************************)
  35
  36 lemma fsup_fsupq: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⊃ ⦃L2, T2⦄ → ⦃L1, T1⦄ ⊃⸮ ⦃L2, T2⦄.
  37 #L1 #L2 #T1 #T2 #H elim H -L1 -L2 -T1 -T2 // /2 width=7/ qed.
  38
  39 (* Basic properties *********************************************************)
  40
  41 lemma fsupq_lref_S_lt: ∀I,L,K,V,T,i. 0 < i → ⦃L, #(i-1)⦄ ⊃⸮ ⦃K, T⦄ → ⦃L.ⓑ{I}V, #i⦄ ⊃⸮ ⦃K, T⦄.
  42 /3 width=7/ qed.
  43
  44 lemma fsupq_lref: ∀I,K,V,i,L. ⇩[0, i] L ≡ K.ⓑ{I}V → ⦃L, #i⦄ ⊃⸮ ⦃K, V⦄.
  45 /3 width=2/ qed.
  46
  47 (* Basic forward lemmas *****************************************************)
  48
  49 lemma fsupq_fwd_fw: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⊃⸮ ⦃L2, T2⦄ → ♯{L2, T2} ≤ ♯{L1, T1}.
  50 #L1 #L2 #T1 #T2 #H elim H -L1 -L2 -T1 -T2 // [1,2,3: /2 width=1/ ]
  51 #L1 #K1 #K2 #T1 #T2 #U1 #d #e #HLK1 #HTU1 #_ #IHT12
  52 lapply (ldrop_fwd_lw … HLK1) -HLK1 #HLK1
  53 lapply (lift_fwd_tw … HTU1) -HTU1 #HTU1
  54 @(transitive_le … IHT12) -IHT12 /2 width=1/
  55 qed-.
  56
  57 fact fsupq_fwd_length_lref1_aux: ∀L1,L2,T1,T2. ⦃L1, T1⦄ ⊃⸮ ⦃L2, T2⦄ →
  58                                  ∀i. T1 = #i → |L2| ≤ |L1|.
  59 #L1 #L2 #T1 #T2 #H elim H -L1 -L2 -T1 -T2 //
  60 [ #a #I #L #V #T #j #H destruct
  61 | #L1 #K1 #K2 #T1 #T2 #U1 #d #e #HLK1 #HTU1 #_ #IHT12 #i #H destruct
  62   lapply (ldrop_fwd_length_le4 … HLK1) -HLK1 #HLK1
  63   elim (lift_inv_lref2 … HTU1) -HTU1 * #Hdei #H destruct
  64   @(transitive_le … HLK1) /2 width=2/
  65 ]
  66 qed-.
  67
  68 lemma fsupq_fwd_length_lref1: ∀L1,L2,T2,i. ⦃L1, #i⦄ ⊃⸮ ⦃L2, T2⦄ → |L2| ≤ |L1|.
  69 /2 width=5 by fsupq_fwd_length_lref1_aux/
  70 qed-.