matita/matita/contribs/lambdadelta/basic_2/relocation/lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/rlift_4.ma".
  16 include "basic_2/grammar/term_weight.ma".
  17 include "basic_2/grammar/term_simple.ma".
  18
  19 (* BASIC TERM RELOCATION ****************************************************)
  20
  21 (* Basic_1: includes:
  22             lift_sort lift_lref_lt lift_lref_ge lift_bind lift_flat
  23 *)
  24 inductive lift: relation4 nat nat term term ≝
  25 | lift_sort   : ∀k,d,e. lift d e (⋆k) (⋆k)
  26 | lift_lref_lt: ∀i,d,e. i < d → lift d e (#i) (#i)
  27 | lift_lref_ge: ∀i,d,e. d ≤ i → lift d e (#i) (#(i + e))
  28 | lift_gref   : ∀p,d,e. lift d e (§p) (§p)
  29 | lift_bind   : ∀a,I,V1,V2,T1,T2,d,e.
  30                 lift d e V1 V2 → lift (d + 1) e T1 T2 →
  31                 lift d e (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  32 | lift_flat   : ∀I,V1,V2,T1,T2,d,e.
  33                 lift d e V1 V2 → lift d e T1 T2 →
  34                 lift d e (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  35 .
  36
  37 interpretation "relocation" 'RLift d e T1 T2 = (lift d e T1 T2).
  38
  39 (* Basic inversion lemmas ***************************************************)
  40
  41 fact lift_inv_O2_aux: ∀d,e,T1,T2. ⇧[d, e] T1 ≡ T2 → e = 0 → T1 = T2.
  42 #d #e #T1 #T2 #H elim H -d -e -T1 -T2 // /3 width=1/
  43 qed-.
  44
  45 lemma lift_inv_O2: ∀d,T1,T2. ⇧[d, 0] T1 ≡ T2 → T1 = T2.
  46 /2 width=4 by lift_inv_O2_aux/ qed-.
  47
  48 fact lift_inv_sort1_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀k. T1 = ⋆k → T2 = ⋆k.
  49 #d #e #T1 #T2 * -d -e -T1 -T2 //
  50 [ #i #d #e #_ #k #H destruct
  51 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  52 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  53 ]
  54 qed-.
  55
  56 lemma lift_inv_sort1: ∀d,e,T2,k. ⇧[d,e] ⋆k ≡ T2 → T2 = ⋆k.
  57 /2 width=5 by lift_inv_sort1_aux/ qed-.
  58
  59 fact lift_inv_lref1_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀i. T1 = #i →
  60                          (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
  61 #d #e #T1 #T2 * -d -e -T1 -T2
  62 [ #k #d #e #i #H destruct
  63 | #j #d #e #Hj #i #Hi destruct /3 width=1/
  64 | #j #d #e #Hj #i #Hi destruct /3 width=1/
  65 | #p #d #e #i #H destruct
  66 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
  67 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
  68 ]
  69 qed-.
  70
  71 lemma lift_inv_lref1: ∀d,e,T2,i. ⇧[d,e] #i ≡ T2 →
  72                       (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
  73 /2 width=3 by lift_inv_lref1_aux/ qed-.
  74
  75 lemma lift_inv_lref1_lt: ∀d,e,T2,i. ⇧[d,e] #i ≡ T2 → i < d → T2 = #i.
  76 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  77 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
  78 elim (lt_refl_false … Hdd)
  79 qed-.
  80
  81 lemma lift_inv_lref1_ge: ∀d,e,T2,i. ⇧[d,e] #i ≡ T2 → d ≤ i → T2 = #(i + e).
  82 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  83 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
  84 elim (lt_refl_false … Hdd)
  85 qed-.
  86
  87 fact lift_inv_gref1_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀p. T1 = §p → T2 = §p.
  88 #d #e #T1 #T2 * -d -e -T1 -T2 //
  89 [ #i #d #e #_ #k #H destruct
  90 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  91 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  92 ]
  93 qed-.
  94
  95 lemma lift_inv_gref1: ∀d,e,T2,p. ⇧[d,e] §p ≡ T2 → T2 = §p.
  96 /2 width=5 by lift_inv_gref1_aux/ qed-.
  97
  98 fact lift_inv_bind1_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 →
  99                          ∀a,I,V1,U1. T1 = ⓑ{a,I} V1.U1 →
 100                          ∃∃V2,U2. ⇧[d,e] V1 ≡ V2 & ⇧[d+1,e] U1 ≡ U2 &
 101                                   T2 = ⓑ{a,I} V2. U2.
 102 #d #e #T1 #T2 * -d -e -T1 -T2
 103 [ #k #d #e #a #I #V1 #U1 #H destruct
 104 | #i #d #e #_ #a #I #V1 #U1 #H destruct
 105 | #i #d #e #_ #a #I #V1 #U1 #H destruct
 106 | #p #d #e #a #I #V1 #U1 #H destruct
 107 | #b #J #W1 #W2 #T1 #T2 #d #e #HW #HT #a #I #V1 #U1 #H destruct /2 width=5/
 108 | #J #W1 #W2 #T1 #T2 #d #e #_ #HT #a #I #V1 #U1 #H destruct
 109 ]
 110 qed-.
 111
 112 lemma lift_inv_bind1: ∀d,e,T2,a,I,V1,U1. ⇧[d,e] ⓑ{a,I} V1. U1 ≡ T2 →
 113                       ∃∃V2,U2. ⇧[d,e] V1 ≡ V2 & ⇧[d+1,e] U1 ≡ U2 &
 114                                T2 = ⓑ{a,I} V2. U2.
 115 /2 width=3 by lift_inv_bind1_aux/ qed-.
 116
 117 fact lift_inv_flat1_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 →
 118                          ∀I,V1,U1. T1 = ⓕ{I} V1.U1 →
 119                          ∃∃V2,U2. ⇧[d,e] V1 ≡ V2 & ⇧[d,e] U1 ≡ U2 &
 120                                   T2 = ⓕ{I} V2. U2.
 121 #d #e #T1 #T2 * -d -e -T1 -T2
 122 [ #k #d #e #I #V1 #U1 #H destruct
 123 | #i #d #e #_ #I #V1 #U1 #H destruct
 124 | #i #d #e #_ #I #V1 #U1 #H destruct
 125 | #p #d #e #I #V1 #U1 #H destruct
 126 | #a #J #W1 #W2 #T1 #T2 #d #e #_ #_ #I #V1 #U1 #H destruct
 127 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 128 ]
 129 qed-.
 130
 131 lemma lift_inv_flat1: ∀d,e,T2,I,V1,U1. ⇧[d,e] ⓕ{I} V1. U1 ≡ T2 →
 132                       ∃∃V2,U2. ⇧[d,e] V1 ≡ V2 & ⇧[d,e] U1 ≡ U2 &
 133                                T2 = ⓕ{I} V2. U2.
 134 /2 width=3 by lift_inv_flat1_aux/ qed-.
 135
 136 fact lift_inv_sort2_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
 137 #d #e #T1 #T2 * -d -e -T1 -T2 //
 138 [ #i #d #e #_ #k #H destruct
 139 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 140 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 141 ]
 142 qed-.
 143
 144 (* Basic_1: was: lift_gen_sort *)
 145 lemma lift_inv_sort2: ∀d,e,T1,k. ⇧[d,e] T1 ≡ ⋆k → T1 = ⋆k.
 146 /2 width=5 by lift_inv_sort2_aux/ qed-.
 147
 148 fact lift_inv_lref2_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀i. T2 = #i →
 149                          (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 150 #d #e #T1 #T2 * -d -e -T1 -T2
 151 [ #k #d #e #i #H destruct
 152 | #j #d #e #Hj #i #Hi destruct /3 width=1/
 153 | #j #d #e #Hj #i #Hi destruct <minus_plus_m_m /4 width=1/
 154 | #p #d #e #i #H destruct
 155 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 156 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 157 ]
 158 qed-.
 159
 160 (* Basic_1: was: lift_gen_lref *)
 161 lemma lift_inv_lref2: ∀d,e,T1,i. ⇧[d,e] T1 ≡ #i →
 162                       (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 163 /2 width=3 by lift_inv_lref2_aux/ qed-.
 164
 165 (* Basic_1: was: lift_gen_lref_lt *)
 166 lemma lift_inv_lref2_lt: ∀d,e,T1,i. ⇧[d,e] T1 ≡ #i → i < d → T1 = #i.
 167 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 168 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
 169 elim (lt_inv_plus_l … Hdd) -Hdd #Hdd
 170 elim (lt_refl_false … Hdd)
 171 qed-.
 172
 173 (* Basic_1: was: lift_gen_lref_false *)
 174 lemma lift_inv_lref2_be: ∀d,e,T1,i. ⇧[d,e] T1 ≡ #i →
 175                          d ≤ i → i < d + e → ⊥.
 176 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H *
 177 [ #H1 #_ #H2 #_ | #H2 #_ #_ #H1 ]
 178 lapply (le_to_lt_to_lt … H2 H1) -H2 -H1 #H
 179 elim (lt_refl_false … H)
 180 qed-.
 181
 182 (* Basic_1: was: lift_gen_lref_ge *)
 183 lemma lift_inv_lref2_ge: ∀d,e,T1,i. ⇧[d,e] T1 ≡ #i → d + e ≤ i → T1 = #(i - e).
 184 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 185 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
 186 elim (lt_inv_plus_l … Hdd) -Hdd #Hdd
 187 elim (lt_refl_false … Hdd)
 188 qed-.
 189
 190 fact lift_inv_gref2_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 → ∀p. T2 = §p → T1 = §p.
 191 #d #e #T1 #T2 * -d -e -T1 -T2 //
 192 [ #i #d #e #_ #k #H destruct
 193 | #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 194 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 195 ]
 196 qed-.
 197
 198 lemma lift_inv_gref2: ∀d,e,T1,p. ⇧[d,e] T1 ≡ §p → T1 = §p.
 199 /2 width=5 by lift_inv_gref2_aux/ qed-.
 200
 201 fact lift_inv_bind2_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 →
 202                          ∀a,I,V2,U2. T2 = ⓑ{a,I} V2.U2 →
 203                          ∃∃V1,U1. ⇧[d,e] V1 ≡ V2 & ⇧[d+1,e] U1 ≡ U2 &
 204                                   T1 = ⓑ{a,I} V1. U1.
 205 #d #e #T1 #T2 * -d -e -T1 -T2
 206 [ #k #d #e #a #I #V2 #U2 #H destruct
 207 | #i #d #e #_ #a #I #V2 #U2 #H destruct
 208 | #i #d #e #_ #a #I #V2 #U2 #H destruct
 209 | #p #d #e #a #I #V2 #U2 #H destruct
 210 | #b #J #W1 #W2 #T1 #T2 #d #e #HW #HT #a #I #V2 #U2 #H destruct /2 width=5/
 211 | #J #W1 #W2 #T1 #T2 #d #e #_ #_ #a #I #V2 #U2 #H destruct
 212 ]
 213 qed-.
 214
 215 (* Basic_1: was: lift_gen_bind *)
 216 lemma lift_inv_bind2: ∀d,e,T1,a,I,V2,U2. ⇧[d,e] T1 ≡ ⓑ{a,I} V2. U2 →
 217                       ∃∃V1,U1. ⇧[d,e] V1 ≡ V2 & ⇧[d+1,e] U1 ≡ U2 &
 218                                T1 = ⓑ{a,I} V1. U1.
 219 /2 width=3 by lift_inv_bind2_aux/ qed-.
 220
 221 fact lift_inv_flat2_aux: ∀d,e,T1,T2. ⇧[d,e] T1 ≡ T2 →
 222                          ∀I,V2,U2. T2 = ⓕ{I} V2.U2 →
 223                          ∃∃V1,U1. ⇧[d,e] V1 ≡ V2 & ⇧[d,e] U1 ≡ U2 &
 224                                   T1 = ⓕ{I} V1. U1.
 225 #d #e #T1 #T2 * -d -e -T1 -T2
 226 [ #k #d #e #I #V2 #U2 #H destruct
 227 | #i #d #e #_ #I #V2 #U2 #H destruct
 228 | #i #d #e #_ #I #V2 #U2 #H destruct
 229 | #p #d #e #I #V2 #U2 #H destruct
 230 | #a #J #W1 #W2 #T1 #T2 #d #e #_ #_ #I #V2 #U2 #H destruct
 231 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width=5/
 232 ]
 233 qed-.
 234
 235 (* Basic_1: was: lift_gen_flat *)
 236 lemma lift_inv_flat2: ∀d,e,T1,I,V2,U2. ⇧[d,e] T1 ≡  ⓕ{I} V2. U2 →
 237                       ∃∃V1,U1. ⇧[d,e] V1 ≡ V2 & ⇧[d,e] U1 ≡ U2 &
 238                                T1 = ⓕ{I} V1. U1.
 239 /2 width=3 by lift_inv_flat2_aux/ qed-.
 240
 241 lemma lift_inv_pair_xy_x: ∀d,e,I,V,T. ⇧[d, e] ②{I} V. T ≡ V → ⊥.
 242 #d #e #J #V elim V -V
 243 [ * #i #T #H
 244   [ lapply (lift_inv_sort2 … H) -H #H destruct
 245   | elim (lift_inv_lref2 … H) -H * #_ #H destruct
 246   | lapply (lift_inv_gref2 … H) -H #H destruct
 247   ]
 248 | * [ #a ] #I #W2 #U2 #IHW2 #_ #T #H
 249   [ elim (lift_inv_bind2 … H) -H #W1 #U1 #HW12 #_ #H destruct /2 width=2/
 250   | elim (lift_inv_flat2 … H) -H #W1 #U1 #HW12 #_ #H destruct /2 width=2/
 251   ]
 252 ]
 253 qed-.
 254
 255 (* Basic_1: was: thead_x_lift_y_y *)
 256 lemma lift_inv_pair_xy_y: ∀I,T,V,d,e. ⇧[d, e] ②{I} V. T ≡ T → ⊥.
 257 #J #T elim T -T
 258 [ * #i #V #d #e #H
 259   [ lapply (lift_inv_sort2 … H) -H #H destruct
 260   | elim (lift_inv_lref2 … H) -H * #_ #H destruct
 261   | lapply (lift_inv_gref2 … H) -H #H destruct
 262   ]
 263 | * [ #a ] #I #W2 #U2 #_ #IHU2 #V #d #e #H
 264   [ elim (lift_inv_bind2 … H) -H #W1 #U1 #_ #HU12 #H destruct /2 width=4/
 265   | elim (lift_inv_flat2 … H) -H #W1 #U1 #_ #HU12 #H destruct /2 width=4/
 266   ]
 267 ]
 268 qed-.
 269
 270 (* Basic forward lemmas *****************************************************)
 271
 272 lemma lift_fwd_pair1: ∀I,T2,V1,U1,d,e. ⇧[d,e] ②{I}V1.U1 ≡ T2 →
 273                       ∃∃V2,U2. ⇧[d,e] V1 ≡ V2 & T2 = ②{I}V2.U2.
 274 * [ #a ] #I #T2 #V1 #U1 #d #e #H
 275 [ elim (lift_inv_bind1 … H) -H /2 width=4/
 276 |  elim (lift_inv_flat1 … H) -H /2 width=4/
 277 ]
 278 qed-.
 279
 280 lemma lift_fwd_pair2: ∀I,T1,V2,U2,d,e. ⇧[d,e] T1 ≡ ②{I}V2.U2 →
 281                       ∃∃V1,U1. ⇧[d,e] V1 ≡ V2 & T1 = ②{I}V1.U1.
 282 * [ #a ] #I #T1 #V2 #U2 #d #e #H
 283 [ elim (lift_inv_bind2 … H) -H /2 width=4/
 284 |  elim (lift_inv_flat2 … H) -H /2 width=4/
 285 ]
 286 qed-.
 287
 288 lemma lift_fwd_tw: ∀d,e,T1,T2. ⇧[d, e] T1 ≡ T2 → ♯{T1} = ♯{T2}.
 289 #d #e #T1 #T2 #H elim H -d -e -T1 -T2 normalize //
 290 qed-.
 291
 292 lemma lift_simple_dx: ∀d,e,T1,T2. ⇧[d, e] T1 ≡ T2 → 𝐒⦃T1⦄ → 𝐒⦃T2⦄.
 293 #d #e #T1 #T2 #H elim H -d -e -T1 -T2 //
 294 #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #H
 295 elim (simple_inv_bind … H)
 296 qed-.
 297
 298 lemma lift_simple_sn: ∀d,e,T1,T2. ⇧[d, e] T1 ≡ T2 → 𝐒⦃T2⦄ → 𝐒⦃T1⦄.
 299 #d #e #T1 #T2 #H elim H -d -e -T1 -T2 //
 300 #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #H
 301 elim (simple_inv_bind … H)
 302 qed-.
 303
 304 (* Basic properties *********************************************************)
 305
 306 (* Basic_1: was: lift_lref_gt *)
 307 lemma lift_lref_ge_minus: ∀d,e,i. d + e ≤ i → ⇧[d, e] #(i - e) ≡ #i.
 308 #d #e #i #H >(plus_minus_m_m i e) in ⊢ (? ? ? ? %); /2 width=2/ /3 width=2/
 309 qed.
 310
 311 lemma lift_lref_ge_minus_eq: ∀d,e,i,j. d + e ≤ i → j = i - e → ⇧[d, e] #j ≡ #i.
 312 /2 width=1/ qed-.
 313
 314 (* Basic_1: was: lift_r *)
 315 lemma lift_refl: ∀T,d. ⇧[d, 0] T ≡ T.
 316 #T elim T -T
 317 [ * #i // #d elim (lt_or_ge i d) /2 width=1/
 318 | * /2 width=1/
 319 ]
 320 qed.
 321
 322 lemma lift_total: ∀T1,d,e. ∃T2. ⇧[d,e] T1 ≡ T2.
 323 #T1 elim T1 -T1
 324 [ * #i /2 width=2/ #d #e elim (lt_or_ge i d) /3 width=2/
 325 | * [ #a ] #I #V1 #T1 #IHV1 #IHT1 #d #e
 326   elim (IHV1 d e) -IHV1 #V2 #HV12
 327   [ elim (IHT1 (d+1) e) -IHT1 /3 width=2/
 328   | elim (IHT1 d e) -IHT1 /3 width=2/
 329   ]
 330 ]
 331 qed.
 332
 333 (* Basic_1: was: lift_free (right to left) *)
 334 lemma lift_split: ∀d1,e2,T1,T2. ⇧[d1, e2] T1 ≡ T2 →
 335                   ∀d2,e1. d1 ≤ d2 → d2 ≤ d1 + e1 → e1 ≤ e2 →
 336                   ∃∃T. ⇧[d1, e1] T1 ≡ T & ⇧[d2, e2 - e1] T ≡ T2.
 337 #d1 #e2 #T1 #T2 #H elim H -d1 -e2 -T1 -T2
 338 [ /3 width=3/
 339 | #i #d1 #e2 #Hid1 #d2 #e1 #Hd12 #_ #_
 340   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2 /4 width=3/
 341 | #i #d1 #e2 #Hid1 #d2 #e1 #_ #Hd21 #He12
 342   lapply (transitive_le … (i+e1) Hd21 ?) /2 width=1/ -Hd21 #Hd21
 343   >(plus_minus_m_m e2 e1 ?) // /3 width=3/
 344 | /3 width=3/
 345 | #a #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
 346   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
 347   elim (IHT (d2+1) … ? ? He12) /2 width=1/ /3 width=5/
 348 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
 349   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
 350   elim (IHT d2 … ? ? He12) // /3 width=5/
 351 ]
 352 qed.
 353
 354 (* Basic_1: was only: dnf_dec2 dnf_dec *)
 355 lemma is_lift_dec: ∀T2,d,e. Decidable (∃T1. ⇧[d,e] T1 ≡ T2).
 356 #T1 elim T1 -T1
 357 [ * [1,3: /3 width=2/ ] #i #d #e
 358   elim (lt_dec i d) #Hid
 359   [ /4 width=2/
 360   | lapply (false_lt_to_le … Hid) -Hid #Hid
 361     elim (lt_dec i (d + e)) #Hide
 362     [ @or_intror * #T1 #H
 363       elim (lift_inv_lref2_be … H Hid Hide)
 364     | lapply (false_lt_to_le … Hide) -Hide /4 width=2/
 365     ]
 366   ]
 367 | * [ #a ] #I #V2 #T2 #IHV2 #IHT2 #d #e
 368   [ elim (IHV2 d e) -IHV2
 369     [ * #V1 #HV12 elim (IHT2 (d+1) e) -IHT2
 370       [ * #T1 #HT12 @or_introl /3 width=2/
 371       | -V1 #HT2 @or_intror * #X #H
 372         elim (lift_inv_bind2 … H) -H /3 width=2/
 373       ]
 374     | -IHT2 #HV2 @or_intror * #X #H
 375       elim (lift_inv_bind2 … H) -H /3 width=2/
 376     ]
 377   | elim (IHV2 d e) -IHV2
 378     [ * #V1 #HV12 elim (IHT2 d e) -IHT2
 379       [ * #T1 #HT12 /4 width=2/
 380       | -V1 #HT2 @or_intror * #X #H
 381         elim (lift_inv_flat2 … H) -H /3 width=2/
 382       ]
 383     | -IHT2 #HV2 @or_intror * #X #H
 384       elim (lift_inv_flat2 … H) -H /3 width=2/
 385     ]
 386   ]
 387 ]
 388 qed.
 389
 390 (* Basic_1: removed theorems 7:
 391             lift_head lift_gen_head
 392             lift_weight_map lift_weight lift_weight_add lift_weight_add_O
 393             lift_tlt_dx
 394 *)