matita/matita/contribs/lambdadelta/basic_2/relocation/lex_tc.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/syntax/ext2_tc.ma".
  16 include "basic_2/relocation/lexs_tc.ma".
  17 include "basic_2/relocation/lex.ma".
  18
  19 alias symbol "subseteq" = "relation inclusion".
  20
  21 (* GENERIC EXTENSION OF A CONTEXT-SENSITIVE REALTION FOR TERMS **************)
  22
  23 (* Inversion lemmas with transitive closure *********************************)
  24
  25 (* Basic_2A1: was: lpx_sn_LTC_TC_lpx_sn *)
  26 lemma lex_inv_ltc: ∀R. c_reflexive … R →
  27                    lex (LTC … R) ⊆ TC … (lex R).
  28 #R #HR #L1 #L2 *
  29 /5 width=11 by lexs_inv_tc_dx, lexs_co, ext2_inv_tc, ext2_refl, monotonic_TC, ex2_intro/
  30 qed-.
  31
  32 lemma s_rs_transitive_lex_inv_isid: ∀R. s_rs_transitive … R (λ_.lex R) →
  33                                     s_rs_transitive_isid cfull (cext2 R).
  34 #R #HR #f #Hf #L2 #T1 #T2 #H #L1 #HL12
  35 elim (ext2_tc … H) -H
  36 [ /3 width=1 by ext2_inv_tc, ext2_unit/
  37 | #I #V1 #V2 #HV12
  38   @ext2_inv_tc @ext2_pair
  39   @(HR … HV12) -HV12 /2 width=3 by ex2_intro/ (**) (* auto fails *)
  40 ]
  41 qed-.
  42
  43 (* Properties with transitive closure ***************************************)
  44
  45 (* Basic_2A1: was: TC_lpx_sn_inv_lpx_sn_LTC *)
  46 lemma lex_ltc: ∀R. s_rs_transitive … R (λ_. lex R) →
  47                TC … (lex R) ⊆ lex (LTC … R).
  48 #R #HR #L1 #L2 #HL12
  49 lapply (monotonic_TC … (lexs cfull (cext2 R) 𝐈𝐝) … HL12) -HL12
  50 [ #L1 #L2 * /3 width=3 by lexs_eq_repl_fwd, eq_id_inv_isid/
  51 | /5 width=9 by s_rs_transitive_lex_inv_isid, lexs_tc_dx, lexs_co, ext2_tc, ex2_intro/
  52 ]
  53 qed-.
  54
  55 lemma lex_ltc_step_dx: ∀R. c_reflexive … R → s_rs_transitive … R (λ_. lex R) →
  56                        ∀L1,L. lex (LTC … R) L1 L →
  57                        ∀L2. lex R L L2 → lex (LTC … R) L1 L2.
  58 /4 width=3 by lex_ltc, lex_inv_ltc, step/ qed-.
  59
  60 lemma lex_ltc_step_sn: ∀R. c_reflexive … R → s_rs_transitive … R (λ_. lex R) →
  61                        ∀L1,L. lex R L1 L →
  62                        ∀L2. lex (LTC … R) L L2 → lex (LTC … R) L1 L2.
  63 /4 width=3 by lex_ltc, lex_inv_ltc, TC_strap/ qed-.