matita/matita/contribs/lambdadelta/basic_2/relocation/lexs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/nstream_sle.ma".
  16 include "basic_2/notation/relations/relationstar_5.ma".
  17 include "basic_2/grammar/lenv.ma".
  18
  19 (* GENERAL ENTRYWISE EXTENSION OF A CONTEXT-SENSITIVE REALTION FOR TERMS ****)
  20
  21 (* Basic_2A1: includes: lpx_sn_atom lpx_sn_pair *)
  22 inductive lexs (RN,RP:relation3 lenv term term): rtmap → relation lenv ≝
  23 | lexs_atom: ∀f. lexs RN RP f (⋆) (⋆)
  24 | lexs_next: ∀I,L1,L2,V1,V2,f.
  25              lexs RN RP f L1 L2 → RN L1 V1 V2 →
  26              lexs RN RP (⫯f) (L1.ⓑ{I}V1) (L2.ⓑ{I}V2)
  27 | lexs_push: ∀I,L1,L2,V1,V2,f.
  28              lexs RN RP f L1 L2 → RP L1 V1 V2 →
  29              lexs RN RP (↑f) (L1.ⓑ{I}V1) (L2.ⓑ{I}V2)
  30 .
  31
  32 interpretation "general entrywise extension (local environment)"
  33    'RelationStar RN RP f L1 L2 = (lexs RN RP f L1 L2).
  34
  35 (* Basic inversion lemmas ***************************************************)
  36
  37 fact lexs_inv_atom1_aux: ∀RN,RP,X,Y,f. X ⦻*[RN, RP, f] Y → X = ⋆ → Y = ⋆.
  38 #RN #RP #X #Y #f * -X -Y -f //
  39 #I #L1 #L2 #V1 #V2 #f #_ #_ #H destruct
  40 qed-.
  41
  42 (* Basic_2A1: includes lpx_sn_inv_atom1 *)
  43 lemma lexs_inv_atom1: ∀RN,RP,Y,f. ⋆ ⦻*[RN, RP, f] Y → Y = ⋆.
  44 /2 width=6 by lexs_inv_atom1_aux/ qed-.
  45
  46 fact lexs_inv_next1_aux: ∀RN,RP,X,Y,f. X ⦻*[RN, RP, f] Y → ∀J,K1,W1,g. X = K1.ⓑ{J}W1 → f = ⫯g →
  47                          ∃∃K2,W2. K1 ⦻*[RN, RP, g] K2 & RN K1 W1 W2 & Y = K2.ⓑ{J}W2.
  48 #RN #RP #X #Y #f * -X -Y -f
  49 [ #f #J #K1 #W1 #g #H destruct
  50 | #I #L1 #L2 #V1 #V2 #f #HL #HV #J #K1 #W1 #g #H1 #H2 <(injective_next … H2) -g destruct
  51   /2 width=5 by ex3_2_intro/
  52 | #I #L1 #L2 #V1 #V2 #f #_ #_ #J #K1 #W1 #g #_ #H elim (discr_push_next … H)
  53 ]
  54 qed-.
  55
  56 (* Basic_2A1: includes lpx_sn_inv_pair1 *)
  57 lemma lexs_inv_next1: ∀RN,RP,J,K1,Y,W1,g. K1.ⓑ{J}W1 ⦻*[RN, RP, ⫯g] Y →
  58                       ∃∃K2,W2. K1 ⦻*[RN, RP, g] K2 & RN K1 W1 W2 & Y = K2.ⓑ{J}W2.
  59 /2 width=7 by lexs_inv_next1_aux/ qed-.
  60
  61
  62 fact lexs_inv_push1_aux: ∀RN,RP,X,Y,f. X ⦻*[RN, RP, f] Y → ∀J,K1,W1,g. X = K1.ⓑ{J}W1 → f = ↑g →
  63                          ∃∃K2,W2. K1 ⦻*[RN, RP, g] K2 & RP K1 W1 W2 & Y = K2.ⓑ{J}W2.
  64 #RN #RP #X #Y #f * -X -Y -f
  65 [ #f #J #K1 #W1 #g #H destruct
  66 | #I #L1 #L2 #V1 #V2 #f #_ #_ #J #K1 #W1 #g #_ #H elim (discr_next_push … H)
  67 | #I #L1 #L2 #V1 #V2 #f #HL #HV #J #K1 #W1 #g #H1 #H2 <(injective_push … H2) -g destruct
  68   /2 width=5 by ex3_2_intro/
  69 ]
  70 qed-.
  71
  72 lemma lexs_inv_push1: ∀RN,RP,J,K1,Y,W1,g. K1.ⓑ{J}W1 ⦻*[RN, RP, ↑g] Y →
  73                       ∃∃K2,W2. K1 ⦻*[RN, RP, g] K2 & RP K1 W1 W2 & Y = K2.ⓑ{J}W2.
  74 /2 width=7 by lexs_inv_push1_aux/ qed-.
  75
  76 fact lexs_inv_atom2_aux: ∀RN,RP,X,Y,f. X ⦻*[RN, RP, f] Y → Y = ⋆ → X = ⋆.
  77 #RN #RP #X #Y #f * -X -Y -f //
  78 #I #L1 #L2 #V1 #V2 #f #_ #_ #H destruct
  79 qed-.
  80
  81 (* Basic_2A1: includes lpx_sn_inv_atom2 *)
  82 lemma lexs_inv_atom2: ∀RN,RP,X,f. X ⦻*[RN, RP, f] ⋆ → X = ⋆.
  83 /2 width=6 by lexs_inv_atom2_aux/ qed-.
  84
  85 fact lexs_inv_next2_aux: ∀RN,RP,X,Y,f. X ⦻*[RN, RP, f] Y → ∀J,K2,W2,g. Y = K2.ⓑ{J}W2 → f = ⫯g →
  86                          ∃∃K1,W1. K1 ⦻*[RN, RP, g] K2 & RN K1 W1 W2 & X = K1.ⓑ{J}W1.
  87 #RN #RP #X #Y #f * -X -Y -f
  88 [ #f #J #K2 #W2 #g #H destruct
  89 | #I #L1 #L2 #V1 #V2 #f #HL #HV #J #K2 #W2 #g #H1 #H2 <(injective_next … H2) -g destruct
  90   /2 width=5 by ex3_2_intro/
  91 | #I #L1 #L2 #V1 #V2 #f #_ #_ #J #K2 #W2 #g #_ #H elim (discr_push_next … H)
  92 ]
  93 qed-.
  94
  95 (* Basic_2A1: includes lpx_sn_inv_pair2 *)
  96 lemma lexs_inv_next2: ∀RN,RP,J,X,K2,W2,g. X ⦻*[RN, RP, ⫯g] K2.ⓑ{J}W2 →
  97                       ∃∃K1,W1. K1 ⦻*[RN, RP, g] K2 & RN K1 W1 W2 & X = K1.ⓑ{J}W1.
  98 /2 width=7 by lexs_inv_next2_aux/ qed-.
  99
 100 fact lexs_inv_push2_aux: ∀RN,RP,X,Y,f. X ⦻*[RN, RP, f] Y → ∀J,K2,W2,g. Y = K2.ⓑ{J}W2 → f = ↑g →
 101                          ∃∃K1,W1. K1 ⦻*[RN, RP, g] K2 & RP K1 W1 W2 & X = K1.ⓑ{J}W1.
 102 #RN #RP #X #Y #f * -X -Y -f
 103 [ #f #J #K2 #W2 #g #H destruct
 104 | #I #L1 #L2 #V1 #V2 #f #_ #_ #J #K2 #W2 #g #_ #H elim (discr_next_push … H)
 105 | #I #L1 #L2 #V1 #V2 #f #HL #HV #J #K2 #W2 #g #H1 #H2 <(injective_push … H2) -g destruct
 106   /2 width=5 by ex3_2_intro/
 107 ]
 108 qed-.
 109
 110 lemma lexs_inv_push2: ∀RN,RP,J,X,K2,W2,g. X ⦻*[RN, RP, ↑g] K2.ⓑ{J}W2 →
 111                       ∃∃K1,W1. K1 ⦻*[RN, RP, g] K2 & RP K1 W1 W2 & X = K1.ⓑ{J}W1.
 112 /2 width=7 by lexs_inv_push2_aux/ qed-.
 113
 114 (* Basic_2A1: includes lpx_sn_inv_pair *)
 115 lemma lexs_inv_next: ∀RN,RP,I1,I2,L1,L2,V1,V2,f.
 116                      L1.ⓑ{I1}V1 ⦻*[RN, RP, ⫯f] (L2.ⓑ{I2}V2) →
 117                      ∧∧ L1 ⦻*[RN, RP, f] L2 & RN L1 V1 V2 & I1 = I2.
 118 #RN #RP #I1 #I2 #L1 #L2 #V1 #V2 #f #H elim (lexs_inv_next1 … H) -H
 119 #L0 #V0 #HL10 #HV10 #H destruct /2 width=1 by and3_intro/
 120 qed-.
 121
 122 lemma lexs_inv_push: ∀RN,RP,I1,I2,L1,L2,V1,V2,f.
 123                      L1.ⓑ{I1}V1 ⦻*[RN, RP, ↑f] (L2.ⓑ{I2}V2) →
 124                      ∧∧ L1 ⦻*[RN, RP, f] L2 & RP L1 V1 V2 & I1 = I2.
 125 #RN #RP #I1 #I2 #L1 #L2 #V1 #V2 #f #H elim (lexs_inv_push1 … H) -H
 126 #L0 #V0 #HL10 #HV10 #H destruct /2 width=1 by and3_intro/
 127 qed-.
 128
 129 (* Basic properties *********************************************************)
 130
 131 lemma lexs_eq_repl_back: ∀RN,RP,L1,L2. eq_stream_repl_back … (λf. L1 ⦻*[RN, RP, f] L2).
 132 #RN #RP #L1 #L2 #f1 #H elim H -L1 -L2 -f1 //
 133 #I #L1 #L2 #V1 #v2 #f1 #_ #HV #IH #f2 #H
 134 [ elim (next_inv_sn … H) -H /3 width=1 by lexs_next/
 135 | elim (push_inv_sn … H) -H /3 width=1 by lexs_push/
 136 ]
 137 qed-.
 138
 139 lemma lexs_eq_repl_fwd: ∀RN,RP,L1,L2. eq_stream_repl_fwd … (λf. L1 ⦻*[RN, RP, f] L2).
 140 #RN #RP #L1 #L2 @eq_stream_repl_sym /2 width=3 by lexs_eq_repl_back/ (**) (* full auto fails *)
 141 qed-.
 142
 143 (* Note: fexs_sym and fexs_trans hold, but lexs_sym and lexs_trans do not  *)
 144 (* Basic_2A1: includes: lpx_sn_refl *)
 145 lemma lexs_refl: ∀RN,RP,f.
 146                  (∀L. reflexive … (RN L)) →
 147                  (∀L. reflexive … (RP L)) →
 148                  reflexive … (lexs RN RP f).
 149 #RN #RP #f #HRN #HRP #L generalize in match f; -f elim L -L //
 150 #L #I #V #IH * * /2 width=1 by lexs_next, lexs_push/
 151 qed.
 152
 153 lemma sle_lexs_trans: ∀RN,RP. (∀L,T1,T2. RN L T1 T2 → RP L T1 T2) →
 154                       ∀L1,L2,f2. L1 ⦻*[RN, RP, f2] L2 →
 155                       ∀f1. f1 ⊆ f2 → L1 ⦻*[RN, RP, f1] L2.
 156 #RN #RP #HR #L1 #L2 #f2 #H elim H -L1 -L2 -f2 //
 157 #I #L1 #L2 #V1 #V2 #f2 #_ #HV12 #IH
 158 [ * * [2: #n1 ] ] #f1 #H
 159 [ /4 width=5 by lexs_next, sle_inv_SS_aux/
 160 | /4 width=5 by lexs_push, sle_inv_OS_aux/
 161 | elim (sle_inv_xO_aux … H) -H [3: // |2: skip ]
 162   #g1 #H #H1 destruct /3 width=5 by lexs_push/
 163 ]
 164 qed-.
 165
 166 lemma sle_lexs_conf: ∀RN,RP. (∀L,T1,T2. RP L T1 T2 → RN L T1 T2) →
 167                      ∀L1,L2,f1. L1 ⦻*[RN, RP, f1] L2 →
 168                      ∀f2. f1 ⊆ f2 → L1 ⦻*[RN, RP, f2] L2.
 169 #RN #RP #HR #L1 #L2 #f2 #H elim H -L1 -L2 -f2 //
 170 #I #L1 #L2 #V1 #V2 #f1 #_ #HV12 #IH
 171 [2: * * [2: #n2 ] ] #f2 #H
 172 [ /4 width=5 by lexs_next, sle_inv_OS_aux/
 173 | /4 width=5 by lexs_push, sle_inv_OO_aux/
 174 | elim (sle_inv_Sx_aux … H) -H [3: // |2: skip ]
 175   #g2 #H #H2 destruct /3 width=5 by lexs_next/
 176 ]
 177 qed-.
 178
 179 lemma lexs_co: ∀RN1,RP1,RN2,RP2.
 180                (∀L1,T1,T2. RN1 L1 T1 T2 → RN2 L1 T1 T2) →
 181                (∀L1,T1,T2. RP1 L1 T1 T2 → RP2 L1 T1 T2) →
 182                ∀L1,L2,f. L1 ⦻*[RN1, RP1, f] L2 → L1 ⦻*[RN2, RP2, f] L2.
 183 #RN1 #RP1 #RN2 #RP2 #HRN #HRP #L1 #L2 #f #H elim H -L1 -L2 -f
 184 /3 width=1 by lexs_atom, lexs_next, lexs_push/
 185 qed-.
 186
 187 (* Basic_2A1: removed theorems 17:
 188               llpx_sn_inv_bind llpx_sn_inv_flat
 189               llpx_sn_fwd_lref llpx_sn_fwd_pair_sn llpx_sn_fwd_length
 190               llpx_sn_fwd_bind_sn llpx_sn_fwd_bind_dx llpx_sn_fwd_flat_sn llpx_sn_fwd_flat_dx
 191               llpx_sn_refl llpx_sn_Y llpx_sn_bind_O llpx_sn_ge_up llpx_sn_ge llpx_sn_co
 192               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 193 *)