matita/matita/contribs/lambdadelta/basic_2/relocation/ldrop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/lib/bool.ma".
  16 include "ground_2/lib/lstar.ma".
  17 include "basic_2/notation/relations/rdrop_5.ma".
  18 include "basic_2/notation/relations/rdrop_4.ma".
  19 include "basic_2/notation/relations/rdrop_3.ma".
  20 include "basic_2/grammar/lenv_length.ma".
  21 include "basic_2/grammar/cl_restricted_weight.ma".
  22 include "basic_2/relocation/lift.ma".
  23
  24 (* BASIC SLICING FOR LOCAL ENVIRONMENTS *************************************)
  25
  26 (* Basic_1: includes: drop_skip_bind *)
  27 inductive ldrop (s:bool): relation4 nat nat lenv lenv ≝
  28 | ldrop_atom: ∀d,e. (s = Ⓕ → e = 0) → ldrop s d e (⋆) (⋆)
  29 | ldrop_pair: ∀I,L,V. ldrop s 0 0 (L.ⓑ{I}V) (L.ⓑ{I}V)
  30 | ldrop_drop: ∀I,L1,L2,V,e. ldrop s 0 e L1 L2 → ldrop s 0 (e+1) (L1.ⓑ{I}V) L2
  31 | ldrop_skip: ∀I,L1,L2,V1,V2,d,e.
  32               ldrop s d e L1 L2 → ⇧[d, e] V2 ≡ V1 →
  33               ldrop s (d+1) e (L1.ⓑ{I}V1) (L2.ⓑ{I}V2)
  34 .
  35
  36 interpretation
  37    "basic slicing (local environment) abstract"
  38    'RDrop s d e L1 L2 = (ldrop s d e L1 L2).
  39 (*
  40 interpretation
  41    "basic slicing (local environment) general"
  42    'RDrop d e L1 L2 = (ldrop true d e L1 L2).
  43 *)
  44 interpretation
  45    "basic slicing (local environment) lget"
  46    'RDrop e L1 L2 = (ldrop false O e L1 L2).
  47
  48 definition l_liftable: predicate (lenv → relation term) ≝
  49                        λR. ∀K,T1,T2. R K T1 T2 → ∀L,s,d,e. ⇩[s, d, e] L ≡ K →
  50                        ∀U1. ⇧[d, e] T1 ≡ U1 → ∀U2. ⇧[d, e] T2 ≡ U2 → R L U1 U2.
  51
  52 definition l_deliftable_sn: predicate (lenv → relation term) ≝
  53                             λR. ∀L,U1,U2. R L U1 U2 → ∀K,s,d,e. ⇩[s, d, e] L ≡ K →
  54                             ∀T1. ⇧[d, e] T1 ≡ U1 →
  55                             ∃∃T2. ⇧[d, e] T2 ≡ U2 & R K T1 T2.
  56
  57 definition dropable_sn: predicate (relation lenv) ≝
  58                         λR. ∀L1,K1,s,d,e. ⇩[s, d, e] L1 ≡ K1 → ∀L2. R L1 L2 →
  59                         ∃∃K2. R K1 K2 & ⇩[s, d, e] L2 ≡ K2.
  60
  61 definition dropable_dx: predicate (relation lenv) ≝
  62                         λR. ∀L1,L2. R L1 L2 → ∀K2,s,e. ⇩[s, 0, e] L2 ≡ K2 →
  63                         ∃∃K1. ⇩[s, 0, e] L1 ≡ K1 & R K1 K2.
  64
  65 (* Basic inversion lemmas ***************************************************)
  66
  67 fact ldrop_inv_atom1_aux: ∀L1,L2,s,d,e. ⇩[s, d, e] L1 ≡ L2 → L1 = ⋆ →
  68                           L2 = ⋆ ∧ (s = Ⓕ → e = 0).
  69 #L1 #L2 #s #d #e * -L1 -L2 -d -e
  70 [ /3 width=1 by conj/
  71 | #I #L #V #H destruct
  72 | #I #L1 #L2 #V #e #_ #H destruct
  73 | #I #L1 #L2 #V1 #V2 #d #e #_ #_ #H destruct
  74 ]
  75 qed-.
  76
  77 (* Basic_1: was: drop_gen_sort *)
  78 lemma ldrop_inv_atom1: ∀L2,s,d,e. ⇩[s, d, e] ⋆ ≡ L2 → L2 = ⋆ ∧ (s = Ⓕ → e = 0).
  79 /2 width=4 by ldrop_inv_atom1_aux/ qed-.
  80
  81 fact ldrop_inv_O1_pair1_aux: ∀L1,L2,s,d,e. ⇩[s, d, e] L1 ≡ L2 → d = 0 →
  82                              ∀K,I,V. L1 = K.ⓑ{I}V →
  83                              (e = 0 ∧ L2 = K.ⓑ{I}V) ∨
  84                              (0 < e ∧ ⇩[s, d, e-1] K ≡ L2).
  85 #L1 #L2 #s #d #e * -L1 -L2 -d -e
  86 [ #d #e #_ #_ #K #J #W #H destruct
  87 | #I #L #V #_ #K #J #W #HX destruct /3 width=1 by or_introl, conj/
  88 | #I #L1 #L2 #V #e #HL12 #_ #K #J #W #H destruct /3 width=1 by or_intror, conj/
  89 | #I #L1 #L2 #V1 #V2 #d #e #_ #_ >commutative_plus normalize #H destruct
  90 ]
  91 qed-.
  92
  93 lemma ldrop_inv_O1_pair1: ∀I,K,L2,V,s,e. ⇩[s, 0, e] K. ⓑ{I} V ≡ L2 →
  94                           (e = 0 ∧ L2 = K.ⓑ{I}V) ∨
  95                           (0 < e ∧ ⇩[s, 0, e-1] K ≡ L2).
  96 /2 width=3 by ldrop_inv_O1_pair1_aux/ qed-.
  97
  98 lemma ldrop_inv_pair1: ∀I,K,L2,V,s. ⇩[s, 0, 0] K.ⓑ{I}V ≡ L2 → L2 = K.ⓑ{I}V.
  99 #I #K #L2 #V #s #H
 100 elim (ldrop_inv_O1_pair1 … H) -H * // #H destruct
 101 elim (lt_refl_false … H)
 102 qed-.
 103
 104 (* Basic_1: was: drop_gen_drop *)
 105 lemma ldrop_inv_drop1_lt: ∀I,K,L2,V,s,e.
 106                           ⇩[s, 0, e] K.ⓑ{I}V ≡ L2 → 0 < e → ⇩[s, 0, e-1] K ≡ L2.
 107 #I #K #L2 #V #s #e #H #He
 108 elim (ldrop_inv_O1_pair1 … H) -H * // #H destruct
 109 elim (lt_refl_false … He)
 110 qed-.
 111
 112 lemma ldrop_inv_drop1: ∀I,K,L2,V,s,e.
 113                        ⇩[s, 0, e+1] K.ⓑ{I}V ≡ L2 → ⇩[s, 0, e] K ≡ L2.
 114 #I #K #L2 #V #s #e #H lapply (ldrop_inv_drop1_lt … H ?) -H //
 115 qed-.
 116
 117 fact ldrop_inv_skip1_aux: ∀L1,L2,s,d,e. ⇩[s, d, e] L1 ≡ L2 → 0 < d →
 118                           ∀I,K1,V1. L1 = K1.ⓑ{I}V1 →
 119                           ∃∃K2,V2. ⇩[s, d-1, e] K1 ≡ K2 &
 120                                    ⇧[d-1, e] V2 ≡ V1 &
 121                                    L2 = K2.ⓑ{I}V2.
 122 #L1 #L2 #s #d #e * -L1 -L2 -d -e
 123 [ #d #e #_ #_ #J #K1 #W1 #H destruct
 124 | #I #L #V #H elim (lt_refl_false … H)
 125 | #I #L1 #L2 #V #e #_ #H elim (lt_refl_false … H)
 126 | #I #L1 #L2 #V1 #V2 #d #e #HL12 #HV21 #_ #J #K1 #W1 #H destruct /2 width=5 by ex3_2_intro/
 127 ]
 128 qed-.
 129
 130 (* Basic_1: was: drop_gen_skip_l *)
 131 lemma ldrop_inv_skip1: ∀I,K1,V1,L2,s,d,e. ⇩[s, d, e] K1.ⓑ{I}V1 ≡ L2 → 0 < d →
 132                        ∃∃K2,V2. ⇩[s, d-1, e] K1 ≡ K2 &
 133                                 ⇧[d-1, e] V2 ≡ V1 &
 134                                 L2 = K2.ⓑ{I}V2.
 135 /2 width=3 by ldrop_inv_skip1_aux/ qed-.
 136
 137 lemma ldrop_inv_O1_pair2: ∀I,K,V,s,e,L1. ⇩[s, 0, e] L1 ≡ K.ⓑ{I}V →
 138                           (e = 0 ∧ L1 = K.ⓑ{I}V) ∨
 139                           ∃∃I1,K1,V1. ⇩[s, 0, e-1] K1 ≡ K.ⓑ{I}V & L1 = K1.ⓑ{I1}V1 & 0 < e.
 140 #I #K #V #s #e *
 141 [ #H elim (ldrop_inv_atom1 … H) -H #H destruct
 142 | #L1 #I1 #V1 #H
 143   elim (ldrop_inv_O1_pair1 … H) -H *
 144   [ #H1 #H2 destruct /3 width=1 by or_introl, conj/
 145   | /3 width=5 by ex3_3_intro, or_intror/
 146   ]
 147 ]
 148 qed-.
 149
 150 fact ldrop_inv_skip2_aux: ∀L1,L2,s,d,e. ⇩[s, d, e] L1 ≡ L2 → 0 < d →
 151                           ∀I,K2,V2. L2 = K2.ⓑ{I}V2 →
 152                           ∃∃K1,V1. ⇩[s, d-1, e] K1 ≡ K2 &
 153                                    ⇧[d-1, e] V2 ≡ V1 &
 154                                    L1 = K1.ⓑ{I}V1.
 155 #L1 #L2 #s #d #e * -L1 -L2 -d -e
 156 [ #d #e #_ #_ #J #K2 #W2 #H destruct
 157 | #I #L #V #H elim (lt_refl_false … H)
 158 | #I #L1 #L2 #V #e #_ #H elim (lt_refl_false … H)
 159 | #I #L1 #L2 #V1 #V2 #d #e #HL12 #HV21 #_ #J #K2 #W2 #H destruct /2 width=5 by ex3_2_intro/
 160 ]
 161 qed-.
 162
 163 (* Basic_1: was: drop_gen_skip_r *)
 164 lemma ldrop_inv_skip2: ∀I,L1,K2,V2,s,d,e. ⇩[s, d, e] L1 ≡ K2.ⓑ{I}V2 → 0 < d →
 165                        ∃∃K1,V1. ⇩[s, d-1, e] K1 ≡ K2 & ⇧[d-1, e] V2 ≡ V1 &
 166                                 L1 = K1.ⓑ{I}V1.
 167 /2 width=3 by ldrop_inv_skip2_aux/ qed-.
 168
 169 (* Basic properties *********************************************************)
 170
 171 lemma ldrop_refl_atom_O2: ∀s,d. ⇩[s, d, O] ⋆ ≡ ⋆.
 172 /2 width=1 by ldrop_atom/ qed.
 173
 174 (* Basic_1: was by definition: drop_refl *)
 175 lemma ldrop_refl: ∀L,d,s. ⇩[s, d, 0] L ≡ L.
 176 #L elim L -L //
 177 #L #I #V #IHL #d #s @(nat_ind_plus … d) -d /2 width=1 by ldrop_pair, ldrop_skip/
 178 qed.
 179
 180 lemma ldrop_drop_lt: ∀I,L1,L2,V,s,e.
 181                      ⇩[s, 0, e-1] L1 ≡ L2 → 0 < e → ⇩[s, 0, e] L1.ⓑ{I}V ≡ L2.
 182 #I #L1 #L2 #V #s #e #HL12 #He >(plus_minus_m_m e 1) /2 width=1 by ldrop_drop/
 183 qed.
 184
 185 lemma ldrop_skip_lt: ∀I,L1,L2,V1,V2,s,d,e.
 186                      ⇩[s, d-1, e] L1 ≡ L2 → ⇧[d-1, e] V2 ≡ V1 → 0 < d →
 187                      ⇩[s, d, e] L1. ⓑ{I} V1 ≡ L2.ⓑ{I}V2.
 188 #I #L1 #L2 #V1 #V2 #s #d #e #HL12 #HV21 #Hd >(plus_minus_m_m d 1) /2 width=1 by ldrop_skip/
 189 qed.
 190
 191 lemma ldrop_O1_le: ∀e,L. e ≤ |L| → ∃K. ⇩[e] L ≡ K.
 192 #e @(nat_ind_plus … e) -e /2 width=2 by ex_intro/
 193 #e #IHe *
 194 [ #H lapply (le_n_O_to_eq … H) -H >commutative_plus normalize #H destruct
 195 | #L #I #V normalize #H
 196   elim (IHe L) -IHe /3 width=2 by ldrop_drop, monotonic_pred, ex_intro/
 197 ]
 198 qed-.
 199
 200 lemma ldrop_O1_lt: ∀L,e. e < |L| → ∃∃I,K,V. ⇩[e] L ≡ K.ⓑ{I}V.
 201 #L elim L -L
 202 [ #e #H elim (lt_zero_false … H)
 203 | #L #I #V #IHL #e @(nat_ind_plus … e) -e /2 width=4 by ldrop_pair, ex1_3_intro/
 204   #e #_ normalize #H
 205   elim (IHL e) -IHL /3 width=4 by ldrop_drop, lt_plus_to_minus_r, lt_plus_to_lt_l, ex1_3_intro/
 206 ]
 207 qed-.
 208
 209 lemma ldrop_FT: ∀L1,L2,d,e. ⇩[Ⓕ, d, e] L1 ≡ L2 → ⇩[Ⓣ, d, e] L1 ≡ L2.
 210 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e
 211 /3 width=1 by ldrop_atom, ldrop_drop, ldrop_skip/
 212 qed.
 213
 214 lemma ldrop_gen: ∀L1,L2,s,d,e. ⇩[Ⓕ, d, e] L1 ≡ L2 → ⇩[s, d, e] L1 ≡ L2.
 215 #L1 #L2 * /2 width=1 by ldrop_FT/
 216 qed-.
 217
 218 lemma ldrop_T: ∀L1,L2,s,d,e. ⇩[s, d, e] L1 ≡ L2 → ⇩[Ⓣ, d, e] L1 ≡ L2.
 219 #L1 #L2 * /2 width=1 by ldrop_FT/
 220 qed-.
 221
 222 lemma l_liftable_LTC: ∀R. l_liftable R → l_liftable (LTC … R).
 223 #R #HR #K #T1 #T2 #H elim H -T2
 224 [ /3 width=10 by inj/
 225 | #T #T2 #_ #HT2 #IHT1 #L #s #d #e #HLK #U1 #HTU1 #U2 #HTU2
 226   elim (lift_total T d e) /4 width=12 by step/
 227 ]
 228 qed-.
 229
 230 lemma l_deliftable_sn_LTC: ∀R. l_deliftable_sn R → l_deliftable_sn (LTC … R).
 231 #R #HR #L #U1 #U2 #H elim H -U2
 232 [ #U2 #HU12 #K #s #d #e #HLK #T1 #HTU1
 233   elim (HR … HU12 … HLK … HTU1) -HR -L -U1 /3 width=3 by inj, ex2_intro/
 234 | #U #U2 #_ #HU2 #IHU1 #K #s #d #e #HLK #T1 #HTU1
 235   elim (IHU1 … HLK … HTU1) -IHU1 -U1 #T #HTU #HT1
 236   elim (HR … HU2 … HLK … HTU) -HR -L -U /3 width=5 by step, ex2_intro/
 237 ]
 238 qed-.
 239
 240 lemma dropable_sn_TC: ∀R. dropable_sn R → dropable_sn (TC … R).
 241 #R #HR #L1 #K1 #s #d #e #HLK1 #L2 #H elim H -L2
 242 [ #L2 #HL12 elim (HR … HLK1 … HL12) -HR -L1
 243   /3 width=3 by inj, ex2_intro/
 244 | #L #L2 #_ #HL2 * #K #HK1 #HLK elim (HR … HLK … HL2) -HR -L
 245   /3 width=3 by step, ex2_intro/
 246 ]
 247 qed-.
 248
 249 lemma dropable_dx_TC: ∀R. dropable_dx R → dropable_dx (TC … R).
 250 #R #HR #L1 #L2 #H elim H -L2
 251 [ #L2 #HL12 #K2 #s #e #HLK2 elim (HR … HL12 … HLK2) -HR -L2
 252   /3 width=3 by inj, ex2_intro/
 253 | #L #L2 #_ #HL2 #IHL1 #K2 #s #e #HLK2 elim (HR … HL2 … HLK2) -HR -L2
 254   #K #HLK #HK2 elim (IHL1 … HLK) -L
 255   /3 width=5 by step, ex2_intro/
 256 ]
 257 qed-.
 258
 259 lemma l_deliftable_sn_llstar: ∀R. l_deliftable_sn R →
 260                               ∀l. l_deliftable_sn (llstar … R l).
 261 #R #HR #l #L #U1 #U2 #H @(lstar_ind_r … l U2 H) -l -U2
 262 [ /2 width=3 by lstar_O, ex2_intro/
 263 | #l #U #U2 #_ #HU2 #IHU1 #K #s #d #e #HLK #T1 #HTU1
 264   elim (IHU1 … HLK … HTU1) -IHU1 -U1 #T #HTU #HT1
 265   elim (HR … HU2 … HLK … HTU) -HR -L -U /3 width=5 by lstar_dx, ex2_intro/
 266 ]
 267 qed-.
 268
 269 (* Basic forvard lemmas *****************************************************)
 270
 271 (* Basic_1: was: drop_S *)
 272 lemma ldrop_fwd_drop2: ∀L1,I2,K2,V2,s,e. ⇩[s, O, e] L1 ≡ K2. ⓑ{I2} V2 →
 273                        ⇩[s, O, e + 1] L1 ≡ K2.
 274 #L1 elim L1 -L1
 275 [ #I2 #K2 #V2 #s #e #H lapply (ldrop_inv_atom1 … H) -H * #H destruct
 276 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #s #e #H
 277   elim (ldrop_inv_O1_pair1 … H) -H * #He #H
 278   [ -IHL1 destruct /2 width=1 by ldrop_drop/
 279   | @ldrop_drop >(plus_minus_m_m e 1) /2 width=3 by/
 280   ]
 281 ]
 282 qed-.
 283
 284 lemma ldrop_fwd_length: ∀L1,L2,d,e. ⇩[Ⓕ, d, e] L1 ≡ L2 → |L1| = |L2| + e.
 285 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e // normalize /2 width=1 by/
 286 qed-.
 287
 288 lemma ldrop_fwd_length_minus2: ∀L1,L2,d,e. ⇩[Ⓕ, d, e] L1 ≡ L2 → |L2| = |L1| - e.
 289 #L1 #L2 #d #e #H lapply (ldrop_fwd_length … H) -H /2 width=1 by plus_minus, le_n/
 290 qed-.
 291
 292 lemma ldrop_fwd_length_minus4: ∀L1,L2,d,e. ⇩[Ⓕ, d, e] L1 ≡ L2 → e = |L1| - |L2|.
 293 #L1 #L2 #d #e #H lapply (ldrop_fwd_length … H) -H //
 294 qed-.
 295
 296 lemma ldrop_fwd_length_le2: ∀L1,L2,d,e. ⇩[Ⓕ, d, e] L1 ≡ L2 → e ≤ |L1|.
 297 #L1 #L2 #d #e #H lapply (ldrop_fwd_length … H) -H //
 298 qed-.
 299
 300 lemma ldrop_fwd_length_le4: ∀L1,L2,d,e. ⇩[Ⓕ, d, e] L1 ≡ L2 → |L2| ≤ |L1|.
 301 #L1 #L2 #d #e #H lapply (ldrop_fwd_length … H) -H //
 302 qed-.
 303
 304 lemma ldrop_fwd_length_lt2: ∀L1,I2,K2,V2,d,e.
 305                             ⇩[Ⓕ, d, e] L1 ≡ K2. ⓑ{I2} V2 → e < |L1|.
 306 #L1 #I2 #K2 #V2 #d #e #H
 307 lapply (ldrop_fwd_length … H) normalize in ⊢ (%→?); -I2 -V2 //
 308 qed-.
 309
 310 lemma ldrop_fwd_length_lt4: ∀L1,L2,d,e. ⇩[Ⓕ, d, e] L1 ≡ L2 → 0 < e → |L2| < |L1|.
 311 #L1 #L2 #d #e #H lapply (ldrop_fwd_length … H) -H /2 width=1 by lt_minus_to_plus_r/
 312 qed-.
 313
 314 lemma ldrop_fwd_length_eq1: ∀L1,L2,K1,K2,d,e. ⇩[Ⓕ, d, e] L1 ≡ K1 → ⇩[Ⓕ, d, e] L2 ≡ K2 →
 315                             |L1| = |L2| → |K1| = |K2|.
 316 #L1 #L2 #K1 #K2 #d #e #HLK1 #HLK2 #HL12
 317 lapply (ldrop_fwd_length … HLK1) -HLK1
 318 lapply (ldrop_fwd_length … HLK2) -HLK2
 319 /2 width=2 by injective_plus_r/
 320 qed-.
 321
 322 lemma ldrop_fwd_length_eq2: ∀L1,L2,K1,K2,d,e. ⇩[Ⓕ, d, e] L1 ≡ K1 → ⇩[Ⓕ, d, e] L2 ≡ K2 →
 323                             |K1| = |K2| → |L1| = |L2|.
 324 #L1 #L2 #K1 #K2 #d #e #HLK1 #HLK2 #HL12
 325 lapply (ldrop_fwd_length … HLK1) -HLK1
 326 lapply (ldrop_fwd_length … HLK2) -HLK2 //
 327 qed-.
 328
 329 lemma ldrop_fwd_lw: ∀L1,L2,s,d,e. ⇩[s, d, e] L1 ≡ L2 → ♯{L2} ≤ ♯{L1}.
 330 #L1 #L2 #s #d #e #H elim H -L1 -L2 -d -e // normalize
 331 [ /2 width=3 by transitive_le/
 332 | #I #L1 #L2 #V1 #V2 #d #e #_ #HV21 #IHL12
 333   >(lift_fwd_tw … HV21) -HV21 /2 width=1 by monotonic_le_plus_l/
 334 ]
 335 qed-.
 336
 337 lemma ldrop_fwd_lw_lt: ∀L1,L2,d,e. ⇩[Ⓕ, d, e] L1 ≡ L2 → 0 < e → ♯{L2} < ♯{L1}.
 338 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e
 339 [ #d #e #H >H -H //
 340 | #I #L #V #H elim (lt_refl_false … H)
 341 | #I #L1 #L2 #V #e #HL12 #_ #_
 342   lapply (ldrop_fwd_lw … HL12) -HL12 #HL12
 343   @(le_to_lt_to_lt … HL12) -HL12 //
 344 | #I #L1 #L2 #V1 #V2 #d #e #_ #HV21 #IHL12 #H normalize in ⊢ (?%%); -I
 345   >(lift_fwd_tw … HV21) -V2 /3 by lt_minus_to_plus/
 346 ]
 347 qed-.
 348
 349 lemma ldrop_fwd_rfw: ∀I,L,K,V,i. ⇩[i] L ≡ K.ⓑ{I}V → ♯{K, V} < ♯{L, #i}.
 350 #I #L #K #V #i #HLK lapply (ldrop_fwd_lw … HLK) -HLK
 351 normalize in ⊢ (%→?%%); /2 width=1 by le_S_S/
 352 qed-.
 353
 354 (* Advanced inversion lemmas ************************************************)
 355
 356 fact ldrop_inv_O2_aux: ∀L1,L2,s,d,e. ⇩[s, d, e] L1 ≡ L2 → e = 0 → L1 = L2.
 357 #L1 #L2 #s #d #e #H elim H -L1 -L2 -d -e
 358 [ //
 359 | //
 360 | #I #L1 #L2 #V #e #_ #_ >commutative_plus normalize #H destruct
 361 | #I #L1 #L2 #V1 #V2 #d #e #_ #HV21 #IHL12 #H
 362   >(IHL12 H) -L1 >(lift_inv_O2_aux … HV21 … H) -V2 -d -e //
 363 ]
 364 qed-.
 365
 366 (* Basic_1: was: drop_gen_refl *)
 367 lemma ldrop_inv_O2: ∀L1,L2,s,d. ⇩[s, d, 0] L1 ≡ L2 → L1 = L2.
 368 /2 width=5 by ldrop_inv_O2_aux/ qed-.
 369
 370 lemma ldrop_inv_length_eq: ∀L1,L2,d,e. ⇩[Ⓕ, d, e] L1 ≡ L2 → |L1| = |L2| → e = 0.
 371 #L1 #L2 #d #e #H #HL12 lapply (ldrop_fwd_length_minus4 … H) //
 372 qed-.
 373
 374 lemma ldrop_inv_refl: ∀L,d,e. ⇩[Ⓕ, d, e] L ≡ L → e = 0.
 375 /2 width=5 by ldrop_inv_length_eq/ qed-.
 376
 377 fact ldrop_inv_FT_aux: ∀L1,L2,s,d,e. ⇩[s, d, e] L1 ≡ L2 →
 378                        ∀I,K,V. L2 = K.ⓑ{I}V → s = Ⓣ → d = 0 →
 379                        ⇩[Ⓕ, d, e] L1 ≡ K.ⓑ{I}V.
 380 #L1 #L2 #s #d #e #H elim H -L1 -L2 -d -e
 381 [ #d #e #_ #J #K #W #H destruct
 382 | #I #L #V #J #K #W #H destruct //
 383 | #I #L1 #L2 #V #e #_ #IHL12 #J #K #W #H1 #H2 destruct
 384   /3 width=1 by ldrop_drop/
 385 | #I #L1 #L2 #V1 #V2 #d #e #_ #_ #_ #J #K #W #_ #_
 386   <plus_n_Sm #H destruct
 387 ]
 388 qed-.
 389
 390 lemma ldrop_inv_FT: ∀I,L,K,V,e. ⇩[Ⓣ, 0, e] L ≡ K.ⓑ{I}V → ⇩[e] L ≡ K.ⓑ{I}V.
 391 /2 width=5 by ldrop_inv_FT_aux/ qed.
 392
 393 lemma ldrop_inv_gen: ∀I,L,K,V,s,e. ⇩[s, 0, e] L ≡ K.ⓑ{I}V → ⇩[e] L ≡ K.ⓑ{I}V.
 394 #I #L #K #V * /2 width=1 by ldrop_inv_FT/
 395 qed-.
 396
 397 lemma ldrop_inv_T: ∀I,L,K,V,s,e. ⇩[Ⓣ, 0, e] L ≡ K.ⓑ{I}V → ⇩[s, 0, e] L ≡ K.ⓑ{I}V.
 398 #I #L #K #V * /2 width=1 by ldrop_inv_FT/
 399 qed-.
 400
 401 (* Basic_1: removed theorems 50:
 402             drop_ctail drop_skip_flat
 403             cimp_flat_sx cimp_flat_dx cimp_bind cimp_getl_conf
 404             drop_clear drop_clear_O drop_clear_S
 405             clear_gen_sort clear_gen_bind clear_gen_flat clear_gen_flat_r
 406             clear_gen_all clear_clear clear_mono clear_trans clear_ctail clear_cle
 407             getl_ctail_clen getl_gen_tail clear_getl_trans getl_clear_trans
 408             getl_clear_bind getl_clear_conf getl_dec getl_drop getl_drop_conf_lt
 409             getl_drop_conf_ge getl_conf_ge_drop getl_drop_conf_rev
 410             drop_getl_trans_lt drop_getl_trans_le drop_getl_trans_ge
 411             getl_drop_trans getl_flt getl_gen_all getl_gen_sort getl_gen_O
 412             getl_gen_S getl_gen_2 getl_gen_flat getl_gen_bind getl_conf_le
 413             getl_trans getl_refl getl_head getl_flat getl_ctail getl_mono
 414 *)