matita/matita/contribs/lambdadelta/basic_2/relocation/lreq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/ideqsn_3.ma".
  16 include "basic_2/syntax/ceq_ext.ma".
  17 include "basic_2/relocation/lexs.ma".
  18
  19 (* RANGED EQUIVALENCE FOR LOCAL ENVIRONMENTS ********************************)
  20
  21 (* Basic_2A1: includes: lreq_atom lreq_zero lreq_pair lreq_succ *)
  22 definition lreq: relation3 rtmap lenv lenv ≝ lexs ceq_ext cfull.
  23
  24 interpretation
  25   "ranged equivalence (local environment)"
  26   'IdEqSn f L1 L2 = (lreq f L1 L2).
  27
  28 (* Basic properties *********************************************************)
  29
  30 lemma lreq_eq_repl_back: ∀L1,L2. eq_repl_back … (λf. L1 ≡[f] L2).
  31 /2 width=3 by lexs_eq_repl_back/ qed-.
  32
  33 lemma lreq_eq_repl_fwd: ∀L1,L2. eq_repl_fwd … (λf. L1 ≡[f] L2).
  34 /2 width=3 by lexs_eq_repl_fwd/ qed-.
  35
  36 lemma sle_lreq_trans: ∀f2,L1,L2. L1 ≡[f2] L2 →
  37                       ∀f1. f1 ⊆ f2 → L1 ≡[f1] L2.
  38 /2 width=3 by sle_lexs_trans/ qed-.
  39
  40 (* Basic_2A1: includes: lreq_refl *)
  41 lemma lreq_refl: ∀f. reflexive … (lreq f).
  42 /2 width=1 by lexs_refl/ qed.
  43
  44 (* Basic_2A1: includes: lreq_sym *)
  45 lemma lreq_sym: ∀f. symmetric … (lreq f).
  46 /3 width=2 by lexs_sym, cext2_sym/ qed-.
  47
  48 (* Basic inversion lemmas ***************************************************)
  49
  50 (* Basic_2A1: includes: lreq_inv_atom1 *)
  51 lemma lreq_inv_atom1: ∀f,Y. ⋆ ≡[f] Y → Y = ⋆.
  52 /2 width=4 by lexs_inv_atom1/ qed-.
  53
  54 (* Basic_2A1: includes: lreq_inv_pair1 *)
  55 lemma lreq_inv_next1: ∀g,J,K1,Y. K1.ⓘ{J} ≡[↑g] Y →
  56                       ∃∃K2. K1 ≡[g] K2 & Y = K2.ⓘ{J}.
  57 #g #J #K1 #Y #H
  58 elim (lexs_inv_next1 … H) -H #Z #K2 #HK12 #H1 #H2 destruct
  59 <(ceq_ext_inv_eq … H1) -Z /2 width=3 by ex2_intro/
  60 qed-.
  61
  62 (* Basic_2A1: includes: lreq_inv_zero1 lreq_inv_succ1 *)
  63 lemma lreq_inv_push1: ∀g,J1,K1,Y. K1.ⓘ{J1} ≡[⫯g] Y →
  64                       ∃∃J2,K2. K1 ≡[g] K2 & Y = K2.ⓘ{J2}.
  65 #g #J1 #K1 #Y #H elim (lexs_inv_push1 … H) -H /2 width=4 by ex2_2_intro/
  66 qed-.
  67
  68 (* Basic_2A1: includes: lreq_inv_atom2 *)
  69 lemma lreq_inv_atom2: ∀f,X. X ≡[f] ⋆ → X = ⋆.
  70 /2 width=4 by lexs_inv_atom2/ qed-.
  71
  72 (* Basic_2A1: includes: lreq_inv_pair2 *)
  73 lemma lreq_inv_next2: ∀g,J,X,K2. X ≡[↑g] K2.ⓘ{J} →
  74                       ∃∃K1. K1 ≡[g] K2 & X = K1.ⓘ{J}.
  75 #g #J #X #K2 #H
  76 elim (lexs_inv_next2 … H) -H #Z #K1 #HK12 #H1 #H2 destruct
  77 <(ceq_ext_inv_eq … H1) -J /2 width=3 by ex2_intro/
  78 qed-.
  79
  80 (* Basic_2A1: includes: lreq_inv_zero2 lreq_inv_succ2 *)
  81 lemma lreq_inv_push2: ∀g,J2,X,K2. X ≡[⫯g] K2.ⓘ{J2} →
  82                       ∃∃J1,K1. K1 ≡[g] K2 & X = K1.ⓘ{J1}.
  83 #g #J2 #X #K2 #H elim (lexs_inv_push2 … H) -H /2 width=4 by ex2_2_intro/
  84 qed-.
  85
  86 (* Basic_2A1: includes: lreq_inv_pair *)
  87 lemma lreq_inv_next: ∀f,I1,I2,L1,L2. L1.ⓘ{I1} ≡[↑f] L2.ⓘ{I2} →
  88                      L1 ≡[f] L2 ∧ I1 = I2.
  89 #f #I1 #I2 #L1 #L2 #H elim (lexs_inv_next … H) -H
  90 /3 width=3 by ceq_ext_inv_eq, conj/
  91 qed-.
  92
  93 (* Basic_2A1: includes: lreq_inv_succ *)
  94 lemma lreq_inv_push: ∀f,I1,I2,L1,L2. L1.ⓘ{I1} ≡[⫯f] L2.ⓘ{I2} → L1 ≡[f] L2.
  95 #f #I1 #I2 #L1 #L2 #H elim (lexs_inv_push … H) -H /2 width=1 by conj/
  96 qed-.
  97
  98 lemma lreq_inv_tl: ∀f,I,L1,L2. L1 ≡[⫱f] L2 → L1.ⓘ{I} ≡[f] L2.ⓘ{I}.
  99 /2 width=1 by lexs_inv_tl/ qed-.
 100
 101 (* Basic_2A1: removed theorems 5:
 102               lreq_pair_lt lreq_succ_lt lreq_pair_O_Y lreq_O2 lreq_inv_O_Y
 103 *)