matita/matita/contribs/lambdadelta/basic_2/relocation/lifts.ma

   1
   2 (**************************************************************************)
   3 (*       ___                                                              *)
   4 (*      ||M||                                                             *)
   5 (*      ||A||       A project by Andrea Asperti                           *)
   6 (*      ||T||                                                             *)
   7 (*      ||I||       Developers:                                           *)
   8 (*      ||T||         The HELM team.                                      *)
   9 (*      ||A||         http://helm.cs.unibo.it                             *)
  10 (*      \   /                                                             *)
  11 (*       \ /        This file is distributed under the terms of the       *)
  12 (*        v         GNU General Public License Version 2                  *)
  13 (*                                                                        *)
  14 (**************************************************************************)
  15
  16 include "ground_2/relocation/nstream_after.ma".
  17 include "basic_2/notation/relations/rliftstar_3.ma".
  18 include "basic_2/syntax/term.ma".
  19
  20 (* GENERIC RELOCATION FOR TERMS *********************************************)
  21
  22 (* Basic_1: includes:
  23             lift_sort lift_lref_lt lift_lref_ge lift_bind lift_flat
  24             lifts_nil lifts_cons
  25 *)
  26 inductive lifts: rtmap → relation term ≝
  27 | lifts_sort: ∀f,s. lifts f (⋆s) (⋆s)
  28 | lifts_lref: ∀f,i1,i2. @⦃i1, f⦄ ≘ i2 → lifts f (#i1) (#i2)
  29 | lifts_gref: ∀f,l. lifts f (§l) (§l)
  30 | lifts_bind: ∀f,p,I,V1,V2,T1,T2.
  31               lifts f V1 V2 → lifts (⫯f) T1 T2 →
  32               lifts f (ⓑ{p,I}V1.T1) (ⓑ{p,I}V2.T2)
  33 | lifts_flat: ∀f,I,V1,V2,T1,T2.
  34               lifts f V1 V2 → lifts f T1 T2 →
  35               lifts f (ⓕ{I}V1.T1) (ⓕ{I}V2.T2)
  36 .
  37
  38 interpretation "uniform relocation (term)"
  39    'RLiftStar i T1 T2 = (lifts (uni i) T1 T2).
  40
  41 interpretation "generic relocation (term)"
  42    'RLiftStar f T1 T2 = (lifts f T1 T2).
  43
  44 definition liftable2_sn: predicate (relation term) ≝
  45                          λR. ∀T1,T2. R T1 T2 → ∀f,U1. ⬆*[f] T1 ≘ U1 →
  46                          ∃∃U2. ⬆*[f] T2 ≘ U2 & R U1 U2.
  47
  48 definition deliftable2_sn: predicate (relation term) ≝
  49                            λR. ∀U1,U2. R U1 U2 → ∀f,T1. ⬆*[f] T1 ≘ U1 →
  50                            ∃∃T2. ⬆*[f] T2 ≘ U2 & R T1 T2.
  51
  52 definition liftable2_bi: predicate (relation term) ≝
  53                          λR. ∀T1,T2. R T1 T2 → ∀f,U1. ⬆*[f] T1 ≘ U1 →
  54                          ∀U2. ⬆*[f] T2 ≘ U2 → R U1 U2.
  55
  56 definition deliftable2_bi: predicate (relation term) ≝
  57                            λR. ∀U1,U2. R U1 U2 → ∀f,T1. ⬆*[f] T1 ≘ U1 →
  58                            ∀T2. ⬆*[f] T2 ≘ U2 → R T1 T2.
  59
  60 (* Basic inversion lemmas ***************************************************)
  61
  62 fact lifts_inv_sort1_aux: ∀f,X,Y. ⬆*[f] X ≘ Y → ∀s. X = ⋆s → Y = ⋆s.
  63 #f #X #Y * -f -X -Y //
  64 [ #f #i1 #i2 #_ #x #H destruct
  65 | #f #p #I #V1 #V2 #T1 #T2 #_ #_ #x #H destruct
  66 | #f #I #V1 #V2 #T1 #T2 #_ #_ #x #H destruct
  67 ]
  68 qed-.
  69
  70 (* Basic_1: was: lift1_sort *)
  71 (* Basic_2A1: includes: lift_inv_sort1 *)
  72 lemma lifts_inv_sort1: ∀f,Y,s. ⬆*[f] ⋆s ≘ Y → Y = ⋆s.
  73 /2 width=4 by lifts_inv_sort1_aux/ qed-.
  74
  75 fact lifts_inv_lref1_aux: ∀f,X,Y. ⬆*[f] X ≘ Y → ∀i1. X = #i1 →
  76                           ∃∃i2. @⦃i1, f⦄ ≘ i2 & Y = #i2.
  77 #f #X #Y * -f -X -Y
  78 [ #f #s #x #H destruct
  79 | #f #i1 #i2 #Hi12 #x #H destruct /2 width=3 by ex2_intro/
  80 | #f #l #x #H destruct
  81 | #f #p #I #V1 #V2 #T1 #T2 #_ #_ #x #H destruct
  82 | #f #I #V1 #V2 #T1 #T2 #_ #_ #x #H destruct
  83 ]
  84 qed-.
  85
  86 (* Basic_1: was: lift1_lref *)
  87 (* Basic_2A1: includes: lift_inv_lref1 lift_inv_lref1_lt lift_inv_lref1_ge *)
  88 lemma lifts_inv_lref1: ∀f,Y,i1. ⬆*[f] #i1 ≘ Y →
  89                        ∃∃i2. @⦃i1, f⦄ ≘ i2 & Y = #i2.
  90 /2 width=3 by lifts_inv_lref1_aux/ qed-.
  91
  92 fact lifts_inv_gref1_aux: ∀f,X,Y. ⬆*[f] X ≘ Y → ∀l. X = §l → Y = §l.
  93 #f #X #Y * -f -X -Y //
  94 [ #f #i1 #i2 #_ #x #H destruct
  95 | #f #p #I #V1 #V2 #T1 #T2 #_ #_ #x #H destruct
  96 | #f #I #V1 #V2 #T1 #T2 #_ #_ #x #H destruct
  97 ]
  98 qed-.
  99
 100 (* Basic_2A1: includes: lift_inv_gref1 *)
 101 lemma lifts_inv_gref1: ∀f,Y,l. ⬆*[f] §l ≘ Y → Y = §l.
 102 /2 width=4 by lifts_inv_gref1_aux/ qed-.
 103
 104 fact lifts_inv_bind1_aux: ∀f,X,Y. ⬆*[f] X ≘ Y →
 105                           ∀p,I,V1,T1. X = ⓑ{p,I}V1.T1 →
 106                           ∃∃V2,T2. ⬆*[f] V1 ≘ V2 & ⬆*[⫯f] T1 ≘ T2 &
 107                                    Y = ⓑ{p,I}V2.T2.
 108 #f #X #Y * -f -X -Y
 109 [ #f #s #q #J #W1 #U1 #H destruct
 110 | #f #i1 #i2 #_ #q #J #W1 #U1 #H destruct
 111 | #f #l #b #J #W1 #U1 #H destruct
 112 | #f #p #I #V1 #V2 #T1 #T2 #HV12 #HT12 #q #J #W1 #U1 #H destruct /2 width=5 by ex3_2_intro/
 113 | #f #I #V1 #V2 #T1 #T2 #_ #_ #q #J #W1 #U1 #H destruct
 114 ]
 115 qed-.
 116
 117 (* Basic_1: was: lift1_bind *)
 118 (* Basic_2A1: includes: lift_inv_bind1 *)
 119 lemma lifts_inv_bind1: ∀f,p,I,V1,T1,Y. ⬆*[f] ⓑ{p,I}V1.T1 ≘ Y →
 120                        ∃∃V2,T2. ⬆*[f] V1 ≘ V2 & ⬆*[⫯f] T1 ≘ T2 &
 121                                 Y = ⓑ{p,I}V2.T2.
 122 /2 width=3 by lifts_inv_bind1_aux/ qed-.
 123
 124 fact lifts_inv_flat1_aux: ∀f:rtmap. ∀X,Y. ⬆*[f] X ≘ Y →
 125                           ∀I,V1,T1. X = ⓕ{I}V1.T1 →
 126                           ∃∃V2,T2. ⬆*[f] V1 ≘ V2 & ⬆*[f] T1 ≘ T2 &
 127                                    Y = ⓕ{I}V2.T2.
 128 #f #X #Y * -f -X -Y
 129 [ #f #s #J #W1 #U1 #H destruct
 130 | #f #i1 #i2 #_ #J #W1 #U1 #H destruct
 131 | #f #l #J #W1 #U1 #H destruct
 132 | #f #p #I #V1 #V2 #T1 #T2 #_ #_ #J #W1 #U1 #H destruct
 133 | #f #I #V1 #V2 #T1 #T2 #HV12 #HT12 #J #W1 #U1 #H destruct /2 width=5 by ex3_2_intro/
 134 ]
 135 qed-.
 136
 137 (* Basic_1: was: lift1_flat *)
 138 (* Basic_2A1: includes: lift_inv_flat1 *)
 139 lemma lifts_inv_flat1: ∀f:rtmap. ∀I,V1,T1,Y. ⬆*[f] ⓕ{I}V1.T1 ≘ Y →
 140                        ∃∃V2,T2. ⬆*[f] V1 ≘ V2 & ⬆*[f] T1 ≘ T2 &
 141                                 Y = ⓕ{I}V2.T2.
 142 /2 width=3 by lifts_inv_flat1_aux/ qed-.
 143
 144 fact lifts_inv_sort2_aux: ∀f,X,Y. ⬆*[f] X ≘ Y → ∀s. Y = ⋆s → X = ⋆s.
 145 #f #X #Y * -f -X -Y //
 146 [ #f #i1 #i2 #_ #x #H destruct
 147 | #f #p #I #V1 #V2 #T1 #T2 #_ #_ #x #H destruct
 148 | #f #I #V1 #V2 #T1 #T2 #_ #_ #x #H destruct
 149 ]
 150 qed-.
 151
 152 (* Basic_1: includes: lift_gen_sort *)
 153 (* Basic_2A1: includes: lift_inv_sort2 *)
 154 lemma lifts_inv_sort2: ∀f,X,s. ⬆*[f] X ≘ ⋆s → X = ⋆s.
 155 /2 width=4 by lifts_inv_sort2_aux/ qed-.
 156
 157 fact lifts_inv_lref2_aux: ∀f,X,Y. ⬆*[f] X ≘ Y → ∀i2. Y = #i2 →
 158                           ∃∃i1. @⦃i1, f⦄ ≘ i2 & X = #i1.
 159 #f #X #Y * -f -X -Y
 160 [ #f #s #x #H destruct
 161 | #f #i1 #i2 #Hi12 #x #H destruct /2 width=3 by ex2_intro/
 162 | #f #l #x #H destruct
 163 | #f #p #I #V1 #V2 #T1 #T2 #_ #_ #x #H destruct
 164 | #f #I #V1 #V2 #T1 #T2 #_ #_ #x #H destruct
 165 ]
 166 qed-.
 167
 168 (* Basic_1: includes: lift_gen_lref lift_gen_lref_lt lift_gen_lref_false lift_gen_lref_ge *)
 169 (* Basic_2A1: includes: lift_inv_lref2 lift_inv_lref2_lt lift_inv_lref2_be lift_inv_lref2_ge lift_inv_lref2_plus *)
 170 lemma lifts_inv_lref2: ∀f,X,i2. ⬆*[f] X ≘ #i2 →
 171                        ∃∃i1. @⦃i1, f⦄ ≘ i2 & X = #i1.
 172 /2 width=3 by lifts_inv_lref2_aux/ qed-.
 173
 174 fact lifts_inv_gref2_aux: ∀f,X,Y. ⬆*[f] X ≘ Y → ∀l. Y = §l → X = §l.
 175 #f #X #Y * -f -X -Y //
 176 [ #f #i1 #i2 #_ #x #H destruct
 177 | #f #p #I #V1 #V2 #T1 #T2 #_ #_ #x #H destruct
 178 | #f #I #V1 #V2 #T1 #T2 #_ #_ #x #H destruct
 179 ]
 180 qed-.
 181
 182 (* Basic_2A1: includes: lift_inv_gref1 *)
 183 lemma lifts_inv_gref2: ∀f,X,l. ⬆*[f] X ≘ §l → X = §l.
 184 /2 width=4 by lifts_inv_gref2_aux/ qed-.
 185
 186 fact lifts_inv_bind2_aux: ∀f,X,Y. ⬆*[f] X ≘ Y →
 187                           ∀p,I,V2,T2. Y = ⓑ{p,I}V2.T2 →
 188                           ∃∃V1,T1. ⬆*[f] V1 ≘ V2 & ⬆*[⫯f] T1 ≘ T2 &
 189                                    X = ⓑ{p,I}V1.T1.
 190 #f #X #Y * -f -X -Y
 191 [ #f #s #q #J #W2 #U2 #H destruct
 192 | #f #i1 #i2 #_ #q #J #W2 #U2 #H destruct
 193 | #f #l #q #J #W2 #U2 #H destruct
 194 | #f #p #I #V1 #V2 #T1 #T2 #HV12 #HT12 #q #J #W2 #U2 #H destruct /2 width=5 by ex3_2_intro/
 195 | #f #I #V1 #V2 #T1 #T2 #_ #_ #q #J #W2 #U2 #H destruct
 196 ]
 197 qed-.
 198
 199 (* Basic_1: includes: lift_gen_bind *)
 200 (* Basic_2A1: includes: lift_inv_bind2 *)
 201 lemma lifts_inv_bind2: ∀f,p,I,V2,T2,X. ⬆*[f] X ≘ ⓑ{p,I}V2.T2 →
 202                        ∃∃V1,T1. ⬆*[f] V1 ≘ V2 & ⬆*[⫯f] T1 ≘ T2 &
 203                                 X = ⓑ{p,I}V1.T1.
 204 /2 width=3 by lifts_inv_bind2_aux/ qed-.
 205
 206 fact lifts_inv_flat2_aux: ∀f:rtmap. ∀X,Y. ⬆*[f] X ≘ Y →
 207                           ∀I,V2,T2. Y = ⓕ{I}V2.T2 →
 208                           ∃∃V1,T1. ⬆*[f] V1 ≘ V2 & ⬆*[f] T1 ≘ T2 &
 209                                    X = ⓕ{I}V1.T1.
 210 #f #X #Y * -f -X -Y
 211 [ #f #s #J #W2 #U2 #H destruct
 212 | #f #i1 #i2 #_ #J #W2 #U2 #H destruct
 213 | #f #l #J #W2 #U2 #H destruct
 214 | #f #p #I #V1 #V2 #T1 #T2 #_ #_ #J #W2 #U2 #H destruct
 215 | #f #I #V1 #V2 #T1 #T2 #HV12 #HT12 #J #W2 #U2 #H destruct /2 width=5 by ex3_2_intro/
 216 ]
 217 qed-.
 218
 219 (* Basic_1: includes: lift_gen_flat *)
 220 (* Basic_2A1: includes: lift_inv_flat2 *)
 221 lemma lifts_inv_flat2: ∀f:rtmap. ∀I,V2,T2,X. ⬆*[f] X ≘ ⓕ{I}V2.T2 →
 222                        ∃∃V1,T1. ⬆*[f] V1 ≘ V2 & ⬆*[f] T1 ≘ T2 &
 223                                 X = ⓕ{I}V1.T1.
 224 /2 width=3 by lifts_inv_flat2_aux/ qed-.
 225
 226 (* Advanced inversion lemmas ************************************************)
 227
 228 lemma lifts_inv_atom1: ∀f,I,Y. ⬆*[f] ⓪{I} ≘ Y →
 229                        ∨∨ ∃∃s. I = Sort s & Y = ⋆s
 230                         | ∃∃i,j. @⦃i, f⦄ ≘ j & I = LRef i & Y = #j
 231                         | ∃∃l. I = GRef l & Y = §l.
 232 #f * #n #Y #H
 233 [ lapply (lifts_inv_sort1 … H)
 234 | elim (lifts_inv_lref1 … H)
 235 | lapply (lifts_inv_gref1 … H)
 236 ] -H /3 width=5 by or3_intro0, or3_intro1, or3_intro2, ex3_2_intro, ex2_intro/
 237 qed-.
 238
 239 lemma lifts_inv_atom2: ∀f,I,X. ⬆*[f] X ≘ ⓪{I} →
 240                        ∨∨ ∃∃s. X = ⋆s & I = Sort s
 241                         | ∃∃i,j. @⦃i, f⦄ ≘ j & X = #i & I = LRef j
 242                         | ∃∃l. X = §l & I = GRef l.
 243 #f * #n #X #H
 244 [ lapply (lifts_inv_sort2 … H)
 245 | elim (lifts_inv_lref2 … H)
 246 | lapply (lifts_inv_gref2 … H)
 247 ] -H /3 width=5 by or3_intro0, or3_intro1, or3_intro2, ex3_2_intro, ex2_intro/
 248 qed-.
 249
 250 (* Basic_2A1: includes: lift_inv_pair_xy_x *)
 251 lemma lifts_inv_pair_xy_x: ∀f,I,V,T. ⬆*[f] ②{I}V.T ≘ V → ⊥.
 252 #f #J #V elim V -V
 253 [ * #i #U #H
 254   [ lapply (lifts_inv_sort2 … H) -H #H destruct
 255   | elim (lifts_inv_lref2 … H) -H
 256     #x #_ #H destruct
 257   | lapply (lifts_inv_gref2 … H) -H #H destruct
 258   ]
 259 | * [ #p ] #I #V2 #T2 #IHV2 #_ #U #H
 260   [ elim (lifts_inv_bind2 … H) -H #V1 #T1 #HV12 #_ #H destruct /2 width=3 by/
 261   | elim (lifts_inv_flat2 … H) -H #V1 #T1 #HV12 #_ #H destruct /2 width=3 by/
 262   ]
 263 ]
 264 qed-.
 265
 266 (* Basic_1: includes: thead_x_lift_y_y *)
 267 (* Basic_2A1: includes: lift_inv_pair_xy_y *)
 268 lemma lifts_inv_pair_xy_y: ∀I,T,V,f. ⬆*[f] ②{I}V.T ≘ T → ⊥.
 269 #J #T elim T -T
 270 [ * #i #W #f #H
 271   [ lapply (lifts_inv_sort2 … H) -H #H destruct
 272   | elim (lifts_inv_lref2 … H) -H
 273     #x #_ #H destruct
 274   | lapply (lifts_inv_gref2 … H) -H #H destruct
 275   ]
 276 | * [ #p ] #I #V2 #T2 #_ #IHT2 #W #f #H
 277   [ elim (lifts_inv_bind2 … H) -H #V1 #T1 #_ #HT12 #H destruct /2 width=4 by/
 278   | elim (lifts_inv_flat2 … H) -H #V1 #T1 #_ #HT12 #H destruct /2 width=4 by/
 279   ]
 280 ]
 281 qed-.
 282
 283 (* Inversion lemmas with uniform relocations ********************************)
 284
 285 lemma lifts_inv_lref1_uni: ∀l,Y,i. ⬆*[l] #i ≘ Y → Y = #(l+i).
 286 #l #Y #i1 #H elim (lifts_inv_lref1 … H) -H /4 width=4 by at_mono, eq_f/
 287 qed-.
 288
 289 lemma lifts_inv_lref2_uni: ∀l,X,i2. ⬆*[l] X ≘ #i2 →
 290                            ∃∃i1. X = #i1 & i2 = l + i1.
 291 #l #X #i2 #H elim (lifts_inv_lref2 … H) -H
 292 /3 width=3 by at_inv_uni, ex2_intro/
 293 qed-.
 294
 295 lemma lifts_inv_lref2_uni_ge: ∀l,X,i. ⬆*[l] X ≘ #(l + i) → X = #i.
 296 #l #X #i2 #H elim (lifts_inv_lref2_uni … H) -H
 297 #i1 #H1 #H2 destruct /4 width=2 by injective_plus_r, eq_f, sym_eq/
 298 qed-.
 299
 300 lemma lifts_inv_lref2_uni_lt: ∀l,X,i. ⬆*[l] X ≘ #i → i < l → ⊥.
 301 #l #X #i2 #H elim (lifts_inv_lref2_uni … H) -H
 302 #i1 #_ #H1 #H2 destruct /2 width=4 by lt_le_false/
 303 qed-.
 304
 305 (* Basic forward lemmas *****************************************************)
 306
 307 (* Basic_2A1: includes: lift_inv_O2 *)
 308 lemma lifts_fwd_isid: ∀f,T1,T2. ⬆*[f] T1 ≘ T2 → 𝐈⦃f⦄ → T1 = T2.
 309 #f #T1 #T2 #H elim H -f -T1 -T2
 310 /4 width=3 by isid_inv_at_mono, isid_push, eq_f2, eq_f/
 311 qed-.
 312
 313 (* Basic_2A1: includes: lift_fwd_pair1 *)
 314 lemma lifts_fwd_pair1: ∀f:rtmap. ∀I,V1,T1,Y. ⬆*[f] ②{I}V1.T1 ≘ Y →
 315                        ∃∃V2,T2. ⬆*[f] V1 ≘ V2 & Y = ②{I}V2.T2.
 316 #f * [ #p ] #I #V1 #T1 #Y #H
 317 [ elim (lifts_inv_bind1 … H) -H /2 width=4 by ex2_2_intro/
 318 | elim (lifts_inv_flat1 … H) -H /2 width=4 by ex2_2_intro/
 319 ]
 320 qed-.
 321
 322 (* Basic_2A1: includes: lift_fwd_pair2 *)
 323 lemma lifts_fwd_pair2: ∀f:rtmap. ∀I,V2,T2,X. ⬆*[f] X ≘ ②{I}V2.T2 →
 324                        ∃∃V1,T1. ⬆*[f] V1 ≘ V2 & X = ②{I}V1.T1.
 325 #f * [ #p ] #I #V2 #T2 #X #H
 326 [ elim (lifts_inv_bind2 … H) -H /2 width=4 by ex2_2_intro/
 327 | elim (lifts_inv_flat2 … H) -H /2 width=4 by ex2_2_intro/
 328 ]
 329 qed-.
 330
 331 (* Basic properties *********************************************************)
 332
 333 lemma lifts_eq_repl_back: ∀T1,T2. eq_repl_back … (λf. ⬆*[f] T1 ≘ T2).
 334 #T1 #T2 #f1 #H elim H -T1 -T2 -f1
 335 /4 width=5 by lifts_flat, lifts_bind, lifts_lref, at_eq_repl_back, eq_push/
 336 qed-.
 337
 338 lemma lifts_eq_repl_fwd: ∀T1,T2. eq_repl_fwd … (λf. ⬆*[f] T1 ≘ T2).
 339 #T1 #T2 @eq_repl_sym /2 width=3 by lifts_eq_repl_back/ (**) (* full auto fails *)
 340 qed-.
 341
 342 (* Basic_1: includes: lift_r *)
 343 (* Basic_2A1: includes: lift_refl *)
 344 lemma lifts_refl: ∀T,f. 𝐈⦃f⦄ → ⬆*[f] T ≘ T.
 345 #T elim T -T *
 346 /4 width=3 by lifts_flat, lifts_bind, lifts_lref, isid_inv_at, isid_push/
 347 qed.
 348
 349 (* Basic_2A1: includes: lift_total *)
 350 lemma lifts_total: ∀T1,f. ∃T2. ⬆*[f] T1 ≘ T2.
 351 #T1 elim T1 -T1 *
 352 /3 width=2 by lifts_lref, lifts_sort, lifts_gref, ex_intro/
 353 [ #p ] #I #V1 #T1 #IHV1 #IHT1 #f
 354 elim (IHV1 f) -IHV1 #V2 #HV12
 355 [ elim (IHT1 (⫯f)) -IHT1 /3 width=2 by lifts_bind, ex_intro/
 356 | elim (IHT1 f) -IHT1 /3 width=2 by lifts_flat, ex_intro/
 357 ]
 358 qed-.
 359
 360 lemma lift_lref_uni: ∀l,i. ⬆*[l] #i ≘ #(l+i).
 361 #l elim l -l /2 width=1 by lifts_lref/
 362 qed.
 363
 364 (* Basic_1: includes: lift_free (right to left) *)
 365 (* Basic_2A1: includes: lift_split *)
 366 lemma lifts_split_trans: ∀f,T1,T2. ⬆*[f] T1 ≘ T2 →
 367                          ∀f1,f2. f2 ⊚ f1 ≘ f →
 368                          ∃∃T. ⬆*[f1] T1 ≘ T & ⬆*[f2] T ≘ T2.
 369 #f #T1 #T2 #H elim H -f -T1 -T2
 370 [ /3 width=3 by lifts_sort, ex2_intro/
 371 | #f #i1 #i2 #Hi #f1 #f2 #Ht elim (after_at_fwd … Hi … Ht) -Hi -Ht
 372   /3 width=3 by lifts_lref, ex2_intro/
 373 | /3 width=3 by lifts_gref, ex2_intro/
 374 | #f #p #I #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #f1 #f2 #Ht
 375   elim (IHV … Ht) elim (IHT (⫯f1) (⫯f2)) -IHV -IHT
 376   /3 width=5 by lifts_bind, after_O2, ex2_intro/
 377 | #f #I #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #f1 #f2 #Ht
 378   elim (IHV … Ht) elim (IHT … Ht) -IHV -IHT -Ht
 379   /3 width=5 by lifts_flat, ex2_intro/
 380 ]
 381 qed-.
 382
 383 (* Note: apparently, this was missing in Basic_2A1 *)
 384 lemma lifts_split_div: ∀f1,T1,T2. ⬆*[f1] T1 ≘ T2 →
 385                        ∀f2,f. f2 ⊚ f1 ≘ f →
 386                        ∃∃T. ⬆*[f2] T2 ≘ T & ⬆*[f] T1 ≘ T.
 387 #f1 #T1 #T2 #H elim H -f1 -T1 -T2
 388 [ /3 width=3 by lifts_sort, ex2_intro/
 389 | #f1 #i1 #i2 #Hi #f2 #f #Ht elim (after_at1_fwd … Hi … Ht) -Hi -Ht
 390   /3 width=3 by lifts_lref, ex2_intro/
 391 | /3 width=3 by lifts_gref, ex2_intro/
 392 | #f1 #p #I #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #f2 #f #Ht
 393   elim (IHV … Ht) elim (IHT (⫯f2) (⫯f)) -IHV -IHT
 394   /3 width=5 by lifts_bind, after_O2, ex2_intro/
 395 | #f1 #I #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #f2 #f #Ht
 396   elim (IHV … Ht) elim (IHT … Ht) -IHV -IHT -Ht
 397   /3 width=5 by lifts_flat, ex2_intro/
 398 ]
 399 qed-.
 400
 401 (* Basic_1: includes: dnf_dec2 dnf_dec *)
 402 (* Basic_2A1: includes: is_lift_dec *)
 403 lemma is_lifts_dec: ∀T2,f. Decidable (∃T1. ⬆*[f] T1 ≘ T2).
 404 #T1 elim T1 -T1
 405 [ * [1,3: /3 width=2 by lifts_sort, lifts_gref, ex_intro, or_introl/ ]
 406   #i2 #f elim (is_at_dec f i2) //
 407   [ * /4 width=3 by lifts_lref, ex_intro, or_introl/
 408   | #H @or_intror *
 409     #X #HX elim (lifts_inv_lref2 … HX) -HX
 410     /3 width=2 by ex_intro/
 411   ]
 412 | * [ #p ] #I #V2 #T2 #IHV2 #IHT2 #f
 413   [ elim (IHV2 f) -IHV2
 414     [ * #V1 #HV12 elim (IHT2 (⫯f)) -IHT2
 415       [ * #T1 #HT12 @or_introl /3 width=2 by lifts_bind, ex_intro/
 416       | -V1 #HT2 @or_intror * #X #H
 417         elim (lifts_inv_bind2 … H) -H /3 width=2 by ex_intro/
 418       ]
 419     | -IHT2 #HV2 @or_intror * #X #H
 420       elim (lifts_inv_bind2 … H) -H /3 width=2 by ex_intro/
 421     ]
 422   | elim (IHV2 f) -IHV2
 423     [ * #V1 #HV12 elim (IHT2 f) -IHT2
 424       [ * #T1 #HT12 /4 width=2 by lifts_flat, ex_intro, or_introl/
 425       | -V1 #HT2 @or_intror * #X #H
 426         elim (lifts_inv_flat2 … H) -H /3 width=2 by ex_intro/
 427       ]
 428     | -IHT2 #HV2 @or_intror * #X #H
 429       elim (lifts_inv_flat2 … H) -H /3 width=2 by ex_intro/
 430     ]
 431   ]
 432 ]
 433 qed-.
 434
 435 (* Properties with uniform relocation ***************************************)
 436
 437 lemma lifts_uni: ∀n1,n2,T,U. ⬆*[𝐔❴n1❵∘𝐔❴n2❵] T ≘ U → ⬆*[n1+n2] T ≘ U.
 438 /3 width=4 by lifts_eq_repl_back, after_inv_total/ qed.
 439
 440 (* Basic_2A1: removed theorems 14:
 441               lifts_inv_nil lifts_inv_cons
 442               lift_inv_Y1 lift_inv_Y2 lift_inv_lref_Y1 lift_inv_lref_Y2 lift_lref_Y lift_Y1
 443               lift_lref_lt_eq lift_lref_ge_eq lift_lref_plus lift_lref_pred
 444               lift_lref_ge_minus lift_lref_ge_minus_eq
 445 *)
 446 (* Basic_1: removed theorems 8:
 447             lift_lref_gt
 448             lift_head lift_gen_head
 449             lift_weight_map lift_weight lift_weight_add lift_weight_add_O
 450             lift_tlt_dx
 451 *)