matita/matita/contribs/lambdadelta/basic_2/relocation/sex.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_sle.ma".
  16 include "ground_2/relocation/rtmap_sdj.ma".
  17 include "basic_2/notation/relations/relation_5.ma".
  18 include "basic_2/syntax/lenv.ma".
  19
  20 (* GENERIC ENTRYWISE EXTENSION OF CONTEXT-SENSITIVE REALTIONS FOR TERMS *****)
  21
  22 inductive sex (RN,RP:relation3 lenv bind bind): rtmap → relation lenv ≝
  23 | sex_atom: ∀f. sex RN RP f (⋆) (⋆)
  24 | sex_next: ∀f,I1,I2,L1,L2.
  25             sex RN RP f L1 L2 → RN L1 I1 I2 →
  26             sex RN RP (↑f) (L1.ⓘ{I1}) (L2.ⓘ{I2})
  27 | sex_push: ∀f,I1,I2,L1,L2.
  28             sex RN RP f L1 L2 → RP L1 I1 I2 →
  29             sex RN RP (⫯f) (L1.ⓘ{I1}) (L2.ⓘ{I2})
  30 .
  31
  32 interpretation "generic entrywise extension (local environment)"
  33    'Relation RN RP f L1 L2 = (sex RN RP f L1 L2).
  34
  35 definition R_pw_confluent2_sex: relation3 lenv bind bind → relation3 lenv bind bind →
  36                                 relation3 lenv bind bind → relation3 lenv bind bind →
  37                                 relation3 lenv bind bind → relation3 lenv bind bind →
  38                                 relation3 rtmap lenv bind ≝
  39                                 λR1,R2,RN1,RP1,RN2,RP2,f,L0,I0.
  40                                 ∀I1. R1 L0 I0 I1 → ∀I2. R2 L0 I0 I2 →
  41                                 ∀L1. L0 ⪤[RN1, RP1, f] L1 → ∀L2. L0 ⪤[RN2, RP2, f] L2 →
  42                                 ∃∃I. R2 L1 I1 I & R1 L2 I2 I.
  43
  44 definition sex_transitive: relation3 lenv bind bind → relation3 lenv bind bind →
  45                            relation3 lenv bind bind →
  46                            relation3 lenv bind bind → relation3 lenv bind bind →
  47                            relation3 rtmap lenv bind ≝
  48                            λR1,R2,R3,RN,RP,f,L1,I1.
  49                            ∀I. R1 L1 I1 I → ∀L2. L1 ⪤[RN, RP, f] L2 →
  50                            ∀I2. R2 L2 I I2 → R3 L1 I1 I2.
  51
  52 (* Basic inversion lemmas ***************************************************)
  53
  54 fact sex_inv_atom1_aux: ∀RN,RP,f,X,Y. X ⪤[RN, RP, f] Y → X = ⋆ → Y = ⋆.
  55 #RN #RP #f #X #Y * -f -X -Y //
  56 #f #I1 #I2 #L1 #L2 #_ #_ #H destruct
  57 qed-.
  58
  59 (* Basic_2A1: includes lpx_sn_inv_atom1 *)
  60 lemma sex_inv_atom1: ∀RN,RP,f,Y. ⋆ ⪤[RN, RP, f] Y → Y = ⋆.
  61 /2 width=6 by sex_inv_atom1_aux/ qed-.
  62
  63 fact sex_inv_next1_aux: ∀RN,RP,f,X,Y. X ⪤[RN, RP, f] Y → ∀g,J1,K1. X = K1.ⓘ{J1} → f = ↑g →
  64                         ∃∃J2,K2. K1 ⪤[RN, RP, g] K2 & RN K1 J1 J2 & Y = K2.ⓘ{J2}.
  65 #RN #RP #f #X #Y * -f -X -Y
  66 [ #f #g #J1 #K1 #H destruct
  67 | #f #I1 #I2 #L1 #L2 #HL #HI #g #J1 #K1 #H1 #H2 <(injective_next … H2) -g destruct
  68   /2 width=5 by ex3_2_intro/
  69 | #f #I1 #I2 #L1 #L2 #_ #_ #g #J1 #K1 #_ #H elim (discr_push_next … H)
  70 ]
  71 qed-.
  72
  73 (* Basic_2A1: includes lpx_sn_inv_pair1 *)
  74 lemma sex_inv_next1: ∀RN,RP,g,J1,K1,Y. K1.ⓘ{J1} ⪤[RN, RP, ↑g] Y →
  75                      ∃∃J2,K2. K1 ⪤[RN, RP, g] K2 & RN K1 J1 J2 & Y = K2.ⓘ{J2}.
  76 /2 width=7 by sex_inv_next1_aux/ qed-.
  77
  78 fact sex_inv_push1_aux: ∀RN,RP,f,X,Y. X ⪤[RN, RP, f] Y → ∀g,J1,K1. X = K1.ⓘ{J1} → f = ⫯g →
  79                         ∃∃J2,K2. K1 ⪤[RN, RP, g] K2 & RP K1 J1 J2 & Y = K2.ⓘ{J2}.
  80 #RN #RP #f #X #Y * -f -X -Y
  81 [ #f #g #J1 #K1 #H destruct
  82 | #f #I1 #I2 #L1 #L2 #_ #_ #g #J1 #K1 #_ #H elim (discr_next_push … H)
  83 | #f #I1 #I2 #L1 #L2 #HL #HI #g #J1 #K1 #H1 #H2 <(injective_push … H2) -g destruct
  84   /2 width=5 by ex3_2_intro/
  85 ]
  86 qed-.
  87
  88 lemma sex_inv_push1: ∀RN,RP,g,J1,K1,Y. K1.ⓘ{J1} ⪤[RN, RP, ⫯g] Y →
  89                      ∃∃J2,K2. K1 ⪤[RN, RP, g] K2 & RP K1 J1 J2 & Y = K2.ⓘ{J2}.
  90 /2 width=7 by sex_inv_push1_aux/ qed-.
  91
  92 fact sex_inv_atom2_aux: ∀RN,RP,f,X,Y. X ⪤[RN, RP, f] Y → Y = ⋆ → X = ⋆.
  93 #RN #RP #f #X #Y * -f -X -Y //
  94 #f #I1 #I2 #L1 #L2 #_ #_ #H destruct
  95 qed-.
  96
  97 (* Basic_2A1: includes lpx_sn_inv_atom2 *)
  98 lemma sex_inv_atom2: ∀RN,RP,f,X. X ⪤[RN, RP, f] ⋆ → X = ⋆.
  99 /2 width=6 by sex_inv_atom2_aux/ qed-.
 100
 101 fact sex_inv_next2_aux: ∀RN,RP,f,X,Y. X ⪤[RN, RP, f] Y → ∀g,J2,K2. Y = K2.ⓘ{J2} → f = ↑g →
 102                         ∃∃J1,K1. K1 ⪤[RN, RP, g] K2 & RN K1 J1 J2 & X = K1.ⓘ{J1}.
 103 #RN #RP #f #X #Y * -f -X -Y
 104 [ #f #g #J2 #K2 #H destruct
 105 | #f #I1 #I2 #L1 #L2 #HL #HI #g #J2 #K2 #H1 #H2 <(injective_next … H2) -g destruct
 106   /2 width=5 by ex3_2_intro/
 107 | #f #I1 #I2 #L1 #L2 #_ #_ #g #J2 #K2 #_ #H elim (discr_push_next … H)
 108 ]
 109 qed-.
 110
 111 (* Basic_2A1: includes lpx_sn_inv_pair2 *)
 112 lemma sex_inv_next2: ∀RN,RP,g,J2,X,K2. X ⪤[RN, RP, ↑g] K2.ⓘ{J2} →
 113                      ∃∃J1,K1. K1 ⪤[RN, RP, g] K2 & RN K1 J1 J2 & X = K1.ⓘ{J1}.
 114 /2 width=7 by sex_inv_next2_aux/ qed-.
 115
 116 fact sex_inv_push2_aux: ∀RN,RP,f,X,Y. X ⪤[RN, RP, f] Y → ∀g,J2,K2. Y = K2.ⓘ{J2} → f = ⫯g →
 117                         ∃∃J1,K1. K1 ⪤[RN, RP, g] K2 & RP K1 J1 J2 & X = K1.ⓘ{J1}.
 118 #RN #RP #f #X #Y * -f -X -Y
 119 [ #f #J2 #K2 #g #H destruct
 120 | #f #I1 #I2 #L1 #L2 #_ #_ #g #J2 #K2 #_ #H elim (discr_next_push … H)
 121 | #f #I1 #I2 #L1 #L2 #HL #HI #g #J2 #K2 #H1 #H2 <(injective_push … H2) -g destruct
 122   /2 width=5 by ex3_2_intro/
 123 ]
 124 qed-.
 125
 126 lemma sex_inv_push2: ∀RN,RP,g,J2,X,K2. X ⪤[RN, RP, ⫯g] K2.ⓘ{J2} →
 127                      ∃∃J1,K1. K1 ⪤[RN, RP, g] K2 & RP K1 J1 J2 & X = K1.ⓘ{J1}.
 128 /2 width=7 by sex_inv_push2_aux/ qed-.
 129
 130 (* Basic_2A1: includes lpx_sn_inv_pair *)
 131 lemma sex_inv_next: ∀RN,RP,f,I1,I2,L1,L2.
 132                     L1.ⓘ{I1} ⪤[RN, RP, ↑f] L2.ⓘ{I2} →
 133                     L1 ⪤[RN, RP, f] L2 ∧ RN L1 I1 I2.
 134 #RN #RP #f #I1 #I2 #L1 #L2 #H elim (sex_inv_next1 … H) -H
 135 #I0 #L0 #HL10 #HI10 #H destruct /2 width=1 by conj/
 136 qed-.
 137
 138 lemma sex_inv_push: ∀RN,RP,f,I1,I2,L1,L2.
 139                     L1.ⓘ{I1} ⪤[RN, RP, ⫯f] L2.ⓘ{I2} →
 140                     L1 ⪤[RN, RP, f] L2 ∧ RP L1 I1 I2.
 141 #RN #RP #f #I1 #I2 #L1 #L2 #H elim (sex_inv_push1 … H) -H
 142 #I0 #L0 #HL10 #HI10 #H destruct /2 width=1 by conj/
 143 qed-.
 144
 145 lemma sex_inv_tl: ∀RN,RP,f,I1,I2,L1,L2. L1 ⪤[RN, RP, ⫱f] L2 →
 146                   RN L1 I1 I2 → RP L1 I1 I2 →
 147                   L1.ⓘ{I1} ⪤[RN, RP, f] L2.ⓘ{I2}.
 148 #RN #RP #f #I1 #I2 #L2 #L2 elim (pn_split f) *
 149 /2 width=1 by sex_next, sex_push/
 150 qed-.
 151
 152 (* Basic forward lemmas *****************************************************)
 153
 154 lemma sex_fwd_bind: ∀RN,RP,f,I1,I2,L1,L2.
 155                     L1.ⓘ{I1} ⪤[RN, RP, f] L2.ⓘ{I2} →
 156                     L1 ⪤[RN, RP, ⫱f] L2.
 157 #RN #RP #f #I1 #I2 #L1 #L2 #Hf
 158 elim (pn_split f) * #g #H destruct
 159 [ elim (sex_inv_push … Hf) | elim (sex_inv_next … Hf) ] -Hf //
 160 qed-.
 161
 162 (* Basic properties *********************************************************)
 163
 164 lemma sex_eq_repl_back: ∀RN,RP,L1,L2. eq_repl_back … (λf. L1 ⪤[RN, RP, f] L2).
 165 #RN #RP #L1 #L2 #f1 #H elim H -f1 -L1 -L2 //
 166 #f1 #I1 #I2 #L1 #L2 #_ #HI #IH #f2 #H
 167 [ elim (eq_inv_nx … H) -H /3 width=3 by sex_next/
 168 | elim (eq_inv_px … H) -H /3 width=3 by sex_push/
 169 ]
 170 qed-.
 171
 172 lemma sex_eq_repl_fwd: ∀RN,RP,L1,L2. eq_repl_fwd … (λf. L1 ⪤[RN, RP, f] L2).
 173 #RN #RP #L1 #L2 @eq_repl_sym /2 width=3 by sex_eq_repl_back/ (**) (* full auto fails *)
 174 qed-.
 175
 176 lemma sex_refl: ∀RN,RP. c_reflexive … RN → c_reflexive … RP →
 177                 ∀f.reflexive … (sex RN RP f).
 178 #RN #RP #HRN #HRP #f #L generalize in match f; -f elim L -L //
 179 #L #I #IH #f elim (pn_split f) *
 180 #g #H destruct /2 width=1 by sex_next, sex_push/
 181 qed.
 182
 183 lemma sex_sym: ∀RN,RP.
 184                (∀L1,L2,I1,I2. RN L1 I1 I2 → RN L2 I2 I1) →
 185                (∀L1,L2,I1,I2. RP L1 I1 I2 → RP L2 I2 I1) →
 186                ∀f. symmetric … (sex RN RP f).
 187 #RN #RP #HRN #HRP #f #L1 #L2 #H elim H -L1 -L2 -f
 188 /3 width=2 by sex_next, sex_push/
 189 qed-.
 190
 191 lemma sex_pair_repl: ∀RN,RP,f,I1,I2,L1,L2.
 192                      L1.ⓘ{I1} ⪤[RN, RP, f] L2.ⓘ{I2} →
 193                      ∀J1,J2. RN L1 J1 J2 → RP L1 J1 J2 →
 194                      L1.ⓘ{J1} ⪤[RN, RP, f] L2.ⓘ{J2}.
 195 /3 width=3 by sex_inv_tl, sex_fwd_bind/ qed-.
 196
 197 lemma sex_co: ∀RN1,RP1,RN2,RP2. RN1 ⊆ RN2 → RP1 ⊆ RP2 →
 198               ∀f,L1,L2. L1 ⪤[RN1, RP1, f] L2 → L1 ⪤[RN2, RP2, f] L2.
 199 #RN1 #RP1 #RN2 #RP2 #HRN #HRP #f #L1 #L2 #H elim H -f -L1 -L2
 200 /3 width=1 by sex_atom, sex_next, sex_push/
 201 qed-.
 202
 203 lemma sex_co_isid: ∀RN1,RP1,RN2,RP2. RP1 ⊆ RP2 →
 204                    ∀f,L1,L2. L1 ⪤[RN1, RP1, f] L2 → 𝐈⦃f⦄ →
 205                    L1 ⪤[RN2, RP2, f] L2.
 206 #RN1 #RP1 #RN2 #RP2 #HR #f #L1 #L2 #H elim H -f -L1 -L2 //
 207 #f #I1 #I2 #K1 #K2 #_ #HI12 #IH #H
 208 [ elim (isid_inv_next … H) -H //
 209 | /4 width=3 by sex_push, isid_inv_push/
 210 ]
 211 qed-.
 212
 213 lemma sex_sdj: ∀RN,RP. RP ⊆ RN →
 214                ∀f1,L1,L2. L1 ⪤[RN, RP, f1] L2 →
 215                ∀f2. f1 ∥ f2 → L1 ⪤[RP, RN, f2] L2.
 216 #RN #RP #HR #f1 #L1 #L2 #H elim H -f1 -L1 -L2 //
 217 #f1 #I1 #I2 #L1 #L2 #_ #HI12 #IH #f2 #H12
 218 [ elim (sdj_inv_nx … H12) -H12 [2,3: // ]
 219   #g2 #H #H2 destruct /3 width=1 by sex_push/
 220 | elim (sdj_inv_px … H12) -H12 [2,4: // ] *
 221   #g2 #H #H2 destruct /3 width=1 by sex_next, sex_push/
 222 ]
 223 qed-.
 224
 225 lemma sle_sex_trans: ∀RN,RP. RN ⊆ RP →
 226                      ∀f2,L1,L2. L1 ⪤[RN, RP, f2] L2 →
 227                      ∀f1. f1 ⊆ f2 → L1 ⪤[RN, RP, f1] L2.
 228 #RN #RP #HR #f2 #L1 #L2 #H elim H -f2 -L1 -L2 //
 229 #f2 #I1 #I2 #L1 #L2 #_ #HI12 #IH #f1 #H12
 230 [ elim (pn_split f1) * ]
 231 [ /4 width=5 by sex_push, sle_inv_pn/
 232 | /4 width=5 by sex_next, sle_inv_nn/
 233 | elim (sle_inv_xp … H12) -H12 [2,3: // ]
 234   #g1 #H #H1 destruct /3 width=5 by sex_push/
 235 ]
 236 qed-.
 237
 238 lemma sle_sex_conf: ∀RN,RP. RP ⊆ RN →
 239                     ∀f1,L1,L2. L1 ⪤[RN, RP, f1] L2 →
 240                     ∀f2. f1 ⊆ f2 → L1 ⪤[RN, RP, f2] L2.
 241 #RN #RP #HR #f1 #L1 #L2 #H elim H -f1 -L1 -L2 //
 242 #f1 #I1 #I2 #L1 #L2 #_ #HI12 #IH #f2 #H12
 243 [2: elim (pn_split f2) * ]
 244 [ /4 width=5 by sex_push, sle_inv_pp/
 245 | /4 width=5 by sex_next, sle_inv_pn/
 246 | elim (sle_inv_nx … H12) -H12 [2,3: // ]
 247   #g2 #H #H2 destruct /3 width=5 by sex_next/
 248 ]
 249 qed-.
 250
 251 lemma sex_sle_split: ∀R1,R2,RP. c_reflexive … R1 → c_reflexive … R2 →
 252                      ∀f,L1,L2. L1 ⪤[R1, RP, f] L2 → ∀g. f ⊆ g →
 253                      ∃∃L. L1 ⪤[R1, RP, g] L & L ⪤[R2, cfull, f] L2.
 254 #R1 #R2 #RP #HR1 #HR2 #f #L1 #L2 #H elim H -f -L1 -L2
 255 [ /2 width=3 by sex_atom, ex2_intro/ ]
 256 #f #I1 #I2 #L1 #L2 #_ #HI12 #IH #y #H
 257 [ elim (sle_inv_nx … H ??) -H [ |*: // ] #g #Hfg #H destruct
 258   elim (IH … Hfg) -IH -Hfg /3 width=5 by sex_next, ex2_intro/
 259 | elim (sle_inv_px … H ??) -H [1,3: * |*: // ] #g #Hfg #H destruct
 260   elim (IH … Hfg) -IH -Hfg /3 width=5 by sex_next, sex_push, ex2_intro/
 261 ]
 262 qed-.
 263
 264 lemma sex_sdj_split: ∀R1,R2,RP. c_reflexive … R1 → c_reflexive … R2 →
 265                      ∀f,L1,L2. L1 ⪤[R1, RP, f] L2 → ∀g. f ∥ g →
 266                      ∃∃L. L1 ⪤[RP, R1, g] L & L ⪤[R2, cfull, f] L2.
 267 #R1 #R2 #RP #HR1 #HR2 #f #L1 #L2 #H elim H -f -L1 -L2
 268 [ /2 width=3 by sex_atom, ex2_intro/ ]
 269 #f #I1 #I2 #L1 #L2 #_ #HI12 #IH #y #H
 270 [ elim (sdj_inv_nx … H ??) -H [ |*: // ] #g #Hfg #H destruct
 271   elim (IH … Hfg) -IH -Hfg /3 width=5 by sex_next, sex_push, ex2_intro/
 272 | elim (sdj_inv_px … H ??) -H [1,3: * |*: // ] #g #Hfg #H destruct
 273   elim (IH … Hfg) -IH -Hfg /3 width=5 by sex_next, sex_push, ex2_intro/
 274 ]
 275 qed-.
 276
 277 lemma sex_dec: ∀RN,RP.
 278                (∀L,I1,I2. Decidable (RN L I1 I2)) →
 279                (∀L,I1,I2. Decidable (RP L I1 I2)) →
 280                ∀L1,L2,f. Decidable (L1 ⪤[RN, RP, f] L2).
 281 #RN #RP #HRN #HRP #L1 elim L1 -L1 [ * | #L1 #I1 #IH * ]
 282 [ /2 width=1 by sex_atom, or_introl/
 283 | #L2 #I2 #f @or_intror #H
 284   lapply (sex_inv_atom1 … H) -H #H destruct
 285 | #f @or_intror #H
 286   lapply (sex_inv_atom2 … H) -H #H destruct
 287 | #L2 #I2 #f elim (IH L2 (⫱f)) -IH #HL12
 288   [2: /4 width=3 by sex_fwd_bind, or_intror/ ]
 289   elim (pn_split f) * #g #H destruct
 290   [ elim (HRP L1 I1 I2) | elim (HRN L1 I1 I2) ] -HRP -HRN #HV12
 291   [1,3: /3 width=1 by sex_push, sex_next, or_introl/ ]
 292   @or_intror #H
 293   [ elim (sex_inv_push … H) | elim (sex_inv_next … H) ] -H
 294   /2 width=1 by/
 295 ]
 296 qed-.