matita/matita/contribs/lambdadelta/basic_2/rt_computation/cnuw_cnuw.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/cnuw.ma".
  16 include "basic_2/rt_computation/cprs_tweq.ma".
  17 include "basic_2/rt_computation/lprs_cpms.ma".
  18
  19 (* NORMAL TERMS FOR T-UNUNBOUND WHD RT-TRANSITION ***************************)
  20
  21 (* Advanced inversion lemmas ************************************************)
  22
  23 lemma cnuw_inv_abbr_pos (h) (G) (L):
  24       ∀V,T. ⦃G,L⦄ ⊢ ➡𝐍𝐖*[h] +ⓓV.T → ⊥.
  25 #h #G #L #V #T1 #H
  26 elim (cprs_abbr_pos_twneq h G L V T1) #T2 #HT12 #HnT12
  27 /3 width=2 by/
  28 qed-.
  29
  30 (* Advanced properties ******************************************************)
  31
  32 lemma cnuw_abbr_neg (h) (G) (L): ∀V,T. ⦃G,L⦄ ⊢ ➡𝐍𝐖*[h] -ⓓV.T.
  33 #h #G #L #V1 #T1 #n #X #H
  34 elim (cpms_inv_abbr_sn_dx … H) -H *
  35 [ #V2 #T2 #_ #_ #H destruct /1 width=1 by tweq_abbr_neg/
  36 | #X1 #_ #_ #H destruct
  37 ]
  38 qed.
  39
  40 lemma cnuw_abst (h) (p) (G) (L): ∀W,T. ⦃G,L⦄ ⊢ ➡𝐍𝐖*[h] ⓛ{p}W.T.
  41 #h #p #G #L #W1 #T1 #n #X #H
  42 elim (cpms_inv_abst_sn … H) -H #W2 #T2 #_ #_ #H destruct
  43 /1 width=1 by tweq_abst/
  44 qed.
  45
  46 lemma cnuw_cpms_trans (h) (n) (G) (L):
  47       ∀T1. ⦃G,L⦄ ⊢ ➡𝐍𝐖*[h] T1 →
  48       ∀T2. ⦃G,L⦄ ⊢ T1 ➡*[n,h] T2 → ⦃G,L⦄ ⊢ ➡𝐍𝐖*[h] T2.
  49 #h #n1 #G #L #T1 #HT1 #T2 #HT12 #n2 #T3 #HT23
  50 /4 width=5 by cpms_trans, tweq_canc_sn/
  51 qed-.