matita/matita/contribs/lambdadelta/basic_2/relocation/ldrop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/lenv_length.ma".
  16 include "basic_2/grammar/lenv_weight.ma".
  17 include "basic_2/relocation/lift.ma".
  18
  19 (* LOCAL ENVIRONMENT SLICING ************************************************)
  20
  21 (* Basic_1: includes: drop_skip_bind *)
  22 inductive ldrop: nat → nat → relation lenv ≝
  23 | ldrop_atom : ∀d. ldrop d 0 (⋆) (⋆)
  24 | ldrop_pair : ∀L,I,V. ldrop 0 0 (L. ⓑ{I} V) (L. ⓑ{I} V)
  25 | ldrop_ldrop: ∀L1,L2,I,V,e. ldrop 0 e L1 L2 → ldrop 0 (e + 1) (L1. ⓑ{I} V) L2
  26 | ldrop_skip : ∀L1,L2,I,V1,V2,d,e.
  27                ldrop d e L1 L2 → ⇧[d,e] V2 ≡ V1 →
  28                ldrop (d + 1) e (L1. ⓑ{I} V1) (L2. ⓑ{I} V2)
  29 .
  30
  31 interpretation "local slicing" 'RDrop d e L1 L2 = (ldrop d e L1 L2).
  32
  33 definition l_liftable: predicate (lenv → relation term) ≝
  34                        λR. ∀K,T1,T2. R K T1 T2 → ∀L,d,e. ⇩[d, e] L ≡ K →
  35                        ∀U1. ⇧[d, e] T1 ≡ U1 → ∀U2. ⇧[d, e] T2 ≡ U2 → R L U1 U2.
  36
  37 definition l_deliftable_sn: predicate (lenv → relation term) ≝
  38                             λR. ∀L,U1,U2. R L U1 U2 → ∀K,d,e. ⇩[d, e] L ≡ K →
  39                             ∀T1. ⇧[d, e] T1 ≡ U1 →
  40                             ∃∃T2. ⇧[d, e] T2 ≡ U2 & R K T1 T2.
  41
  42 definition dropable_sn: predicate (relation lenv) ≝
  43                         λR. ∀L1,K1,d,e. ⇩[d, e] L1 ≡ K1 → ∀L2. R L1 L2 →
  44                         ∃∃K2. R K1 K2 & ⇩[d, e] L2 ≡ K2.
  45
  46 definition dedropable_sn: predicate (relation lenv) ≝
  47                           λR. ∀L1,K1,d,e. ⇩[d, e] L1 ≡ K1 → ∀K2. R K1 K2 →
  48                           ∃∃L2. R L1 L2 & ⇩[d, e] L2 ≡ K2.
  49
  50 definition dropable_dx: predicate (relation lenv) ≝
  51                         λR. ∀L1,L2. R L1 L2 → ∀K2,e. ⇩[0, e] L2 ≡ K2 →
  52                         ∃∃K1. ⇩[0, e] L1 ≡ K1 & R K1 K2.
  53
  54 (* Basic inversion lemmas ***************************************************)
  55
  56 fact ldrop_inv_atom1_aux: ∀d,e,L1,L2. ⇩[d, e] L1 ≡ L2 → L1 = ⋆ →
  57                           L2 = ⋆ ∧ e = 0.
  58 #d #e #L1 #L2 * -d -e -L1 -L2
  59 [ /2 width=1/
  60 | #L #I #V #H destruct
  61 | #L1 #L2 #I #V #e #_ #H destruct
  62 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
  63 ]
  64 qed-.
  65
  66 (* Basic_1: was: drop_gen_sort *)
  67 lemma ldrop_inv_atom1: ∀d,e,L2. ⇩[d, e] ⋆ ≡ L2 → L2 = ⋆ ∧ e = 0.
  68 /2 width=4 by ldrop_inv_atom1_aux/ qed-.
  69
  70 fact ldrop_inv_O1_pair1_aux: ∀d,e,L1,L2. ⇩[d, e] L1 ≡ L2 → d = 0 →
  71                              ∀K,I,V. L1 = K. ⓑ{I} V →
  72                              (e = 0 ∧ L2 = K. ⓑ{I} V) ∨
  73                              (0 < e ∧ ⇩[d, e - 1] K ≡ L2).
  74 #d #e #L1 #L2 * -d -e -L1 -L2
  75 [ #d #_ #K #I #V #H destruct
  76 | #L #I #V #_ #K #J #W #HX destruct /3 width=1/
  77 | #L1 #L2 #I #V #e #HL12 #_ #K #J #W #H destruct /3 width=1/
  78 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ >commutative_plus normalize #H destruct
  79 ]
  80 qed-.
  81
  82 lemma ldrop_inv_O1_pair1: ∀e,K,I,V,L2. ⇩[0, e] K. ⓑ{I} V ≡ L2 →
  83                           (e = 0 ∧ L2 = K. ⓑ{I} V) ∨
  84                           (0 < e ∧ ⇩[0, e - 1] K ≡ L2).
  85 /2 width=3 by ldrop_inv_O1_pair1_aux/ qed-.
  86
  87 lemma ldrop_inv_pair1: ∀K,I,V,L2. ⇩[0, 0] K. ⓑ{I} V ≡ L2 → L2 = K. ⓑ{I} V.
  88 #K #I #V #L2 #H
  89 elim (ldrop_inv_O1_pair1 … H) -H * // #H destruct
  90 elim (lt_refl_false … H)
  91 qed-.
  92
  93 (* Basic_1: was: drop_gen_drop *)
  94 lemma ldrop_inv_ldrop1: ∀e,K,I,V,L2.
  95                         ⇩[0, e] K. ⓑ{I} V ≡ L2 → 0 < e → ⇩[0, e - 1] K ≡ L2.
  96 #e #K #I #V #L2 #H #He
  97 elim (ldrop_inv_O1_pair1 … H) -H * // #H destruct
  98 elim (lt_refl_false … He)
  99 qed-.
 100
 101 fact ldrop_inv_skip1_aux: ∀d,e,L1,L2. ⇩[d, e] L1 ≡ L2 → 0 < d →
 102                           ∀I,K1,V1. L1 = K1. ⓑ{I} V1 →
 103                           ∃∃K2,V2. ⇩[d - 1, e] K1 ≡ K2 &
 104                                    ⇧[d - 1, e] V2 ≡ V1 &
 105                                    L2 = K2. ⓑ{I} V2.
 106 #d #e #L1 #L2 * -d -e -L1 -L2
 107 [ #d #_ #I #K #V #H destruct
 108 | #L #I #V #H elim (lt_refl_false … H)
 109 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
 110 | #X #L2 #Y #Z #V2 #d #e #HL12 #HV12 #_ #I #L1 #V1 #H destruct /2 width=5/
 111 ]
 112 qed-.
 113
 114 (* Basic_1: was: drop_gen_skip_l *)
 115 lemma ldrop_inv_skip1: ∀d,e,I,K1,V1,L2. ⇩[d, e] K1. ⓑ{I} V1 ≡ L2 → 0 < d →
 116                        ∃∃K2,V2. ⇩[d - 1, e] K1 ≡ K2 &
 117                                 ⇧[d - 1, e] V2 ≡ V1 &
 118                                 L2 = K2. ⓑ{I} V2.
 119 /2 width=3 by ldrop_inv_skip1_aux/ qed-.
 120
 121 lemma ldrop_inv_O1_pair2: ∀I,K,V,e,L1. ⇩[0, e] L1 ≡ K. ⓑ{I} V →
 122                           (e = 0 ∧ L1 = K. ⓑ{I} V) ∨
 123                           ∃∃I1,K1,V1. ⇩[0, e - 1] K1 ≡ K. ⓑ{I} V & L1 = K1.ⓑ{I1}V1 & 0 < e.
 124 #I #K #V #e *
 125 [ #H elim (ldrop_inv_atom1 … H) -H #H destruct
 126 | #L1 #I1 #V1 #H
 127   elim (ldrop_inv_O1_pair1 … H) -H *
 128   [ #H1 #H2 destruct /3 width=1/
 129   | /3 width=5/
 130   ]
 131 ]
 132 qed-.
 133
 134 fact ldrop_inv_skip2_aux: ∀d,e,L1,L2. ⇩[d, e] L1 ≡ L2 → 0 < d →
 135                           ∀I,K2,V2. L2 = K2. ⓑ{I} V2 →
 136                           ∃∃K1,V1. ⇩[d - 1, e] K1 ≡ K2 &
 137                                    ⇧[d - 1, e] V2 ≡ V1 &
 138                                    L1 = K1. ⓑ{I} V1.
 139 #d #e #L1 #L2 * -d -e -L1 -L2
 140 [ #d #_ #I #K #V #H destruct
 141 | #L #I #V #H elim (lt_refl_false … H)
 142 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
 143 | #L1 #X #Y #V1 #Z #d #e #HL12 #HV12 #_ #I #L2 #V2 #H destruct /2 width=5/
 144 ]
 145 qed-.
 146
 147 (* Basic_1: was: drop_gen_skip_r *)
 148 lemma ldrop_inv_skip2: ∀d,e,I,L1,K2,V2. ⇩[d, e] L1 ≡ K2. ⓑ{I} V2 → 0 < d →
 149                        ∃∃K1,V1. ⇩[d - 1, e] K1 ≡ K2 & ⇧[d - 1, e] V2 ≡ V1 &
 150                                 L1 = K1. ⓑ{I} V1.
 151 /2 width=3 by ldrop_inv_skip2_aux/ qed-.
 152
 153 (* Basic properties *********************************************************)
 154
 155 (* Basic_1: was by definition: drop_refl *)
 156 lemma ldrop_refl: ∀L,d. ⇩[d, 0] L ≡ L.
 157 #L elim L -L //
 158 #L #I #V #IHL #d @(nat_ind_plus … d) -d // /2 width=1/
 159 qed.
 160
 161 lemma ldrop_ldrop_lt: ∀L1,L2,I,V,e.
 162                       ⇩[0, e - 1] L1 ≡ L2 → 0 < e → ⇩[0, e] L1. ⓑ{I} V ≡ L2.
 163 #L1 #L2 #I #V #e #HL12 #He >(plus_minus_m_m e 1) // /2 width=1/
 164 qed.
 165
 166 lemma ldrop_skip_lt: ∀L1,L2,I,V1,V2,d,e.
 167                      ⇩[d - 1, e] L1 ≡ L2 → ⇧[d - 1, e] V2 ≡ V1 → 0 < d →
 168                      ⇩[d, e] L1. ⓑ{I} V1 ≡ L2. ⓑ{I} V2.
 169 #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV21 #Hd >(plus_minus_m_m d 1) // /2 width=1/
 170 qed.
 171
 172 lemma ldrop_O1_le: ∀e,L. e ≤ |L| → ∃K. ⇩[0, e] L ≡ K.
 173 #e @(nat_ind_plus … e) -e /2 width=2/
 174 #e #IHe *
 175 [ #H lapply (le_n_O_to_eq … H) -H >commutative_plus normalize #H destruct
 176 | #L #I #V normalize #H
 177   elim (IHe L) -IHe /2 width=1/ -H /3 width=2/
 178 ]
 179 qed.
 180
 181 lemma ldrop_O1_lt: ∀L,e. e < |L| → ∃∃I,K,V. ⇩[0, e] L ≡ K.ⓑ{I}V.
 182 #L elim L -L
 183 [ #e #H elim (lt_zero_false … H)
 184 | #L #I #V #IHL #e @(nat_ind_plus … e) -e /2 width=4/
 185   #e #_ normalize #H
 186   elim (IHL e) -IHL /2 width=1/ -H /3 width=4/
 187 ]
 188 qed.
 189
 190 lemma l_liftable_LTC: ∀R. l_liftable R → l_liftable (LTC … R).
 191 #R #HR #K #T1 #T2 #H elim H -T2
 192 [ /3 width=9/
 193 | #T #T2 #_ #HT2 #IHT1 #L #d #e #HLK #U1 #HTU1 #U2 #HTU2
 194   elim (lift_total T d e) /4 width=11 by step/ (**) (* auto too slow without trace *)
 195 ]
 196 qed.
 197
 198 lemma l_deliftable_sn_LTC: ∀R. l_deliftable_sn R → l_deliftable_sn (LTC … R).
 199 #R #HR #L #U1 #U2 #H elim H -U2
 200 [ #U2 #HU12 #K #d #e #HLK #T1 #HTU1
 201   elim (HR … HU12 … HLK … HTU1) -HR -L -U1 /3 width=3/
 202 | #U #U2 #_ #HU2 #IHU1 #K #d #e #HLK #T1 #HTU1
 203   elim (IHU1 … HLK … HTU1) -IHU1 -U1 #T #HTU #HT1
 204   elim (HR … HU2 … HLK … HTU) -HR -L -U /3 width=5/
 205 ]
 206 qed.
 207
 208 lemma dropable_sn_TC: ∀R. dropable_sn R → dropable_sn (TC … R).
 209 #R #HR #L1 #K1 #d #e #HLK1 #L2 #H elim H -L2
 210 [ #L2 #HL12
 211   elim (HR … HLK1 … HL12) -HR -L1 /3 width=3/
 212 | #L #L2 #_ #HL2 * #K #HK1 #HLK
 213   elim (HR … HLK … HL2) -HR -L /3 width=3/
 214 ]
 215 qed.
 216
 217 lemma dedropable_sn_TC: ∀R. dedropable_sn R → dedropable_sn (TC … R).
 218 #R #HR #L1 #K1 #d #e #HLK1 #K2 #H elim H -K2
 219 [ #K2 #HK12
 220   elim (HR … HLK1 … HK12) -HR -K1 /3 width=3/
 221 | #K #K2 #_ #HK2 * #L #HL1 #HLK
 222   elim (HR … HLK … HK2) -HR -K /3 width=3/
 223 ]
 224 qed.
 225
 226 lemma dropable_dx_TC: ∀R. dropable_dx R → dropable_dx (TC … R).
 227 #R #HR #L1 #L2 #H elim H -L2
 228 [ #L2 #HL12 #K2 #e #HLK2
 229   elim (HR … HL12 … HLK2) -HR -L2 /3 width=3/
 230 | #L #L2 #_ #HL2 #IHL1 #K2 #e #HLK2
 231   elim (HR … HL2 … HLK2) -HR -L2 #K #HLK #HK2
 232   elim (IHL1 … HLK) -L /3 width=5/
 233 ]
 234 qed.
 235
 236 (* Basic forvard lemmas *****************************************************)
 237
 238 (* Basic_1: was: drop_S *)
 239 lemma ldrop_fwd_ldrop2: ∀L1,I2,K2,V2,e. ⇩[O, e] L1 ≡ K2. ⓑ{I2} V2 →
 240                         ⇩[O, e + 1] L1 ≡ K2.
 241 #L1 elim L1 -L1
 242 [ #I2 #K2 #V2 #e #H lapply (ldrop_inv_atom1 … H) -H * #H destruct
 243 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #e #H
 244   elim (ldrop_inv_O1_pair1 … H) -H * #He #H
 245   [ -IHL1 destruct /2 width=1/
 246   | @ldrop_ldrop >(plus_minus_m_m e 1) // /2 width=3/
 247   ]
 248 ]
 249 qed-.
 250
 251 lemma ldrop_fwd_length: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → |L1| = |L2| + e.
 252 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e // normalize /2 width=1/
 253 qed-.
 254
 255 lemma ldrop_fwd_length_minus2: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → |L2| = |L1| - e.
 256 #L1 #L2 #d #e #H lapply (ldrop_fwd_length … H) -H /2 width=1/
 257 qed-.
 258
 259 lemma ldrop_fwd_length_minus4: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → e = |L1| - |L2|.
 260 #L1 #L2 #d #e #H lapply (ldrop_fwd_length … H) -H //
 261 qed-.
 262
 263 lemma ldrop_fwd_length_le2: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → e ≤ |L1|.
 264 #L1 #L2 #d #e #H lapply (ldrop_fwd_length … H) -H //
 265 qed-.
 266
 267 lemma ldrop_fwd_length_le4: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → |L2| ≤ |L1|.
 268 #L1 #L2 #d #e #H lapply (ldrop_fwd_length … H) -H //
 269 qed-.
 270
 271 lemma ldrop_fwd_length_lt2: ∀L1,I2,K2,V2,d,e.
 272                             ⇩[d, e] L1 ≡ K2. ⓑ{I2} V2 → e < |L1|.
 273 #L1 #I2 #K2 #V2 #d #e #H
 274 lapply (ldrop_fwd_length … H) normalize in ⊢ (%→?); -I2 -V2 //
 275 qed-.
 276
 277 lemma ldrop_fwd_length_lt4: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → 0 < e → |L2| < |L1|.
 278 #L1 #L2 #d #e #H lapply (ldrop_fwd_length … H) -H /2 width=1/
 279 qed-.
 280
 281 lemma ldrop_fwd_lw: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → ♯{L2} ≤ ♯{L1}.
 282 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e // normalize
 283 [ /2 width=3/
 284 | #L1 #L2 #I #V1 #V2 #d #e #_ #HV21 #IHL12
 285   >(lift_fwd_tw … HV21) -HV21 /2 width=1/
 286 ]
 287 qed-.
 288
 289 lemma ldrop_fwd_lw_lt: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → 0 < e → ♯{L2} < ♯{L1}.
 290 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e //
 291 [ #L #I #V #H elim (lt_refl_false … H)
 292 | #L1 #L2 #I #V #e #HL12 #_ #_
 293   lapply (ldrop_fwd_lw … HL12) -HL12 #HL12
 294   @(le_to_lt_to_lt … HL12) -HL12 //
 295 | #L1 #L2 #I #V1 #V2 #d #e #_ #HV21 #IHL12 #H normalize in ⊢ (?%%); -I
 296   >(lift_fwd_tw … HV21) -V2 /3 by lt_minus_to_plus/ (**) (* auto too slow without trace *)
 297 ]
 298 qed-.
 299
 300 (* Advanced inversion lemmas ************************************************)
 301
 302 fact ldrop_inv_O2_aux: ∀d,e,L1,L2. ⇩[d, e] L1 ≡ L2 → e = 0 → L1 = L2.
 303 #d #e #L1 #L2 #H elim H -d -e -L1 -L2
 304 [ //
 305 | //
 306 | #L1 #L2 #I #V #e #_ #_ >commutative_plus normalize #H destruct
 307 | #L1 #L2 #I #V1 #V2 #d #e #_ #HV21 #IHL12 #H
 308   >(IHL12 H) -L1 >(lift_inv_O2_aux … HV21 … H) -V2 -d -e //
 309 ]
 310 qed-.
 311
 312 (* Basic_1: was: drop_gen_refl *)
 313 lemma ldrop_inv_O2: ∀L1,L2,d. ⇩[d, 0] L1 ≡ L2 → L1 = L2.
 314 /2 width=4 by ldrop_inv_O2_aux/ qed-.
 315
 316 lemma ldrop_inv_length_eq: ∀L1,L2,d,e. ⇩[d, e] L1 ≡ L2 → |L1| = |L2| → e = 0.
 317 #L1 #L2 #d #e #H #HL12 lapply (ldrop_fwd_length_minus4 … H) //
 318 qed-.
 319
 320 lemma ldrop_inv_refl: ∀L,d,e. ⇩[d, e] L ≡ L → e = 0.
 321 /2 width=5 by ldrop_inv_length_eq/ qed-.
 322
 323 (* Basic_1: removed theorems 50:
 324             drop_ctail drop_skip_flat
 325             cimp_flat_sx cimp_flat_dx cimp_bind cimp_getl_conf
 326             drop_clear drop_clear_O drop_clear_S
 327             clear_gen_sort clear_gen_bind clear_gen_flat clear_gen_flat_r
 328             clear_gen_all clear_clear clear_mono clear_trans clear_ctail clear_cle
 329             getl_ctail_clen getl_gen_tail clear_getl_trans getl_clear_trans
 330             getl_clear_bind getl_clear_conf getl_dec getl_drop getl_drop_conf_lt
 331             getl_drop_conf_ge getl_conf_ge_drop getl_drop_conf_rev
 332             drop_getl_trans_lt drop_getl_trans_le drop_getl_trans_ge
 333             getl_drop_trans getl_flt getl_gen_all getl_gen_sort getl_gen_O
 334             getl_gen_S getl_gen_2 getl_gen_flat getl_gen_bind getl_conf_le
 335             getl_trans getl_refl getl_head getl_flat getl_ctail getl_mono
 336 *)