matita/matita/contribs/lambdadelta/basic_2/relocation/lifts_lifts_vector.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/lifts_lifts.ma".
  16 include "basic_2/relocation/lifts_vector.ma".
  17
  18 (* GENERIC RELOCATION FOR TERM VECTORS *************************************)
  19
  20 (* Main properties **********************************************************)
  21
  22 (* Basic_1: includes: lifts_inj *)
  23 theorem liftsv_inj: ∀T1c,Us,f. ⬆*[f] T1c ≡ Us →
  24                     ∀T2c. ⬆*[f] T2c ≡ Us → T1c = T2c.
  25 #T1c #Us #f #H elim H -T1c -Us
  26 [ #T2c #H >(liftsv_inv_nil2 … H) -H //
  27 | #T1c #Us #T1 #U #HT1U #_ #IHT1Us #X #H destruct
  28   elim (liftsv_inv_cons2 … H) -H #T2 #T2c #HT2U #HT2Us #H destruct
  29   >(lifts_inj … HT1U … HT2U) -U /3 width=1 by eq_f/
  30 ]
  31 qed-.
  32
  33 (* Basic_2A1: includes: liftv_mono *)
  34 theorem liftsv_mono: ∀Ts,U1c,f. ⬆*[f] Ts ≡ U1c →
  35                      ∀U2c. ⬆*[f] Ts ≡ U2c → U1c = U2c.
  36 #Ts #U1c #f #H elim H -Ts -U1c
  37 [ #U2c #H >(liftsv_inv_nil1 … H) -H //
  38 | #Ts #U1c #T #U1 #HTU1 #_ #IHTU1c #X #H destruct
  39   elim (liftsv_inv_cons1 … H) -H #U2 #U2c #HTU2 #HTU2c #H destruct
  40   >(lifts_mono … HTU1 … HTU2) -T /3 width=1 by eq_f/
  41 ]
  42 qed-.
  43
  44 (* Basic_1: includes: lifts1_xhg (right to left) *)
  45 (* Basic_2A1: includes: liftsv_liftv_trans_le *)
  46 theorem liftsv_trans: ∀T1c,Ts,f1. ⬆*[f1] T1c ≡ Ts → ∀T2c,f2. ⬆*[f2] Ts ≡ T2c →
  47                       ∀f. f2 ⊚ f1 ≡ f → ⬆*[f] T1c ≡ T2c.
  48 #T1c #Ts #f1 #H elim H -T1c -Ts
  49 [ #T2c #f2 #H >(liftsv_inv_nil1 … H) -T2c /2 width=3 by liftsv_nil/
  50 | #T1c #Ts #T1 #T #HT1 #_ #IHT1c #X #f2 #H elim (liftsv_inv_cons1 … H) -H
  51   #T2 #T2c #HT2 #HT2c #H destruct /3 width=6 by lifts_trans, liftsv_cons/
  52 ]
  53 qed-.