matita/matita/contribs/lambdadelta/basic_2/rt_computation/cnuw_tdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/cpr_tdeq.ma".
  16 include "basic_2/rt_computation/cnuw_simple.ma".
  17 include "basic_2/rt_computation/cnuw_drops.ma".
  18 include "basic_2/rt_computation/cnuw_cnuw.ma".
  19
  20 (* NORMAL TERMS FOR T-UNUNBOUND WHD RT-TRANSITION ***************************)
  21
  22 (* Properties with context-free sort-irrelevant equivalence for terms *******)
  23
  24 lemma cnuw_dec_tdeq (h) (G) (L):
  25       ∀T1. ∨∨ ⦃G,L⦄ ⊢ ➡𝐍𝐖*[h] T1
  26             | ∃∃n,T2. ⦃G,L⦄ ⊢ T1 ➡[n,h] T2 & (T1 ≛ T2 → ⊥).
  27 #h #G #L #T1 elim T1 -T1 *
  28 [ #s /3 width=5 by cnuw_sort, or_introl/
  29 | #i elim (drops_F_uni L i)
  30   [ /3 width=7 by cnuw_atom_drops, or_introl/
  31   | * * [ #I | * #V ] #K #HLK
  32     [ /3 width=8 by cnuw_unit_drops, or_introl/
  33     | elim (lifts_total V 𝐔❴↑i❵) #W #HVW
  34       @or_intror @(ex2_2_intro … W) [1,2: /2 width=7 by cpm_delta_drops/ ] #H
  35       lapply (tdeq_inv_lref1 … H) -H #H destruct
  36       /2 width=5 by lifts_inv_lref2_uni_lt/
  37     | elim (lifts_total V 𝐔❴↑i❵) #W #HVW
  38       @or_intror @(ex2_2_intro … W) [1,2: /2 width=7 by cpm_ell_drops/ ] #H
  39       lapply (tdeq_inv_lref1 … H) -H #H destruct
  40       /2 width=5 by lifts_inv_lref2_uni_lt/
  41     ]
  42   ]
  43 | #l /3 width=5 by cnuw_gref, or_introl/
  44 | #p * [ cases p ] #V1 #T1 #_ #_
  45   [ elim (cpr_subst h G (L.ⓓV1) T1 0 L V1) [| /2 width=1 by drops_refl/ ] #T2 #X2 #HT12 #HXT2
  46     elim (tdeq_dec T1 T2) [ -HT12 #HT12 | #HnT12 ]
  47     [ elim (tdeq_inv_lifts_dx … HT12 … HXT2) -T2 #X1 #HXT1 #_ -X2
  48       @or_intror @(ex2_2_intro … X1) [1,2: /2 width=4 by cpm_zeta/ ] #H
  49       /2 width=7 by tdeq_lifts_inv_pair_sn/
  50     | @or_intror @(ex2_2_intro … (+ⓓV1.T2)) [1,2: /2 width=2 by cpm_bind/ ] #H
  51       elim (tdeq_inv_pair … H) -H /2 width=1 by/
  52     ]
  53   | /3 width=5 by cnuw_abbr_neg, or_introl/
  54   | /3 width=5 by cnuw_abst, or_introl/
  55   ]
  56 | * #V1 #T1 #_ #IH
  57   [ elim (simple_dec_ex T1) [ #HT1 | * #p * #W1 #U1 #H destruct ]
  58     [ elim IH -IH
  59       [ /3 width=6 by cnuw_appl_simple, or_introl/
  60       | * #n #T2 #HT12 #HnT12
  61         @or_intror @(ex2_2_intro … n (ⓐV1.T2)) [ /2 width=1 by cpm_appl/ ] #H
  62         elim (tdeq_inv_pair … H) -H #_ #_ /2 width=1 by/
  63       ]
  64     | elim (lifts_total V1 𝐔❴1❵) #X1 #HVX1
  65       @or_intror @(ex2_2_intro … (ⓓ{p}W1.ⓐX1.U1)) [1,2: /2 width=3 by cpm_theta/ ] #H
  66       elim (tdeq_inv_pair … H) -H #H destruct
  67     | @or_intror @(ex2_2_intro … (ⓓ{p}ⓝW1.V1.U1)) [1,2: /2 width=2 by cpm_beta/ ] #H
  68       elim (tdeq_inv_pair … H) -H #H destruct
  69     ]
  70   | @or_intror @(ex2_2_intro … T1) [1,2: /2 width=2 by cpm_eps/ ] #H
  71     /2 width=4 by tdeq_inv_pair_xy_y/
  72   ]
  73 ]
  74 qed-.