matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpms.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/lib/ltc.ma".
  16 include "basic_2/notation/relations/predstar_6.ma".
  17 include "basic_2/notation/relations/predstar_5.ma".
  18 include "basic_2/rt_transition/cpm.ma".
  19
  20 (* T-BOUND CONTEXT-SENSITIVE PARALLEL RT-COMPUTATION FOR TERMS **************)
  21
  22 (* Basic_2A1: uses: scpds *)
  23 definition cpms (h) (G) (L): relation3 nat term term ≝
  24                              ltc … plus … (cpm h G L).
  25
  26 interpretation
  27    "t-bound context-sensitive parallel rt-computarion (term)"
  28    'PRedStar n h G L T1 T2 = (cpms h G L n T1 T2).
  29
  30 interpretation
  31    "context-sensitive parallel r-computation (term)"
  32    'PRedStar h G L T1 T2 = (cpms h G L O T1 T2).
  33
  34 (* Basic eliminators ********************************************************)
  35
  36 lemma cpms_ind_sn (h) (G) (L) (T2) (Q:relation2 …):
  37                   Q 0 T2 →
  38                   (∀n1,n2,T1,T. ⦃G, L⦄ ⊢ T1 ➡[n1, h] T → ⦃G, L⦄ ⊢ T ➡*[n2, h] T2 → Q n2 T → Q (n1+n2) T1) →
  39                   ∀n,T1. ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2 → Q n T1.
  40 #h #G #L #T2 #Q @ltc_ind_sn_refl //
  41 qed-.
  42
  43 lemma cpms_ind_dx (h) (G) (L) (T1) (Q:relation2 …):
  44                   Q 0 T1 →
  45                   (∀n1,n2,T,T2. ⦃G, L⦄ ⊢ T1 ➡*[n1, h] T → Q n1 T → ⦃G, L⦄ ⊢ T ➡[n2, h] T2 → Q (n1+n2) T2) →
  46                   ∀n,T2. ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2 → Q n T2.
  47 #h #G #L #T1 #Q @ltc_ind_dx_refl //
  48 qed-.
  49
  50 (* Basic inversion lemmas ***************************************************)
  51
  52 lemma cpms_inv_sort1 (n) (h) (G) (L): ∀X2,s. ⦃G, L⦄ ⊢ ⋆s ➡*[n, h] X2 → X2 = ⋆(((next h)^n) s).
  53 #n #h #G #L #X2 #s #H @(cpms_ind_dx … H) -X2 //
  54 #n1 #n2 #X #X2 #_ #IH #HX2 destruct
  55 elim (cpm_inv_sort1 … HX2) -HX2 * // #H1 #H2 destruct
  56 /2 width=3 by refl, trans_eq/
  57 qed-.
  58
  59 (* Basic properties *********************************************************)
  60
  61 (* Basic_1: includes: pr1_pr0 *)
  62 (* Basic_1: uses: pr3_pr2 *)
  63 (* Basic_2A1: includes: cpr_cprs *)
  64 lemma cpm_cpms (h) (G) (L): ∀n,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 → ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2.
  65 /2 width=1 by ltc_rc/ qed.
  66
  67 lemma cpms_step_sn (h) (G) (L): ∀n1,T1,T. ⦃G, L⦄ ⊢ T1 ➡[n1, h] T →
  68                                 ∀n2,T2. ⦃G, L⦄ ⊢ T ➡*[n2, h] T2 → ⦃G, L⦄ ⊢ T1 ➡*[n1+n2, h] T2.
  69 /2 width=3 by ltc_sn/ qed-.
  70
  71 lemma cpms_step_dx (h) (G) (L): ∀n1,T1,T. ⦃G, L⦄ ⊢ T1 ➡*[n1, h] T →
  72                                 ∀n2,T2. ⦃G, L⦄ ⊢ T ➡[n2, h] T2 → ⦃G, L⦄ ⊢ T1 ➡*[n1+n2, h] T2.
  73 /2 width=3 by ltc_dx/ qed-.
  74
  75 (* Basic_2A1: uses: cprs_bind_dx *)
  76 lemma cpms_bind_dx (n) (h) (G) (L):
  77                    ∀V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 →
  78                    ∀I,T1,T2. ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡*[n, h] T2 →
  79                    ∀p. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ➡*[n, h] ⓑ{p,I}V2.T2.
  80 #n #h #G #L #V1 #V2 #HV12 #I #T1 #T2 #H #a @(cpms_ind_sn … H) -T1
  81 /3 width=3 by cpms_step_sn, cpm_cpms, cpm_bind/ qed.
  82
  83 lemma cpms_appl_dx (n) (h) (G) (L):
  84                    ∀V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 →
  85                    ∀T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2 →
  86                    ⦃G, L⦄ ⊢ ⓐV1.T1 ➡*[n, h] ⓐV2.T2.
  87 #n #h #G #L #V1 #V2 #HV12 #T1 #T2 #H @(cpms_ind_sn … H) -T1
  88 /3 width=3 by cpms_step_sn, cpm_cpms, cpm_appl/
  89 qed.
  90
  91 (* Basic_2A1: uses: cprs_zeta *)
  92 lemma cpms_zeta (n) (h) (G) (L):
  93                 ∀T2,T. ⬆*[1] T2 ≘ T →
  94                 ∀V,T1. ⦃G, L.ⓓV⦄ ⊢ T1 ➡*[n, h] T → ⦃G, L⦄ ⊢ +ⓓV.T1 ➡*[n, h] T2.
  95 #n #h #G #L #T2 #T #HT2 #V #T1 #H @(cpms_ind_sn … H) -T1
  96 /3 width=3 by cpms_step_sn, cpm_cpms, cpm_bind, cpm_zeta/
  97 qed.
  98
  99 (* Basic_2A1: uses: cprs_eps *)
 100 lemma cpms_eps (n) (h) (G) (L):
 101                ∀T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2 →
 102                ∀V. ⦃G, L⦄ ⊢ ⓝV.T1 ➡*[n, h] T2.
 103 #n #h #G #L #T1 #T2 #H @(cpms_ind_sn … H) -T1
 104 /3 width=3 by cpms_step_sn, cpm_cpms, cpm_eps/
 105 qed.
 106
 107 lemma cpms_ee (n) (h) (G) (L):
 108               ∀U1,U2. ⦃G, L⦄ ⊢ U1 ➡*[n, h] U2 →
 109               ∀T. ⦃G, L⦄ ⊢ ⓝU1.T ➡*[↑n, h] U2.
 110 #n #h #G #L #U1 #U2 #H @(cpms_ind_sn … H) -U1 -n
 111 [ /3 width=1 by cpm_cpms, cpm_ee/
 112 | #n1 #n2 #U1 #U #HU1 #HU2 #_ #T >plus_S1
 113   /3 width=3 by cpms_step_sn, cpm_ee/
 114 ]
 115 qed.
 116
 117 (* Basic_2A1: uses: cprs_beta_dx *)
 118 lemma cpms_beta_dx (n) (h) (G) (L):
 119                    ∀V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 →
 120                    ∀W1,W2. ⦃G, L⦄ ⊢ W1 ➡[h] W2 →
 121                    ∀T1,T2. ⦃G, L.ⓛW1⦄ ⊢ T1 ➡*[n, h] T2 →
 122                    ∀p. ⦃G, L⦄ ⊢ ⓐV1.ⓛ{p}W1.T1 ➡*[n, h] ⓓ{p}ⓝW2.V2.T2.
 123 #n #h #G #L #V1 #V2 #HV12 #W1 #W2 #HW12 #T1 #T2 #H @(cpms_ind_dx … H) -T2
 124 /4 width=7 by cpms_step_dx, cpm_cpms, cpms_bind_dx, cpms_appl_dx, cpm_beta/
 125 qed.
 126
 127 (* Basic_2A1: uses: cprs_theta_dx *)
 128 lemma cpms_theta_dx (n) (h) (G) (L):
 129                     ∀V1,V. ⦃G, L⦄ ⊢ V1 ➡[h] V →
 130                     ∀V2. ⬆*[1] V ≘ V2 →
 131                     ∀W1,W2. ⦃G, L⦄ ⊢ W1 ➡[h] W2 →
 132                     ∀T1,T2. ⦃G, L.ⓓW1⦄ ⊢ T1 ➡*[n, h] T2 →
 133                     ∀p. ⦃G, L⦄ ⊢ ⓐV1.ⓓ{p}W1.T1 ➡*[n, h] ⓓ{p}W2.ⓐV2.T2.
 134 #n #h #G #L #V1 #V #HV1 #V2 #HV2 #W1 #W2 #HW12 #T1 #T2 #H @(cpms_ind_dx … H) -T2
 135 /4 width=9 by cpms_step_dx, cpm_cpms, cpms_bind_dx, cpms_appl_dx, cpm_theta/
 136 qed.
 137
 138 (* Basic properties with r-transition ***************************************)
 139
 140 (* Basic_1: was: pr3_refl *)
 141 lemma cprs_refl: ∀h,G,L. reflexive … (cpms h G L 0).
 142 /2 width=1 by cpm_cpms/ qed.
 143
 144 (* Basic_2A1: removed theorems 5:
 145               sta_cprs_scpds lstas_scpds scpds_strap1 scpds_fwd_cprs
 146               scpds_inv_lstas_eq
 147 *)