matita/matita/contribs/lambdadelta/basic_2/relocation/lexs_lexs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_sand.ma".
  16 include "ground_2/relocation/rtmap_sor.ma".
  17 include "basic_2/grammar/lenv_weight.ma".
  18 include "basic_2/relocation/lexs.ma".
  19
  20 (* GENERAL ENTRYWISE EXTENSION OF A CONTEXT-SENSITIVE REALTION FOR TERMS ****)
  21
  22 (* Main properties **********************************************************)
  23
  24 (* Basic_2A1: includes: lpx_sn_trans *)
  25 theorem lexs_trans (RN) (RP) (f): lexs_transitive RN RN RN RP →
  26                                   lexs_transitive RP RP RN RP →
  27                                   Transitive … (lexs RN RP f).
  28 #RN #RP #f #HN #HP #L1 #L0 #H elim H -L1 -L0 -f
  29 [ #f #L2 #H >(lexs_inv_atom1 … H) -L2 //
  30 | #I #K1 #K #V1 #V #f #HK1 #HV1 #IH #L2 #H elim (lexs_inv_next1 … H) -H
  31   #K2 #V2 #HK2 #HV2 #H destruct /4 width=6 by lexs_next/
  32 | #I #K1 #K #V1 #V #f #HK1 #HV1 #IH #L2 #H elim (lexs_inv_push1 … H) -H
  33   #K2 #V2 #HK2 #HV2 #H destruct /4 width=6 by lexs_push/
  34 ]
  35 qed-.
  36
  37 (* Basic_2A1: includes: lpx_sn_conf *)
  38 theorem lexs_conf: ∀RN1,RP1,RN2,RP2.
  39                    lpx_sn_confluent RN1 RN2 RN1 RP1 RN2 RP2 →
  40                    lpx_sn_confluent RP1 RP2 RN1 RP1 RN2 RP2 →
  41                    ∀f. confluent2 … (lexs RN1 RP1 f) (lexs RN2 RP2 f).
  42 #RN1 #RP1 #RN2 #RP2 #HRN #HRP #f #L0 generalize in match f; -f
  43 @(f_ind … lw … L0) -L0 #x #IH *
  44 [ #_ #f #X1 #H1 #X2 #H2 -x
  45   >(lexs_inv_atom1 … H1) -X1
  46   >(lexs_inv_atom1 … H2) -X2 /2 width=3 by lexs_atom, ex2_intro/
  47 | #L0 #I #V0 #Hx #f elim (pn_split f) *
  48   #g #H #X1 #H1 #X2 #H2 destruct
  49   [ elim (lexs_inv_push1 … H1) -H1 #L1 #V1 #HL01 #HV01 #H destruct
  50     elim (lexs_inv_push1 … H2) -H2 #L2 #V2 #HL02 #HV02 #H destruct
  51     elim (IH … HL01 … HL02) -IH // #L #HL1 #HL2
  52     elim (HRP … HV01 … HV02 … HL01 … HL02) -L0 -V0 /3 width=5 by lexs_push, ex2_intro/
  53   | elim (lexs_inv_next1 … H1) -H1 #L1 #V1 #HL01 #HV01 #H destruct
  54     elim (lexs_inv_next1 … H2) -H2 #L2 #V2 #HL02 #HV02 #H destruct
  55     elim (IH … HL01 … HL02) -IH // #L #HL1 #HL2
  56     elim (HRN … HV01 … HV02 … HL01 … HL02) -L0 -V0 /3 width=5 by lexs_next, ex2_intro/
  57   ]
  58 ]
  59 qed-.
  60
  61 theorem lexs_canc_sx: ∀RN,RP,f. Transitive … (lexs RN RP f) →
  62                                 symmetric … (lexs RN RP f) →
  63                                 left_cancellable … (lexs RN RP f).
  64 /3 width=3 by/ qed-.
  65
  66 theorem lexs_canc_dx: ∀RN,RP,f. Transitive … (lexs RN RP f) →
  67                                 symmetric … (lexs RN RP f) →
  68                                 right_cancellable … (lexs RN RP f).
  69 /3 width=3 by/ qed-.
  70
  71 theorem lexs_meet: ∀RN,RP,L1,L2,f1. L1 ⦻*[RN, RP, f1] L2 →
  72                    ∀f2. L1 ⦻*[RN, RP, f2] L2 →
  73                    ∀f. f1 ⋒ f2 ≡ f → L1 ⦻*[RN, RP, f] L2.
  74 #RN #RP #L1 #L2 #f1 #H elim H -L1 -L2 -f1 //
  75 #I #L1 #L2 #V1 #V2 #f1 #_ #H1V #IH #f2 elim (pn_split f2) *
  76 #g2 #H #H2 #f #Hf destruct
  77 [1,3: elim (lexs_inv_push … H2) |2,4: elim (lexs_inv_next … H2) ] -H2
  78 #H2 #H2V #_
  79 [ elim (sand_inv_npx … Hf) | elim (sand_inv_ppx … Hf) | elim (sand_inv_nnx … Hf) | elim (sand_inv_pnx … Hf) ] -Hf
  80 /3 width=5 by lexs_next, lexs_push/
  81 qed-.
  82
  83 theorem lexs_join: ∀RN,RP,L1,L2,f1. L1 ⦻*[RN, RP, f1] L2 →
  84                    ∀f2. L1 ⦻*[RN, RP, f2] L2 →
  85                    ∀f. f1 ⋓ f2 ≡ f → L1 ⦻*[RN, RP, f] L2.
  86 #RN #RP #L1 #L2 #f1 #H elim H -L1 -L2 -f1 //
  87 #I #L1 #L2 #V1 #V2 #f1 #_ #H1V #IH #f2 elim (pn_split f2) *
  88 #g2 #H #H2 #f #Hf destruct
  89 [1,3: elim (lexs_inv_push … H2) |2,4: elim (lexs_inv_next … H2) ] -H2
  90 #H2 #H2V #_
  91 [ elim (sor_inv_npx … Hf) | elim (sor_inv_ppx … Hf) | elim (sor_inv_nnx … Hf) | elim (sor_inv_pnx … Hf) ] -Hf
  92 /3 width=5 by lexs_next, lexs_push/
  93 qed-.