matita/matita/contribs/lambdadelta/basic_2/relocation/lexs_lexs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_sand.ma".
  16 include "ground_2/relocation/rtmap_sor.ma".
  17 include "basic_2/grammar/lenv_weight.ma".
  18 include "basic_2/relocation/lexs.ma".
  19
  20 (* GENERIC ENTRYWISE EXTENSION OF CONTEXT-SENSITIVE REALTIONS FOR TERMS *****)
  21
  22 (* Main properties **********************************************************)
  23
  24 theorem lexs_trans_gen (RN1) (RP1) (RN2) (RP2) (RN) (RP) (f):
  25                        lexs_transitive RN1 RN2 RN RN1 RP1 →
  26                        lexs_transitive RP1 RP2 RP RN1 RP1 →
  27                        ∀L1,L0. L1 ⦻*[RN1, RP1, f] L0 →
  28                        ∀L2. L0 ⦻*[RN2, RP2, f] L2 →
  29                        L1 ⦻*[RN, RP, f] L2.
  30 #RN1 #RP1 #RN2 #RP2 #RN #RP #f #HN #HP #L1 #L0 #H elim H -f -L1 -L0
  31 [ #f #L2 #H >(lexs_inv_atom1 … H) -L2 //
  32 | #f #I #K1 #K #V1 #V #HK1 #HV1 #IH #L2 #H elim (lexs_inv_next1 … H) -H
  33   #K2 #V2 #HK2 #HV2 #H destruct /4 width=6 by lexs_next/
  34 | #f #I #K1 #K #V1 #V #HK1 #HV1 #IH #L2 #H elim (lexs_inv_push1 … H) -H
  35   #K2 #V2 #HK2 #HV2 #H destruct /4 width=6 by lexs_push/
  36 ]
  37 qed-.
  38
  39 (* Basic_2A1: includes: lpx_sn_trans *)
  40 theorem lexs_trans (RN) (RP) (f): lexs_transitive RN RN RN RN RP →
  41                                   lexs_transitive RP RP RP RN RP →
  42                                   Transitive … (lexs RN RP f).
  43 /2 width=9 by lexs_trans_gen/ qed-.
  44
  45 (* Basic_2A1: includes: lpx_sn_conf *)
  46 theorem lexs_conf: ∀RN1,RP1,RN2,RP2.
  47                    lexs_confluent RN1 RN2 RN1 RP1 RN2 RP2 →
  48                    lexs_confluent RP1 RP2 RN1 RP1 RN2 RP2 →
  49                    ∀f. confluent2 … (lexs RN1 RP1 f) (lexs RN2 RP2 f).
  50 #RN1 #RP1 #RN2 #RP2 #HRN #HRP #f #L0 generalize in match f; -f
  51 @(f_ind … lw … L0) -L0 #x #IH *
  52 [ #_ #f #X1 #H1 #X2 #H2 -x
  53   >(lexs_inv_atom1 … H1) -X1
  54   >(lexs_inv_atom1 … H2) -X2 /2 width=3 by lexs_atom, ex2_intro/
  55 | #L0 #I #V0 #Hx #f elim (pn_split f) *
  56   #g #H #X1 #H1 #X2 #H2 destruct
  57   [ elim (lexs_inv_push1 … H1) -H1 #L1 #V1 #HL01 #HV01 #H destruct
  58     elim (lexs_inv_push1 … H2) -H2 #L2 #V2 #HL02 #HV02 #H destruct
  59     elim (IH … HL01 … HL02) -IH // #L #HL1 #HL2
  60     elim (HRP … HV01 … HV02 … HL01 … HL02) -L0 -V0 /3 width=5 by lexs_push, ex2_intro/
  61   | elim (lexs_inv_next1 … H1) -H1 #L1 #V1 #HL01 #HV01 #H destruct
  62     elim (lexs_inv_next1 … H2) -H2 #L2 #V2 #HL02 #HV02 #H destruct
  63     elim (IH … HL01 … HL02) -IH // #L #HL1 #HL2
  64     elim (HRN … HV01 … HV02 … HL01 … HL02) -L0 -V0 /3 width=5 by lexs_next, ex2_intro/
  65   ]
  66 ]
  67 qed-.
  68
  69 theorem lexs_canc_sn: ∀RN,RP,f. Transitive … (lexs RN RP f) →
  70                                 symmetric … (lexs RN RP f) →
  71                                 left_cancellable … (lexs RN RP f).
  72 /3 width=3 by/ qed-.
  73
  74 theorem lexs_canc_dx: ∀RN,RP,f. Transitive … (lexs RN RP f) →
  75                                 symmetric … (lexs RN RP f) →
  76                                 right_cancellable … (lexs RN RP f).
  77 /3 width=3 by/ qed-.
  78
  79 lemma lexs_meet: ∀RN,RP,L1,L2.
  80                  ∀f1. L1 ⦻*[RN, RP, f1] L2 →
  81                  ∀f2. L1 ⦻*[RN, RP, f2] L2 →
  82                  ∀f. f1 ⋒ f2 ≡ f → L1 ⦻*[RN, RP, f] L2.
  83 #RN #RP #L1 #L2 #f1 #H elim H -f1 -L1 -L2 //
  84 #f1 #I #L1 #L2 #V1 #V2 #_ #HV12 #IH #f2 #H #f #Hf
  85 elim (pn_split f2) * #g2 #H2 destruct
  86 try elim (lexs_inv_push … H) try elim (lexs_inv_next … H) -H
  87 [ elim (sand_inv_npx … Hf) | elim (sand_inv_nnx … Hf)
  88 | elim (sand_inv_ppx … Hf) | elim (sand_inv_pnx … Hf)
  89 ] -Hf /3 width=5 by lexs_next, lexs_push/
  90 qed-.
  91
  92 lemma lexs_join: ∀RN,RP,L1,L2.
  93                  ∀f1. L1 ⦻*[RN, RP, f1] L2 →
  94                  ∀f2. L1 ⦻*[RN, RP, f2] L2 →
  95                  ∀f. f1 ⋓ f2 ≡ f → L1 ⦻*[RN, RP, f] L2.
  96 #RN #RP #L1 #L2 #f1 #H elim H -f1 -L1 -L2 //
  97 #f1 #I #L1 #L2 #V1 #V2 #_ #HV12 #IH #f2 #H #f #Hf
  98 elim (pn_split f2) * #g2 #H2 destruct
  99 try elim (lexs_inv_push … H) try elim (lexs_inv_next … H) -H
 100 [ elim (sor_inv_npx … Hf) | elim (sor_inv_nnx … Hf)
 101 | elim (sor_inv_ppx … Hf) | elim (sor_inv_pnx … Hf)
 102 ] -Hf /3 width=5 by lexs_next, lexs_push/
 103 qed-.