matita/matita/contribs/lambdadelta/basic_2/relocation/lexs_lexs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_sand.ma".
  16 include "basic_2/relocation/drops.ma".
  17
  18 (* GENERIC ENTRYWISE EXTENSION OF CONTEXT-SENSITIVE REALTIONS FOR TERMS *****)
  19
  20 (* Main properties **********************************************************)
  21
  22 theorem lexs_trans_gen (RN1) (RP1) (RN2) (RP2) (RN) (RP) (f):
  23                        lexs_transitive RN1 RN2 RN RN1 RP1 →
  24                        lexs_transitive RP1 RP2 RP RN1 RP1 →
  25                        ∀L1,L0. L1 ⪤*[RN1, RP1, f] L0 →
  26                        ∀L2. L0 ⪤*[RN2, RP2, f] L2 →
  27                        L1 ⪤*[RN, RP, f] L2.
  28 #RN1 #RP1 #RN2 #RP2 #RN #RP #f #HN #HP #L1 #L0 #H elim H -f -L1 -L0
  29 [ #f #L2 #H >(lexs_inv_atom1 … H) -L2 //
  30 | #f #I1 #I #K1 #K #HK1 #HI1 #IH #L2 #H elim (lexs_inv_next1 … H) -H
  31   #I2 #K2 #HK2 #HI2 #H destruct /4 width=6 by lexs_next/
  32 | #f #I1 #I #K1 #K #HK1 #HI1 #IH #L2 #H elim (lexs_inv_push1 … H) -H
  33   #I2 #K2 #HK2 #HI2 #H destruct /4 width=6 by lexs_push/
  34 ]
  35 qed-.
  36
  37 (* Basic_2A1: includes: lpx_sn_trans *)
  38 theorem lexs_trans (RN) (RP) (f): lexs_transitive RN RN RN RN RP →
  39                                   lexs_transitive RP RP RP RN RP →
  40                                   Transitive … (lexs RN RP f).
  41 /2 width=9 by lexs_trans_gen/ qed-.
  42
  43 theorem lexs_trans_id_cfull: ∀R1,R2,R3,L1,L,f. L1 ⪤*[R1, cfull, f] L → 𝐈⦃f⦄ →
  44                              ∀L2.  L ⪤*[R2, cfull, f] L2 → L1 ⪤*[R3, cfull, f] L2.
  45 #R1 #R2 #R3 #L1 #L #f #H elim H -L1 -L -f
  46 [ #f #Hf #L2 #H >(lexs_inv_atom1 … H) -L2 // ]
  47 #f #I1 #I #K1 #K #HK1 #_ #IH #Hf #L2 #H
  48 [ elim (isid_inv_next … Hf) | lapply (isid_inv_push … Hf ??) ] -Hf [5: |*: // ] #Hf
  49 elim (lexs_inv_push1 … H) -H #I2 #K2 #HK2 #_ #H destruct
  50 /3 width=1 by lexs_push/
  51 qed-.
  52
  53 (* Basic_2A1: includes: lpx_sn_conf *)
  54 theorem lexs_conf (RN1) (RP1) (RN2) (RP2):
  55                   ∀L,f.
  56                   (∀g,I,K,n. ⬇*[n] L ≡ K.ⓘ{I} → ⫯g = ⫱*[n] f → R_pw_confluent2_lexs RN1 RN2 RN1 RP1 RN2 RP2 g K I) →
  57                   (∀g,I,K,n. ⬇*[n] L ≡ K.ⓘ{I} → ↑g = ⫱*[n] f → R_pw_confluent2_lexs RP1 RP2 RN1 RP1 RN2 RP2 g K I) →
  58                   pw_confluent2 … (lexs RN1 RP1 f) (lexs RN2 RP2 f) L.
  59 #RN1 #RP1 #RN2 #RP2 #L elim L -L
  60 [ #f #_ #_ #L1 #H1 #L2 #H2 >(lexs_inv_atom1 … H1) >(lexs_inv_atom1 … H2) -H2 -H1
  61   /2 width=3 by lexs_atom, ex2_intro/
  62 | #L #I0 #IH #f elim (pn_split f) * #g #H destruct
  63   #HN #HP #Y1 #H1 #Y2 #H2
  64   [ elim (lexs_inv_push1 … H1) -H1 #I1 #L1 #HL1 #HI01 #H destruct
  65     elim (lexs_inv_push1 … H2) -H2 #I2 #L2 #HL2 #HI02 #H destruct
  66     elim (HP … 0 … HI01 … HI02 … HL1 … HL2) -HI01 -HI02 /2 width=2 by drops_refl/ #I #HI1 #HI2
  67     elim (IH … HL1 … HL2) -IH -HL1 -HL2 /3 width=5 by drops_drop, lexs_push, ex2_intro/
  68   | elim (lexs_inv_next1 … H1) -H1 #I1 #L1 #HL1 #HI01 #H destruct
  69     elim (lexs_inv_next1 … H2) -H2 #I2 #L2 #HL2 #HI02 #H destruct
  70     elim (HN … 0 … HI01 … HI02 … HL1 … HL2) -HI01 -HI02 /2 width=2 by drops_refl/ #I #HI1 #HI2
  71     elim (IH … HL1 … HL2) -IH -HL1 -HL2 /3 width=5 by drops_drop, lexs_next, ex2_intro/
  72   ]
  73 ]
  74 qed-.
  75
  76 theorem lexs_canc_sn: ∀RN,RP,f. Transitive … (lexs RN RP f) →
  77                                 symmetric … (lexs RN RP f) →
  78                                 left_cancellable … (lexs RN RP f).
  79 /3 width=3 by/ qed-.
  80
  81 theorem lexs_canc_dx: ∀RN,RP,f. Transitive … (lexs RN RP f) →
  82                                 symmetric … (lexs RN RP f) →
  83                                 right_cancellable … (lexs RN RP f).
  84 /3 width=3 by/ qed-.
  85
  86 lemma lexs_meet: ∀RN,RP,L1,L2.
  87                  ∀f1. L1 ⪤*[RN, RP, f1] L2 →
  88                  ∀f2. L1 ⪤*[RN, RP, f2] L2 →
  89                  ∀f. f1 ⋒ f2 ≡ f → L1 ⪤*[RN, RP, f] L2.
  90 #RN #RP #L1 #L2 #f1 #H elim H -f1 -L1 -L2 //
  91 #f1 #I1 #I2 #L1 #L2 #_ #HI12 #IH #f2 #H #f #Hf
  92 elim (pn_split f2) * #g2 #H2 destruct
  93 try elim (lexs_inv_push … H) try elim (lexs_inv_next … H) -H
  94 [ elim (sand_inv_npx … Hf) | elim (sand_inv_nnx … Hf)
  95 | elim (sand_inv_ppx … Hf) | elim (sand_inv_pnx … Hf)
  96 ] -Hf /3 width=5 by lexs_next, lexs_push/
  97 qed-.
  98
  99 lemma lexs_join: ∀RN,RP,L1,L2.
 100                  ∀f1. L1 ⪤*[RN, RP, f1] L2 →
 101                  ∀f2. L1 ⪤*[RN, RP, f2] L2 →
 102                  ∀f. f1 ⋓ f2 ≡ f → L1 ⪤*[RN, RP, f] L2.
 103 #RN #RP #L1 #L2 #f1 #H elim H -f1 -L1 -L2 //
 104 #f1 #I1 #I2 #L1 #L2 #_ #HI12 #IH #f2 #H #f #Hf
 105 elim (pn_split f2) * #g2 #H2 destruct
 106 try elim (lexs_inv_push … H) try elim (lexs_inv_next … H) -H
 107 [ elim (sor_inv_npx … Hf) | elim (sor_inv_nnx … Hf)
 108 | elim (sor_inv_ppx … Hf) | elim (sor_inv_pnx … Hf)
 109 ] -Hf /3 width=5 by lexs_next, lexs_push/
 110 qed-.