matita/matita/contribs/lambdadelta/basic_2/relocation/lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/term_weight.ma".
  16 include "basic_2/grammar/term_simple.ma".
  17
  18 (* BASIC TERM RELOCATION ****************************************************)
  19
  20 (* Basic_1: includes:
  21             lift_sort lift_lref_lt lift_lref_ge lift_bind lift_flat
  22 *)
  23 inductive lift: nat → nat → relation term ≝
  24 | lift_sort   : ∀k,d,e. lift d e (⋆k) (⋆k)
  25 | lift_lref_lt: ∀i,d,e. i < d → lift d e (#i) (#i)
  26 | lift_lref_ge: ∀i,d,e. d ≤ i → lift d e (#i) (#(i + e))
  27 | lift_gref   : ∀p,d,e. lift d e (§p) (§p)
  28 | lift_bind   : ∀a,I,V1,V2,T1,T2,d,e.
  29                 lift d e V1 V2 → lift (d + 1) e T1 T2 →
  30                 lift d e (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  31 | lift_flat   : ∀I,V1,V2,T1,T2,d,e.
  32                 lift d e V1 V2 → lift d e T1 T2 →
  33                 lift d e (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  34 .
  35
  36 interpretation "relocation" 'RLift d e T1 T2 = (lift d e T1 T2).
  37
  38 (* Basic inversion lemmas ***************************************************)
  39
  40 fact lift_inv_O2_aux: ∀d,e,T1,T2. ⇧[d, e] T1 ≡ T2 → e = 0 → T1 = T2.
  41 #d #e #T1 #T2 #H elim H -d -e -T1 -T2 // /3 width=1/
  42 qed-.
  43
  44 lemma lift_inv_O2: ∀d,T1,T2. ⇧[d, 0] T1 ≡ T2 → T1 = T2.
  45 /2 width=4 by lift_inv_O2_aux/ qed-.
  46
  47 fact lift_inv_sort1_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀k. T1 = ⋆k → T2 = ⋆k.
  48 #d #e #T1 #T2 * -d -e -T1 -T2 //
  49 [ #i #d #e #_ #k #H destruct
  50 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  51 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  52 ]
  53 qed-.
  54
  55 lemma lift_inv_sort1: ∀d,e,T2,k. ⇧[d,e] ⋆k ≡ T2 → T2 = ⋆k.
  56 /2 width=5 by lift_inv_sort1_aux/ qed-.
  57
  58 fact lift_inv_lref1_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀i. T1 = #i →
  59                          (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
  60 #d #e #T1 #T2 * -d -e -T1 -T2
  61 [ #k #d #e #i #H destruct
  62 | #j #d #e #Hj #i #Hi destruct /3 width=1/
  63 | #j #d #e #Hj #i #Hi destruct /3 width=1/
  64 | #p #d #e #i #H destruct
  65 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
  66 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
  67 ]
  68 qed-.
  69
  70 lemma lift_inv_lref1: ∀d,e,T2,i. ⇧[d,e] #i ≡ T2 →
  71                       (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
  72 /2 width=3 by lift_inv_lref1_aux/ qed-.
  73
  74 lemma lift_inv_lref1_lt: ∀d,e,T2,i. ⇧[d,e] #i ≡ T2 → i < d → T2 = #i.
  75 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  76 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
  77 elim (lt_refl_false … Hdd)
  78 qed-.
  79
  80 lemma lift_inv_lref1_ge: ∀d,e,T2,i. ⇧[d,e] #i ≡ T2 → d ≤ i → T2 = #(i + e).
  81 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  82 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
  83 elim (lt_refl_false … Hdd)
  84 qed-.
  85
  86 fact lift_inv_gref1_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀p. T1 = §p → T2 = §p.
  87 #d #e #T1 #T2 * -d -e -T1 -T2 //
  88 [ #i #d #e #_ #k #H destruct
  89 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  90 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  91 ]
  92 qed-.
  93
  94 lemma lift_inv_gref1: ∀d,e,T2,p. ⇧[d,e] §p ≡ T2 → T2 = §p.
  95 /2 width=5 by lift_inv_gref1_aux/ qed-.
  96
  97 fact lift_inv_bind1_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 →
  98                          ∀a,I,V1,U1. T1 = ⓑ{a,I} V1.U1 →
  99                          ∃∃V2,U2. ⇧[d,e] V1 ≡ V2 & ⇧[d+1,e] U1 ≡ U2 &
 100                                   T2 = ⓑ{a,I} V2. U2.
 101 #d #e #T1 #T2 * -d -e -T1 -T2
 102 [ #k #d #e #a #I #V1 #U1 #H destruct
 103 | #i #d #e #_ #a #I #V1 #U1 #H destruct
 104 | #i #d #e #_ #a #I #V1 #U1 #H destruct
 105 | #p #d #e #a #I #V1 #U1 #H destruct
 106 | #b #J #W1 #W2 #T1 #T2 #d #e #HW #HT #a #I #V1 #U1 #H destruct /2 width=5/
 107 | #J #W1 #W2 #T1 #T2 #d #e #_ #HT #a #I #V1 #U1 #H destruct
 108 ]
 109 qed-.
 110
 111 lemma lift_inv_bind1: ∀d,e,T2,a,I,V1,U1. ⇧[d,e] ⓑ{a,I} V1. U1 ≡ T2 →
 112                       ∃∃V2,U2. ⇧[d,e] V1 ≡ V2 & ⇧[d+1,e] U1 ≡ U2 &
 113                                T2 = ⓑ{a,I} V2. U2.
 114 /2 width=3 by lift_inv_bind1_aux/ qed-.
 115
 116 fact lift_inv_flat1_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 →
 117                          ∀I,V1,U1. T1 = ⓕ{I} V1.U1 →
 118                          ∃∃V2,U2. ⇧[d,e] V1 ≡ V2 & ⇧[d,e] U1 ≡ U2 &
 119                                   T2 = ⓕ{I} V2. U2.
 120 #d #e #T1 #T2 * -d -e -T1 -T2
 121 [ #k #d #e #I #V1 #U1 #H destruct
 122 | #i #d #e #_ #I #V1 #U1 #H destruct
 123 | #i #d #e #_ #I #V1 #U1 #H destruct
 124 | #p #d #e #I #V1 #U1 #H destruct
 125 | #a #J #W1 #W2 #T1 #T2 #d #e #_ #_ #I #V1 #U1 #H destruct
 126 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 127 ]
 128 qed-.
 129
 130 lemma lift_inv_flat1: ∀d,e,T2,I,V1,U1. ⇧[d,e] ⓕ{I} V1. U1 ≡ T2 →
 131                       ∃∃V2,U2. ⇧[d,e] V1 ≡ V2 & ⇧[d,e] U1 ≡ U2 &
 132                                T2 = ⓕ{I} V2. U2.
 133 /2 width=3 by lift_inv_flat1_aux/ qed-.
 134
 135 fact lift_inv_sort2_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
 136 #d #e #T1 #T2 * -d -e -T1 -T2 //
 137 [ #i #d #e #_ #k #H destruct
 138 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 139 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 140 ]
 141 qed-.
 142
 143 (* Basic_1: was: lift_gen_sort *)
 144 lemma lift_inv_sort2: ∀d,e,T1,k. ⇧[d,e] T1 ≡ ⋆k → T1 = ⋆k.
 145 /2 width=5 by lift_inv_sort2_aux/ qed-.
 146
 147 fact lift_inv_lref2_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀i. T2 = #i →
 148                          (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 149 #d #e #T1 #T2 * -d -e -T1 -T2
 150 [ #k #d #e #i #H destruct
 151 | #j #d #e #Hj #i #Hi destruct /3 width=1/
 152 | #j #d #e #Hj #i #Hi destruct <minus_plus_m_m /4 width=1/
 153 | #p #d #e #i #H destruct
 154 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 155 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 156 ]
 157 qed-.
 158
 159 (* Basic_1: was: lift_gen_lref *)
 160 lemma lift_inv_lref2: ∀d,e,T1,i. ⇧[d,e] T1 ≡ #i →
 161                       (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 162 /2 width=3 by lift_inv_lref2_aux/ qed-.
 163
 164 (* Basic_1: was: lift_gen_lref_lt *)
 165 lemma lift_inv_lref2_lt: ∀d,e,T1,i. ⇧[d,e] T1 ≡ #i → i < d → T1 = #i.
 166 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 167 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
 168 elim (lt_inv_plus_l … Hdd) -Hdd #Hdd
 169 elim (lt_refl_false … Hdd)
 170 qed-.
 171
 172 (* Basic_1: was: lift_gen_lref_false *)
 173 lemma lift_inv_lref2_be: ∀d,e,T1,i. ⇧[d,e] T1 ≡ #i →
 174                          d ≤ i → i < d + e → ⊥.
 175 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H *
 176 [ #H1 #_ #H2 #_ | #H2 #_ #_ #H1 ]
 177 lapply (le_to_lt_to_lt … H2 H1) -H2 -H1 #H
 178 elim (lt_refl_false … H)
 179 qed-.
 180
 181 (* Basic_1: was: lift_gen_lref_ge *)
 182 lemma lift_inv_lref2_ge: ∀d,e,T1,i. ⇧[d,e] T1 ≡ #i → d + e ≤ i → T1 = #(i - e).
 183 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 184 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
 185 elim (lt_inv_plus_l … Hdd) -Hdd #Hdd
 186 elim (lt_refl_false … Hdd)
 187 qed-.
 188
 189 fact lift_inv_gref2_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀p. T2 = §p → T1 = §p.
 190 #d #e #T1 #T2 * -d -e -T1 -T2 //
 191 [ #i #d #e #_ #k #H destruct
 192 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 193 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 194 ]
 195 qed-.
 196
 197 lemma lift_inv_gref2: ∀d,e,T1,p. ⇧[d,e] T1 ≡ §p → T1 = §p.
 198 /2 width=5 by lift_inv_gref2_aux/ qed-.
 199
 200 fact lift_inv_bind2_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 →
 201                          ∀a,I,V2,U2. T2 = ⓑ{a,I} V2.U2 →
 202                          ∃∃V1,U1. ⇧[d,e] V1 ≡ V2 & ⇧[d+1,e] U1 ≡ U2 &
 203                                   T1 = ⓑ{a,I} V1. U1.
 204 #d #e #T1 #T2 * -d -e -T1 -T2
 205 [ #k #d #e #a #I #V2 #U2 #H destruct
 206 | #i #d #e #_ #a #I #V2 #U2 #H destruct
 207 | #i #d #e #_ #a #I #V2 #U2 #H destruct
 208 | #p #d #e #a #I #V2 #U2 #H destruct
 209 | #b #J #W1 #W2 #T1 #T2 #d #e #HW #HT #a #I #V2 #U2 #H destruct /2 width=5/
 210 | #J #W1 #W2 #T1 #T2 #d #e #_ #_ #a #I #V2 #U2 #H destruct
 211 ]
 212 qed-.
 213
 214 (* Basic_1: was: lift_gen_bind *)
 215 lemma lift_inv_bind2: ∀d,e,T1,a,I,V2,U2. ⇧[d,e] T1 ≡ ⓑ{a,I} V2. U2 →
 216                       ∃∃V1,U1. ⇧[d,e] V1 ≡ V2 & ⇧[d+1,e] U1 ≡ U2 &
 217                                T1 = ⓑ{a,I} V1. U1.
 218 /2 width=3 by lift_inv_bind2_aux/ qed-.
 219
 220 fact lift_inv_flat2_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 →
 221                          ∀I,V2,U2. T2 = ⓕ{I} V2.U2 →
 222                          ∃∃V1,U1. ⇧[d,e] V1 ≡ V2 & ⇧[d,e] U1 ≡ U2 &
 223                                   T1 = ⓕ{I} V1. U1.
 224 #d #e #T1 #T2 * -d -e -T1 -T2
 225 [ #k #d #e #I #V2 #U2 #H destruct
 226 | #i #d #e #_ #I #V2 #U2 #H destruct
 227 | #i #d #e #_ #I #V2 #U2 #H destruct
 228 | #p #d #e #I #V2 #U2 #H destruct
 229 | #a #J #W1 #W2 #T1 #T2 #d #e #_ #_ #I #V2 #U2 #H destruct
 230 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width=5/
 231 ]
 232 qed-.
 233
 234 (* Basic_1: was: lift_gen_flat *)
 235 lemma lift_inv_flat2: ∀d,e,T1,I,V2,U2. ⇧[d,e] T1 ≡  ⓕ{I} V2. U2 →
 236                       ∃∃V1,U1. ⇧[d,e] V1 ≡ V2 & ⇧[d,e] U1 ≡ U2 &
 237                                T1 = ⓕ{I} V1. U1.
 238 /2 width=3 by lift_inv_flat2_aux/ qed-.
 239
 240 lemma lift_inv_pair_xy_x: ∀d,e,I,V,T. ⇧[d, e] ②{I} V. T ≡ V → ⊥.
 241 #d #e #J #V elim V -V
 242 [ * #i #T #H
 243   [ lapply (lift_inv_sort2 … H) -H #H destruct
 244   | elim (lift_inv_lref2 … H) -H * #_ #H destruct
 245   | lapply (lift_inv_gref2 … H) -H #H destruct
 246   ]
 247 | * [ #a ] #I #W2 #U2 #IHW2 #_ #T #H
 248   [ elim (lift_inv_bind2 … H) -H #W1 #U1 #HW12 #_ #H destruct /2 width=2/
 249   | elim (lift_inv_flat2 … H) -H #W1 #U1 #HW12 #_ #H destruct /2 width=2/
 250   ]
 251 ]
 252 qed-.
 253
 254 (* Basic_1: was: thead_x_lift_y_y *)
 255 lemma lift_inv_pair_xy_y: ∀I,T,V,d,e. ⇧[d, e] ②{I} V. T ≡ T → ⊥.
 256 #J #T elim T -T
 257 [ * #i #V #d #e #H
 258   [ lapply (lift_inv_sort2 … H) -H #H destruct
 259   | elim (lift_inv_lref2 … H) -H * #_ #H destruct
 260   | lapply (lift_inv_gref2 … H) -H #H destruct
 261   ]
 262 | * [ #a ] #I #W2 #U2 #_ #IHU2 #V #d #e #H
 263   [ elim (lift_inv_bind2 … H) -H #W1 #U1 #_ #HU12 #H destruct /2 width=4/
 264   | elim (lift_inv_flat2 … H) -H #W1 #U1 #_ #HU12 #H destruct /2 width=4/
 265   ]
 266 ]
 267 qed-.
 268
 269 (* Basic forward lemmas *****************************************************)
 270
 271 lemma lift_fwd_pair1: ∀I,T2,V1,U1,d,e. ⇧[d,e] ②{I}V1.U1 ≡ T2 →
 272                       ∃∃V2,U2. ⇧[d,e] V1 ≡ V2 & T2 = ②{I}V2.U2.
 273 * [ #a ] #I #T2 #V1 #U1 #d #e #H
 274 [ elim (lift_inv_bind1 … H) -H /2 width=4/
 275 |  elim (lift_inv_flat1 … H) -H /2 width=4/
 276 ]
 277 qed-.
 278
 279 lemma lift_fwd_pair2: ∀I,T1,V2,U2,d,e. ⇧[d,e] T1 ≡ ②{I}V2.U2 →
 280                       ∃∃V1,U1. ⇧[d,e] V1 ≡ V2 & T1 = ②{I}V1.U1.
 281 * [ #a ] #I #T1 #V2 #U2 #d #e #H
 282 [ elim (lift_inv_bind2 … H) -H /2 width=4/
 283 |  elim (lift_inv_flat2 … H) -H /2 width=4/
 284 ]
 285 qed-.
 286
 287 lemma lift_fwd_tw: ∀d,e,T1,T2. ⇧[d, e] T1 ≡ T2 → ♯{T1} = ♯{T2}.
 288 #d #e #T1 #T2 #H elim H -d -e -T1 -T2 normalize //
 289 qed-.
 290
 291 lemma lift_simple_dx: ∀d,e,T1,T2. ⇧[d, e] T1 ≡ T2 → 𝐒⦃T1⦄ → 𝐒⦃T2⦄.
 292 #d #e #T1 #T2 #H elim H -d -e -T1 -T2 //
 293 #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #H
 294 elim (simple_inv_bind … H)
 295 qed-.
 296
 297 lemma lift_simple_sn: ∀d,e,T1,T2. ⇧[d, e] T1 ≡ T2 → 𝐒⦃T2⦄ → 𝐒⦃T1⦄.
 298 #d #e #T1 #T2 #H elim H -d -e -T1 -T2 //
 299 #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #H
 300 elim (simple_inv_bind … H)
 301 qed-.
 302
 303 (* Basic properties *********************************************************)
 304
 305 (* Basic_1: was: lift_lref_gt *)
 306 lemma lift_lref_ge_minus: ∀d,e,i. d + e ≤ i → ⇧[d, e] #(i - e) ≡ #i.
 307 #d #e #i #H >(plus_minus_m_m i e) in ⊢ (? ? ? ? %); /2 width=2/ /3 width=2/
 308 qed.
 309
 310 lemma lift_lref_ge_minus_eq: ∀d,e,i,j. d + e ≤ i → j = i - e → ⇧[d, e] #j ≡ #i.
 311 /2 width=1/ qed-.
 312
 313 (* Basic_1: was: lift_r *)
 314 lemma lift_refl: ∀T,d. ⇧[d, 0] T ≡ T.
 315 #T elim T -T
 316 [ * #i // #d elim (lt_or_ge i d) /2 width=1/
 317 | * /2 width=1/
 318 ]
 319 qed.
 320
 321 lemma lift_total: ∀T1,d,e. ∃T2. ⇧[d,e] T1 ≡ T2.
 322 #T1 elim T1 -T1
 323 [ * #i /2 width=2/ #d #e elim (lt_or_ge i d) /3 width=2/
 324 | * [ #a ] #I #V1 #T1 #IHV1 #IHT1 #d #e
 325   elim (IHV1 d e) -IHV1 #V2 #HV12
 326   [ elim (IHT1 (d+1) e) -IHT1 /3 width=2/
 327   | elim (IHT1 d e) -IHT1 /3 width=2/
 328   ]
 329 ]
 330 qed.
 331
 332 (* Basic_1: was: lift_free (right to left) *)
 333 lemma lift_split: ∀d1,e2,T1,T2. ⇧[d1, e2] T1 ≡ T2 →
 334                   ∀d2,e1. d1 ≤ d2 → d2 ≤ d1 + e1 → e1 ≤ e2 →
 335                   ∃∃T. ⇧[d1, e1] T1 ≡ T & ⇧[d2, e2 - e1] T ≡ T2.
 336 #d1 #e2 #T1 #T2 #H elim H -d1 -e2 -T1 -T2
 337 [ /3 width=3/
 338 | #i #d1 #e2 #Hid1 #d2 #e1 #Hd12 #_ #_
 339   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2 /4 width=3/
 340 | #i #d1 #e2 #Hid1 #d2 #e1 #_ #Hd21 #He12
 341   lapply (transitive_le … (i+e1) Hd21 ?) /2 width=1/ -Hd21 #Hd21
 342   >(plus_minus_m_m e2 e1 ?) // /3 width=3/
 343 | /3 width=3/
 344 | #a #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
 345   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
 346   elim (IHT (d2+1) … ? ? He12) /2 width=1/ /3 width=5/
 347 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
 348   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
 349   elim (IHT d2 … ? ? He12) // /3 width=5/
 350 ]
 351 qed.
 352
 353 (* Basic_1: was only: dnf_dec2 dnf_dec *)
 354 lemma is_lift_dec: ∀T2,d,e. Decidable (∃T1. ⇧[d,e] T1 ≡ T2).
 355 #T1 elim T1 -T1
 356 [ * [1,3: /3 width=2/ ] #i #d #e
 357   elim (lt_dec i d) #Hid
 358   [ /4 width=2/
 359   | lapply (false_lt_to_le … Hid) -Hid #Hid
 360     elim (lt_dec i (d + e)) #Hide
 361     [ @or_intror * #T1 #H
 362       elim (lift_inv_lref2_be … H Hid Hide)
 363     | lapply (false_lt_to_le … Hide) -Hide /4 width=2/
 364     ]
 365   ]
 366 | * [ #a ] #I #V2 #T2 #IHV2 #IHT2 #d #e
 367   [ elim (IHV2 d e) -IHV2
 368     [ * #V1 #HV12 elim (IHT2 (d+1) e) -IHT2
 369       [ * #T1 #HT12 @or_introl /3 width=2/
 370       | -V1 #HT2 @or_intror * #X #H
 371         elim (lift_inv_bind2 … H) -H /3 width=2/
 372       ]
 373     | -IHT2 #HV2 @or_intror * #X #H
 374       elim (lift_inv_bind2 … H) -H /3 width=2/
 375     ]
 376   | elim (IHV2 d e) -IHV2
 377     [ * #V1 #HV12 elim (IHT2 d e) -IHT2
 378       [ * #T1 #HT12 /4 width=2/
 379       | -V1 #HT2 @or_intror * #X #H
 380         elim (lift_inv_flat2 … H) -H /3 width=2/
 381       ]
 382     | -IHT2 #HV2 @or_intror * #X #H
 383       elim (lift_inv_flat2 … H) -H /3 width=2/
 384     ]
 385   ]
 386 ]
 387 qed.
 388
 389 (* Basic_1: removed theorems 7:
 390             lift_head lift_gen_head
 391             lift_weight_map lift_weight lift_weight_add lift_weight_add_O
 392             lift_tlt_dx
 393 *)