matita/matita/contribs/lambdadelta/basic_2/relocation/lexs_lexs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_sand.ma".
  16 include "ground_2/relocation/rtmap_sor.ma".
  17 include "basic_2/relocation/lexs.ma".
  18
  19 (* GENERIC ENTRYWISE EXTENSION OF CONTEXT-SENSITIVE REALTIONS FOR TERMS *****)
  20
  21 (* Main properties **********************************************************)
  22
  23 theorem lexs_trans_gen (RN1) (RP1) (RN2) (RP2) (RN) (RP) (f):
  24                        lexs_transitive RN1 RN2 RN RN1 RP1 →
  25                        lexs_transitive RP1 RP2 RP RN1 RP1 →
  26                        ∀L1,L0. L1 ⦻*[RN1, RP1, f] L0 →
  27                        ∀L2. L0 ⦻*[RN2, RP2, f] L2 →
  28                        L1 ⦻*[RN, RP, f] L2.
  29 #RN1 #RP1 #RN2 #RP2 #RN #RP #f #HN #HP #L1 #L0 #H elim H -f -L1 -L0
  30 [ #f #L2 #H >(lexs_inv_atom1 … H) -L2 //
  31 | #f #I #K1 #K #V1 #V #HK1 #HV1 #IH #L2 #H elim (lexs_inv_next1 … H) -H
  32   #K2 #V2 #HK2 #HV2 #H destruct /4 width=6 by lexs_next/
  33 | #f #I #K1 #K #V1 #V #HK1 #HV1 #IH #L2 #H elim (lexs_inv_push1 … H) -H
  34   #K2 #V2 #HK2 #HV2 #H destruct /4 width=6 by lexs_push/
  35 ]
  36 qed-.
  37
  38 (* Basic_2A1: includes: lpx_sn_trans *)
  39 theorem lexs_trans (RN) (RP) (f): lexs_transitive RN RN RN RN RP →
  40                                   lexs_transitive RP RP RP RN RP →
  41                                   Transitive … (lexs RN RP f).
  42 /2 width=9 by lexs_trans_gen/ qed-.
  43
  44 (* Basic_2A1: includes: lpx_sn_conf *)
  45 theorem lexs_conf (RN1) (RP1) (RN2) (RP2): lexs_confluent RN1 RN2 RN1 RP1 RN2 RP2 →
  46                                            lexs_confluent RP1 RP2 RN1 RP1 RN2 RP2 →
  47                                            ∀f. confluent2 … (lexs RN1 RP1 f) (lexs RN2 RP2 f).
  48 #RN1 #RP1 #RN2 #RP2 #HRN #HRP #f #L0
  49 generalize in match f; -f elim L0 -L0
  50 [ #f #L1 #HL01 #L2 #HL02 -HRN -HRP
  51   lapply (lexs_inv_atom1 … HL01) -HL01 #H destruct
  52   lapply (lexs_inv_atom1 … HL02) -HL02 #H destruct
  53   /2 width=3 by ex2_intro/
  54 | #K0 #I #V0 #IH #f #L1 #HL01 #L2 #HL02
  55   elim (pn_split f) * #g #H destruct
  56   [ elim (lexs_inv_push1 … HL01) -HL01 #K1 #V1 #HK01 #HV01 #H destruct
  57     elim (lexs_inv_push1 … HL02) -HL02 #K2 #V2 #HK02 #HV02 #H destruct
  58     elim (IH … HK01 … HK02) -IH #K #HK1 #HK2
  59     elim (HRP … HV01 … HV02 … HK01 … HK02) -HRP -HRN -K0 -V0
  60     /3 width=5 by lexs_push, ex2_intro/
  61   | elim (lexs_inv_next1 … HL01) -HL01 #K1 #V1 #HK01 #HV01 #H destruct
  62     elim (lexs_inv_next1 … HL02) -HL02 #K2 #V2 #HK02 #HV02 #H destruct
  63     elim (IH … HK01 … HK02) -IH #K #HK1 #HK2
  64     elim (HRN … HV01 … HV02 … HK01 … HK02) -HRN -HRP -K0 -V0
  65     /3 width=5 by lexs_next, ex2_intro/
  66   ]
  67 ]
  68 qed-.
  69
  70 theorem lexs_canc_sn: ∀RN,RP,f. Transitive … (lexs RN RP f) →
  71                                 symmetric … (lexs RN RP f) →
  72                                 left_cancellable … (lexs RN RP f).
  73 /3 width=3 by/ qed-.
  74
  75 theorem lexs_canc_dx: ∀RN,RP,f. Transitive … (lexs RN RP f) →
  76                                 symmetric … (lexs RN RP f) →
  77                                 right_cancellable … (lexs RN RP f).
  78 /3 width=3 by/ qed-.
  79
  80 lemma lexs_meet: ∀RN,RP,L1,L2.
  81                  ∀f1. L1 ⦻*[RN, RP, f1] L2 →
  82                  ∀f2. L1 ⦻*[RN, RP, f2] L2 →
  83                  ∀f. f1 ⋒ f2 ≡ f → L1 ⦻*[RN, RP, f] L2.
  84 #RN #RP #L1 #L2 #f1 #H elim H -f1 -L1 -L2 //
  85 #f1 #I #L1 #L2 #V1 #V2 #_ #HV12 #IH #f2 #H #f #Hf
  86 elim (pn_split f2) * #g2 #H2 destruct
  87 try elim (lexs_inv_push … H) try elim (lexs_inv_next … H) -H
  88 [ elim (sand_inv_npx … Hf) | elim (sand_inv_nnx … Hf)
  89 | elim (sand_inv_ppx … Hf) | elim (sand_inv_pnx … Hf)
  90 ] -Hf /3 width=5 by lexs_next, lexs_push/
  91 qed-.
  92
  93 lemma lexs_join: ∀RN,RP,L1,L2.
  94                  ∀f1. L1 ⦻*[RN, RP, f1] L2 →
  95                  ∀f2. L1 ⦻*[RN, RP, f2] L2 →
  96                  ∀f. f1 ⋓ f2 ≡ f → L1 ⦻*[RN, RP, f] L2.
  97 #RN #RP #L1 #L2 #f1 #H elim H -f1 -L1 -L2 //
  98 #f1 #I #L1 #L2 #V1 #V2 #_ #HV12 #IH #f2 #H #f #Hf
  99 elim (pn_split f2) * #g2 #H2 destruct
 100 try elim (lexs_inv_push … H) try elim (lexs_inv_next … H) -H
 101 [ elim (sor_inv_npx … Hf) | elim (sor_inv_nnx … Hf)
 102 | elim (sor_inv_ppx … Hf) | elim (sor_inv_pnx … Hf)
 103 ] -Hf /3 width=5 by lexs_next, lexs_push/
 104 qed-.