matita/matita/contribs/lambdadelta/basic_2/relocation/lexs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_sle.ma".
  16 include "ground_2/relocation/rtmap_sdj.ma".
  17 include "basic_2/notation/relations/relationstar_5.ma".
  18 include "basic_2/syntax/lenv.ma".
  19
  20 (* GENERIC ENTRYWISE EXTENSION OF CONTEXT-SENSITIVE REALTIONS FOR TERMS *****)
  21
  22 inductive lexs (RN,RP:relation3 lenv bind bind): rtmap → relation lenv ≝
  23 | lexs_atom: ∀f. lexs RN RP f (⋆) (⋆)
  24 | lexs_next: ∀f,I1,I2,L1,L2.
  25              lexs RN RP f L1 L2 → RN L1 I1 I2 →
  26              lexs RN RP (⫯f) (L1.ⓘ{I1}) (L2.ⓘ{I2})
  27 | lexs_push: ∀f,I1,I2,L1,L2.
  28              lexs RN RP f L1 L2 → RP L1 I1 I2 →
  29              lexs RN RP (↑f) (L1.ⓘ{I1}) (L2.ⓘ{I2})
  30 .
  31
  32 interpretation "generic entrywise extension (local environment)"
  33    'RelationStar RN RP f L1 L2 = (lexs RN RP f L1 L2).
  34
  35 definition R_pw_confluent2_lexs: relation3 lenv bind bind → relation3 lenv bind bind →
  36                                  relation3 lenv bind bind → relation3 lenv bind bind →
  37                                  relation3 lenv bind bind → relation3 lenv bind bind →
  38                                  relation3 rtmap lenv bind ≝
  39                                  λR1,R2,RN1,RP1,RN2,RP2,f,L0,T0.
  40                                  ∀T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  41                                  ∀L1. L0 ⪤*[RN1, RP1, f] L1 → ∀L2. L0 ⪤*[RN2, RP2, f] L2 →
  42                                  ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  43
  44 definition lexs_transitive: relation5 (relation3 lenv bind bind)
  45                                       (relation3 lenv bind bind) … ≝
  46                             λR1,R2,R3,RN,RP.
  47                             ∀f,L1,T1,T. R1 L1 T1 T → ∀L2. L1 ⪤*[RN, RP, f] L2 →
  48                             ∀T2. R2 L2 T T2 → R3 L1 T1 T2.
  49
  50 (* Basic inversion lemmas ***************************************************)
  51
  52 fact lexs_inv_atom1_aux: ∀RN,RP,f,X,Y. X ⪤*[RN, RP, f] Y → X = ⋆ → Y = ⋆.
  53 #RN #RP #f #X #Y * -f -X -Y //
  54 #f #I1 #I2 #L1 #L2 #_ #_ #H destruct
  55 qed-.
  56
  57 (* Basic_2A1: includes lpx_sn_inv_atom1 *)
  58 lemma lexs_inv_atom1: ∀RN,RP,f,Y. ⋆ ⪤*[RN, RP, f] Y → Y = ⋆.
  59 /2 width=6 by lexs_inv_atom1_aux/ qed-.
  60
  61 fact lexs_inv_next1_aux: ∀RN,RP,f,X,Y. X ⪤*[RN, RP, f] Y → ∀g,J1,K1. X = K1.ⓘ{J1} → f = ⫯g →
  62                          ∃∃J2,K2. K1 ⪤*[RN, RP, g] K2 & RN K1 J1 J2 & Y = K2.ⓘ{J2}.
  63 #RN #RP #f #X #Y * -f -X -Y
  64 [ #f #g #J1 #K1 #H destruct
  65 | #f #I1 #I2 #L1 #L2 #HL #HI #g #J1 #K1 #H1 #H2 <(injective_next … H2) -g destruct
  66   /2 width=5 by ex3_2_intro/
  67 | #f #I1 #I2 #L1 #L2 #_ #_ #g #J1 #K1 #_ #H elim (discr_push_next … H)
  68 ]
  69 qed-.
  70
  71 (* Basic_2A1: includes lpx_sn_inv_pair1 *)
  72 lemma lexs_inv_next1: ∀RN,RP,g,J1,K1,Y. K1.ⓘ{J1} ⪤*[RN, RP, ⫯g] Y →
  73                       ∃∃J2,K2. K1 ⪤*[RN, RP, g] K2 & RN K1 J1 J2 & Y = K2.ⓘ{J2}.
  74 /2 width=7 by lexs_inv_next1_aux/ qed-.
  75
  76 fact lexs_inv_push1_aux: ∀RN,RP,f,X,Y. X ⪤*[RN, RP, f] Y → ∀g,J1,K1. X = K1.ⓘ{J1} → f = ↑g →
  77                          ∃∃J2,K2. K1 ⪤*[RN, RP, g] K2 & RP K1 J1 J2 & Y = K2.ⓘ{J2}.
  78 #RN #RP #f #X #Y * -f -X -Y
  79 [ #f #g #J1 #K1 #H destruct
  80 | #f #I1 #I2 #L1 #L2 #_ #_ #g #J1 #K1 #_ #H elim (discr_next_push … H)
  81 | #f #I1 #I2 #L1 #L2 #HL #HI #g #J1 #K1 #H1 #H2 <(injective_push … H2) -g destruct
  82   /2 width=5 by ex3_2_intro/
  83 ]
  84 qed-.
  85
  86 lemma lexs_inv_push1: ∀RN,RP,g,J1,K1,Y. K1.ⓘ{J1} ⪤*[RN, RP, ↑g] Y →
  87                       ∃∃J2,K2. K1 ⪤*[RN, RP, g] K2 & RP K1 J1 J2 & Y = K2.ⓘ{J2}.
  88 /2 width=7 by lexs_inv_push1_aux/ qed-.
  89
  90 fact lexs_inv_atom2_aux: ∀RN,RP,f,X,Y. X ⪤*[RN, RP, f] Y → Y = ⋆ → X = ⋆.
  91 #RN #RP #f #X #Y * -f -X -Y //
  92 #f #I1 #I2 #L1 #L2 #_ #_ #H destruct
  93 qed-.
  94
  95 (* Basic_2A1: includes lpx_sn_inv_atom2 *)
  96 lemma lexs_inv_atom2: ∀RN,RP,f,X. X ⪤*[RN, RP, f] ⋆ → X = ⋆.
  97 /2 width=6 by lexs_inv_atom2_aux/ qed-.
  98
  99 fact lexs_inv_next2_aux: ∀RN,RP,f,X,Y. X ⪤*[RN, RP, f] Y → ∀g,J2,K2. Y = K2.ⓘ{J2} → f = ⫯g →
 100                          ∃∃J1,K1. K1 ⪤*[RN, RP, g] K2 & RN K1 J1 J2 & X = K1.ⓘ{J1}.
 101 #RN #RP #f #X #Y * -f -X -Y
 102 [ #f #g #J2 #K2 #H destruct
 103 | #f #I1 #I2 #L1 #L2 #HL #HI #g #J2 #K2 #H1 #H2 <(injective_next … H2) -g destruct
 104   /2 width=5 by ex3_2_intro/
 105 | #f #I1 #I2 #L1 #L2 #_ #_ #g #J2 #K2 #_ #H elim (discr_push_next … H)
 106 ]
 107 qed-.
 108
 109 (* Basic_2A1: includes lpx_sn_inv_pair2 *)
 110 lemma lexs_inv_next2: ∀RN,RP,g,J2,X,K2. X ⪤*[RN, RP, ⫯g] K2.ⓘ{J2} →
 111                       ∃∃J1,K1. K1 ⪤*[RN, RP, g] K2 & RN K1 J1 J2 & X = K1.ⓘ{J1}.
 112 /2 width=7 by lexs_inv_next2_aux/ qed-.
 113
 114 fact lexs_inv_push2_aux: ∀RN,RP,f,X,Y. X ⪤*[RN, RP, f] Y → ∀g,J2,K2. Y = K2.ⓘ{J2} → f = ↑g →
 115                          ∃∃J1,K1. K1 ⪤*[RN, RP, g] K2 & RP K1 J1 J2 & X = K1.ⓘ{J1}.
 116 #RN #RP #f #X #Y * -f -X -Y
 117 [ #f #J2 #K2 #g #H destruct
 118 | #f #I1 #I2 #L1 #L2 #_ #_ #g #J2 #K2 #_ #H elim (discr_next_push … H)
 119 | #f #I1 #I2 #L1 #L2 #HL #HI #g #J2 #K2 #H1 #H2 <(injective_push … H2) -g destruct
 120   /2 width=5 by ex3_2_intro/
 121 ]
 122 qed-.
 123
 124 lemma lexs_inv_push2: ∀RN,RP,g,J2,X,K2. X ⪤*[RN, RP, ↑g] K2.ⓘ{J2} →
 125                       ∃∃J1,K1. K1 ⪤*[RN, RP, g] K2 & RP K1 J1 J2 & X = K1.ⓘ{J1}.
 126 /2 width=7 by lexs_inv_push2_aux/ qed-.
 127
 128 (* Basic_2A1: includes lpx_sn_inv_pair *)
 129 lemma lexs_inv_next: ∀RN,RP,f,I1,I2,L1,L2.
 130                      L1.ⓘ{I1} ⪤*[RN, RP, ⫯f] L2.ⓘ{I2} →
 131                      L1 ⪤*[RN, RP, f] L2 ∧ RN L1 I1 I2.
 132 #RN #RP #f #I1 #I2 #L1 #L2 #H elim (lexs_inv_next1 … H) -H
 133 #I0 #L0 #HL10 #HI10 #H destruct /2 width=1 by conj/
 134 qed-.
 135
 136 lemma lexs_inv_push: ∀RN,RP,f,I1,I2,L1,L2.
 137                      L1.ⓘ{I1} ⪤*[RN, RP, ↑f] L2.ⓘ{I2} →
 138                      L1 ⪤*[RN, RP, f] L2 ∧ RP L1 I1 I2.
 139 #RN #RP #f #I1 #I2 #L1 #L2 #H elim (lexs_inv_push1 … H) -H
 140 #I0 #L0 #HL10 #HI10 #H destruct /2 width=1 by conj/
 141 qed-.
 142
 143 lemma lexs_inv_tl: ∀RN,RP,f,I1,I2,L1,L2. L1 ⪤*[RN, RP, ⫱f] L2 →
 144                    RN L1 I1 I2 → RP L1 I1 I2 →
 145                    L1.ⓘ{I1} ⪤*[RN, RP, f] L2.ⓘ{I2}.
 146 #RN #RP #f #I1 #I2 #L2 #L2 elim (pn_split f) *
 147 /2 width=1 by lexs_next, lexs_push/
 148 qed-.
 149
 150 (* Basic forward lemmas *****************************************************)
 151
 152 lemma lexs_fwd_bind: ∀RN,RP,f,I1,I2,L1,L2.
 153                      L1.ⓘ{I1} ⪤*[RN, RP, f] L2.ⓘ{I2} →
 154                      L1 ⪤*[RN, RP, ⫱f] L2.
 155 #RN #RP #f #I1 #I2 #L1 #L2 #Hf
 156 elim (pn_split f) * #g #H destruct
 157 [ elim (lexs_inv_push … Hf) | elim (lexs_inv_next … Hf) ] -Hf //
 158 qed-.
 159
 160 (* Basic properties *********************************************************)
 161
 162 lemma lexs_eq_repl_back: ∀RN,RP,L1,L2. eq_repl_back … (λf. L1 ⪤*[RN, RP, f] L2).
 163 #RN #RP #L1 #L2 #f1 #H elim H -f1 -L1 -L2 //
 164 #f1 #I1 #I2 #L1 #L2 #_ #HI #IH #f2 #H
 165 [ elim (eq_inv_nx … H) -H /3 width=3 by lexs_next/
 166 | elim (eq_inv_px … H) -H /3 width=3 by lexs_push/
 167 ]
 168 qed-.
 169
 170 lemma lexs_eq_repl_fwd: ∀RN,RP,L1,L2. eq_repl_fwd … (λf. L1 ⪤*[RN, RP, f] L2).
 171 #RN #RP #L1 #L2 @eq_repl_sym /2 width=3 by lexs_eq_repl_back/ (**) (* full auto fails *)
 172 qed-.
 173
 174 lemma lexs_refl: ∀RN,RP. c_reflexive … RN → c_reflexive … RP →
 175                  ∀f.reflexive … (lexs RN RP f).
 176 #RN #RP #HRN #HRP #f #L generalize in match f; -f elim L -L //
 177 #L #I #IH #f elim (pn_split f) *
 178 #g #H destruct /2 width=1 by lexs_next, lexs_push/
 179 qed.
 180
 181 lemma lexs_sym: ∀RN,RP.
 182                 (∀L1,L2,I1,I2. RN L1 I1 I2 → RN L2 I2 I1) →
 183                 (∀L1,L2,I1,I2. RP L1 I1 I2 → RP L2 I2 I1) →
 184                 ∀f. symmetric … (lexs RN RP f).
 185 #RN #RP #HRN #HRP #f #L1 #L2 #H elim H -L1 -L2 -f
 186 /3 width=2 by lexs_next, lexs_push/
 187 qed-.
 188
 189 lemma lexs_pair_repl: ∀RN,RP,f,I1,I2,L1,L2.
 190                       L1.ⓘ{I1} ⪤*[RN, RP, f] L2.ⓘ{I2} →
 191                       ∀J1,J2. RN L1 J1 J2 → RP L1 J1 J2 →
 192                       L1.ⓘ{J1} ⪤*[RN, RP, f] L2.ⓘ{J2}.
 193 /3 width=3 by lexs_inv_tl, lexs_fwd_bind/ qed-.
 194
 195 lemma lexs_co: ∀RN1,RP1,RN2,RP2. RN1 ⊆ RN2 → RP1 ⊆ RP2 →
 196                ∀f,L1,L2. L1 ⪤*[RN1, RP1, f] L2 → L1 ⪤*[RN2, RP2, f] L2.
 197 #RN1 #RP1 #RN2 #RP2 #HRN #HRP #f #L1 #L2 #H elim H -f -L1 -L2
 198 /3 width=1 by lexs_atom, lexs_next, lexs_push/
 199 qed-.
 200
 201 lemma lexs_co_isid: ∀RN1,RP1,RN2,RP2. RP1 ⊆ RP2 →
 202                     ∀f,L1,L2. L1 ⪤*[RN1, RP1, f] L2 → 𝐈⦃f⦄ →
 203                     L1 ⪤*[RN2, RP2, f] L2.
 204 #RN1 #RP1 #RN2 #RP2 #HR #f #L1 #L2 #H elim H -f -L1 -L2 //
 205 #f #I1 #I2 #K1 #K2 #_ #HI12 #IH #H
 206 [ elim (isid_inv_next … H) -H //
 207 | /4 width=3 by lexs_push, isid_inv_push/
 208 ]
 209 qed-.
 210
 211 lemma lexs_sdj: ∀RN,RP. RP ⊆ RN →
 212                 ∀f1,L1,L2. L1 ⪤*[RN, RP, f1] L2 →
 213                 ∀f2. f1 ∥ f2 → L1 ⪤*[RP, RN, f2] L2.
 214 #RN #RP #HR #f1 #L1 #L2 #H elim H -f1 -L1 -L2 //
 215 #f1 #I1 #I2 #L1 #L2 #_ #HI12 #IH #f2 #H12
 216 [ elim (sdj_inv_nx … H12) -H12 [2,3: // ]
 217   #g2 #H #H2 destruct /3 width=1 by lexs_push/
 218 | elim (sdj_inv_px … H12) -H12 [2,4: // ] *
 219   #g2 #H #H2 destruct /3 width=1 by lexs_next, lexs_push/
 220 ]
 221 qed-.
 222
 223 lemma sle_lexs_trans: ∀RN,RP. RN ⊆ RP →
 224                       ∀f2,L1,L2. L1 ⪤*[RN, RP, f2] L2 →
 225                       ∀f1. f1 ⊆ f2 → L1 ⪤*[RN, RP, f1] L2.
 226 #RN #RP #HR #f2 #L1 #L2 #H elim H -f2 -L1 -L2 //
 227 #f2 #I1 #I2 #L1 #L2 #_ #HI12 #IH #f1 #H12
 228 [ elim (pn_split f1) * ]
 229 [ /4 width=5 by lexs_push, sle_inv_pn/
 230 | /4 width=5 by lexs_next, sle_inv_nn/
 231 | elim (sle_inv_xp … H12) -H12 [2,3: // ]
 232   #g1 #H #H1 destruct /3 width=5 by lexs_push/
 233 ]
 234 qed-.
 235
 236 lemma sle_lexs_conf: ∀RN,RP. RP ⊆ RN →
 237                      ∀f1,L1,L2. L1 ⪤*[RN, RP, f1] L2 →
 238                      ∀f2. f1 ⊆ f2 → L1 ⪤*[RN, RP, f2] L2.
 239 #RN #RP #HR #f1 #L1 #L2 #H elim H -f1 -L1 -L2 //
 240 #f1 #I1 #I2 #L1 #L2 #_ #HI12 #IH #f2 #H12
 241 [2: elim (pn_split f2) * ]
 242 [ /4 width=5 by lexs_push, sle_inv_pp/
 243 | /4 width=5 by lexs_next, sle_inv_pn/
 244 | elim (sle_inv_nx … H12) -H12 [2,3: // ]
 245   #g2 #H #H2 destruct /3 width=5 by lexs_next/
 246 ]
 247 qed-.
 248
 249 lemma lexs_sle_split: ∀R1,R2,RP. c_reflexive … R1 → c_reflexive … R2 →
 250                       ∀f,L1,L2. L1 ⪤*[R1, RP, f] L2 → ∀g. f ⊆ g →
 251                       ∃∃L. L1 ⪤*[R1, RP, g] L & L ⪤*[R2, cfull, f] L2.
 252 #R1 #R2 #RP #HR1 #HR2 #f #L1 #L2 #H elim H -f -L1 -L2
 253 [ /2 width=3 by lexs_atom, ex2_intro/ ]
 254 #f #I1 #I2 #L1 #L2 #_ #HI12 #IH #y #H
 255 [ elim (sle_inv_nx … H ??) -H [ |*: // ] #g #Hfg #H destruct
 256   elim (IH … Hfg) -IH -Hfg /3 width=5 by lexs_next, ex2_intro/
 257 | elim (sle_inv_px … H ??) -H [1,3: * |*: // ] #g #Hfg #H destruct
 258   elim (IH … Hfg) -IH -Hfg /3 width=5 by lexs_next, lexs_push, ex2_intro/
 259 ]
 260 qed-.
 261
 262 lemma lexs_sdj_split: ∀R1,R2,RP. c_reflexive … R1 → c_reflexive … R2 →
 263                       ∀f,L1,L2. L1 ⪤*[R1, RP, f] L2 → ∀g. f ∥ g →
 264                       ∃∃L. L1 ⪤*[RP, R1, g] L & L ⪤*[R2, cfull, f] L2.
 265 #R1 #R2 #RP #HR1 #HR2 #f #L1 #L2 #H elim H -f -L1 -L2
 266 [ /2 width=3 by lexs_atom, ex2_intro/ ]
 267 #f #I1 #I2 #L1 #L2 #_ #HI12 #IH #y #H
 268 [ elim (sdj_inv_nx … H ??) -H [ |*: // ] #g #Hfg #H destruct
 269   elim (IH … Hfg) -IH -Hfg /3 width=5 by lexs_next, lexs_push, ex2_intro/
 270 | elim (sdj_inv_px … H ??) -H [1,3: * |*: // ] #g #Hfg #H destruct
 271   elim (IH … Hfg) -IH -Hfg /3 width=5 by lexs_next, lexs_push, ex2_intro/
 272 ]
 273 qed-.
 274
 275 lemma lexs_dec: ∀RN,RP.
 276                 (∀L,I1,I2. Decidable (RN L I1 I2)) →
 277                 (∀L,I1,I2. Decidable (RP L I1 I2)) →
 278                 ∀L1,L2,f. Decidable (L1 ⪤*[RN, RP, f] L2).
 279 #RN #RP #HRN #HRP #L1 elim L1 -L1 [ * | #L1 #I1 #IH * ]
 280 [ /2 width=1 by lexs_atom, or_introl/
 281 | #L2 #I2 #f @or_intror #H
 282   lapply (lexs_inv_atom1 … H) -H #H destruct
 283 | #f @or_intror #H
 284   lapply (lexs_inv_atom2 … H) -H #H destruct
 285 | #L2 #I2 #f elim (IH L2 (⫱f)) -IH #HL12
 286   [2: /4 width=3 by lexs_fwd_bind, or_intror/ ]
 287   elim (pn_split f) * #g #H destruct
 288   [ elim (HRP L1 I1 I2) | elim (HRN L1 I1 I2) ] -HRP -HRN #HV12
 289   [1,3: /3 width=1 by lexs_push, lexs_next, or_introl/ ]
 290   @or_intror #H
 291   [ elim (lexs_inv_push … H) | elim (lexs_inv_next … H) ] -H
 292   /2 width=1 by/
 293 ]
 294 qed-.