matita/matita/contribs/lambdadelta/basic_2/relocation/lexs_lexs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_sand.ma".
  16 include "ground_2/relocation/rtmap_sor.ma".
  17 include "basic_2/relocation/lexs.ma".
  18 include "basic_2/relocation/drops.ma".
  19
  20 (* GENERIC ENTRYWISE EXTENSION OF CONTEXT-SENSITIVE REALTIONS FOR TERMS *****)
  21
  22 (* Main properties **********************************************************)
  23
  24 theorem lexs_trans_gen (RN1) (RP1) (RN2) (RP2) (RN) (RP) (f):
  25                        lexs_transitive RN1 RN2 RN RN1 RP1 →
  26                        lexs_transitive RP1 RP2 RP RN1 RP1 →
  27                        ∀L1,L0. L1 ⦻*[RN1, RP1, f] L0 →
  28                        ∀L2. L0 ⦻*[RN2, RP2, f] L2 →
  29                        L1 ⦻*[RN, RP, f] L2.
  30 #RN1 #RP1 #RN2 #RP2 #RN #RP #f #HN #HP #L1 #L0 #H elim H -f -L1 -L0
  31 [ #f #L2 #H >(lexs_inv_atom1 … H) -L2 //
  32 | #f #I #K1 #K #V1 #V #HK1 #HV1 #IH #L2 #H elim (lexs_inv_next1 … H) -H
  33   #K2 #V2 #HK2 #HV2 #H destruct /4 width=6 by lexs_next/
  34 | #f #I #K1 #K #V1 #V #HK1 #HV1 #IH #L2 #H elim (lexs_inv_push1 … H) -H
  35   #K2 #V2 #HK2 #HV2 #H destruct /4 width=6 by lexs_push/
  36 ]
  37 qed-.
  38
  39 (* Basic_2A1: includes: lpx_sn_trans *)
  40 theorem lexs_trans (RN) (RP) (f): lexs_transitive RN RN RN RN RP →
  41                                   lexs_transitive RP RP RP RN RP →
  42                                   Transitive … (lexs RN RP f).
  43 /2 width=9 by lexs_trans_gen/ qed-.
  44
  45 (* Basic_2A1: includes: lpx_sn_conf *)
  46 theorem lexs_conf (RN1) (RP1) (RN2) (RP2):
  47                   ∀L,f.
  48                   (∀g,I,K,V,n. ⬇*[n] L ≡ K.ⓑ{I}V → ⫯g = ⫱*[n] f → lexs_pw_confluent2_R RN1 RN2 RN1 RP1 RN2 RP2 g K V) →
  49                   (∀g,I,K,V,n. ⬇*[n] L ≡ K.ⓑ{I}V → ↑g = ⫱*[n] f → lexs_pw_confluent2_R RP1 RP2 RN1 RP1 RN2 RP2 g K V) →
  50                   pw_confluent2 … (lexs RN1 RP1 f) (lexs RN2 RP2 f) L.
  51 #RN1 #RP1 #RN2 #RP2 #L elim L -L
  52 [ #f #_ #_ #L1 #H1 #L2 #H2 >(lexs_inv_atom1 … H1) >(lexs_inv_atom1 … H2) -H2 -H1
  53   /2 width=3 by lexs_atom, ex2_intro/
  54 | #L #I #V #IH #f elim (pn_split f) * #g #H destruct
  55   #HN #HP #Y1 #H1 #Y2 #H2
  56   [ elim (lexs_inv_push1 … H1) -H1 #L1 #V1 #HL1 #HV1 #H destruct
  57     elim (lexs_inv_push1 … H2) -H2 #L2 #V2 #HL2 #HV2 #H destruct
  58     elim (HP … 0 … HV1 … HV2 … HL1 … HL2) -HV1 -HV2 /2 width=2 by drops_refl/ #V #HV1 #HV2
  59     elim (IH … HL1 … HL2) -IH -HL1 -HL2 /3 width=5 by drops_drop, lexs_push, ex2_intro/
  60   | elim (lexs_inv_next1 … H1) -H1 #L1 #V1 #HL1 #HV1 #H destruct
  61     elim (lexs_inv_next1 … H2) -H2 #L2 #V2 #HL2 #HV2 #H destruct
  62     elim (HN … 0 … HV1 … HV2 … HL1 … HL2) -HV1 -HV2 /2 width=2 by drops_refl/ #V #HV1 #HV2
  63     elim (IH … HL1 … HL2) -IH -HL1 -HL2 /3 width=5 by drops_drop, lexs_next, ex2_intro/
  64   ]
  65 ]
  66 qed-.
  67
  68 theorem lexs_canc_sn: ∀RN,RP,f. Transitive … (lexs RN RP f) →
  69                                 symmetric … (lexs RN RP f) →
  70                                 left_cancellable … (lexs RN RP f).
  71 /3 width=3 by/ qed-.
  72
  73 theorem lexs_canc_dx: ∀RN,RP,f. Transitive … (lexs RN RP f) →
  74                                 symmetric … (lexs RN RP f) →
  75                                 right_cancellable … (lexs RN RP f).
  76 /3 width=3 by/ qed-.
  77
  78 lemma lexs_meet: ∀RN,RP,L1,L2.
  79                  ∀f1. L1 ⦻*[RN, RP, f1] L2 →
  80                  ∀f2. L1 ⦻*[RN, RP, f2] L2 →
  81                  ∀f. f1 ⋒ f2 ≡ f → L1 ⦻*[RN, RP, f] L2.
  82 #RN #RP #L1 #L2 #f1 #H elim H -f1 -L1 -L2 //
  83 #f1 #I #L1 #L2 #V1 #V2 #_ #HV12 #IH #f2 #H #f #Hf
  84 elim (pn_split f2) * #g2 #H2 destruct
  85 try elim (lexs_inv_push … H) try elim (lexs_inv_next … H) -H
  86 [ elim (sand_inv_npx … Hf) | elim (sand_inv_nnx … Hf)
  87 | elim (sand_inv_ppx … Hf) | elim (sand_inv_pnx … Hf)
  88 ] -Hf /3 width=5 by lexs_next, lexs_push/
  89 qed-.
  90
  91 lemma lexs_join: ∀RN,RP,L1,L2.
  92                  ∀f1. L1 ⦻*[RN, RP, f1] L2 →
  93                  ∀f2. L1 ⦻*[RN, RP, f2] L2 →
  94                  ∀f. f1 ⋓ f2 ≡ f → L1 ⦻*[RN, RP, f] L2.
  95 #RN #RP #L1 #L2 #f1 #H elim H -f1 -L1 -L2 //
  96 #f1 #I #L1 #L2 #V1 #V2 #_ #HV12 #IH #f2 #H #f #Hf
  97 elim (pn_split f2) * #g2 #H2 destruct
  98 try elim (lexs_inv_push … H) try elim (lexs_inv_next … H) -H
  99 [ elim (sor_inv_npx … Hf) | elim (sor_inv_nnx … Hf)
 100 | elim (sor_inv_ppx … Hf) | elim (sor_inv_pnx … Hf)
 101 ] -Hf /3 width=5 by lexs_next, lexs_push/
 102 qed-.