matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpms.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/lib/ltc.ma".
  16 include "basic_2/notation/relations/predstar_6.ma".
  17 include "basic_2/notation/relations/predstar_5.ma".
  18 include "basic_2/rt_transition/cpm.ma".
  19
  20 (* T-BOUND CONTEXT-SENSITIVE PARALLEL RT-COMPUTATION FOR TERMS **************)
  21
  22 (* Basic_2A1: uses: scpds *)
  23 definition cpms (h) (G) (L): relation3 nat term term ≝
  24                              ltc … plus … (cpm h G L).
  25
  26 interpretation
  27    "t-bound context-sensitive parallel rt-computarion (term)"
  28    'PRedStar n h G L T1 T2 = (cpms h G L n T1 T2).
  29
  30 interpretation
  31    "context-sensitive parallel r-computation (term)"
  32    'PRedStar h G L T1 T2 = (cpms h G L O T1 T2).
  33
  34 (* Basic eliminators ********************************************************)
  35
  36 lemma cpms_ind_sn (h) (G) (L) (T2) (Q:relation2 …):
  37                   Q 0 T2 →
  38                   (∀n1,n2,T1,T. ⦃G, L⦄ ⊢ T1 ➡[n1, h] T → ⦃G, L⦄ ⊢ T ➡*[n2, h] T2 → Q n2 T → Q (n1+n2) T1) →
  39                   ∀n,T1. ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2 → Q n T1.
  40 #h #G #L #T2 #Q @ltc_ind_sn_refl //
  41 qed-.
  42
  43 lemma cpms_ind_dx (h) (G) (L) (T1) (Q:relation2 …):
  44                   Q 0 T1 →
  45                   (∀n1,n2,T,T2. ⦃G, L⦄ ⊢ T1 ➡*[n1, h] T → Q n1 T → ⦃G, L⦄ ⊢ T ➡[n2, h] T2 → Q (n1+n2) T2) →
  46                   ∀n,T2. ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2 → Q n T2.
  47 #h #G #L #T1 #Q @ltc_ind_dx_refl //
  48 qed-.
  49
  50 (* Basic properties *********************************************************)
  51
  52 (* Basic_1: includes: pr1_pr0 *)
  53 (* Basic_1: uses: pr3_pr2 *)
  54 (* Basic_2A1: includes: cpr_cprs *)
  55 lemma cpm_cpms (h) (G) (L): ∀n,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 → ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2.
  56 /2 width=1 by ltc_rc/ qed.
  57
  58 lemma cpms_step_sn (h) (G) (L): ∀n1,T1,T. ⦃G, L⦄ ⊢ T1 ➡[n1, h] T →
  59                                 ∀n2,T2. ⦃G, L⦄ ⊢ T ➡*[n2, h] T2 → ⦃G, L⦄ ⊢ T1 ➡*[n1+n2, h] T2.
  60 /2 width=3 by ltc_sn/ qed-.
  61
  62 lemma cpms_step_dx (h) (G) (L): ∀n1,T1,T. ⦃G, L⦄ ⊢ T1 ➡*[n1, h] T →
  63                                 ∀n2,T2. ⦃G, L⦄ ⊢ T ➡[n2, h] T2 → ⦃G, L⦄ ⊢ T1 ➡*[n1+n2, h] T2.
  64 /2 width=3 by ltc_dx/ qed-.
  65
  66 (* Basic_2A1: uses: cprs_bind_dx *)
  67 lemma cpms_bind_dx (n) (h) (G) (L):
  68                    ∀V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 →
  69                    ∀I,T1,T2. ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡*[n, h] T2 →
  70                    ∀p. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ➡*[n, h] ⓑ{p,I}V2.T2.
  71 #n #h #G #L #V1 #V2 #HV12 #I #T1 #T2 #H #a @(cpms_ind_sn … H) -T1
  72 /3 width=3 by cpms_step_sn, cpm_cpms, cpm_bind/ qed.
  73
  74 lemma cpms_appl_dx (n) (h) (G) (L):
  75                    ∀V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 →
  76                    ∀T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2 →
  77                    ⦃G, L⦄ ⊢ ⓐV1.T1 ➡*[n, h] ⓐV2.T2.
  78 #n #h #G #L #V1 #V2 #HV12 #T1 #T2 #H @(cpms_ind_sn … H) -T1
  79 /3 width=3 by cpms_step_sn, cpm_cpms, cpm_appl/
  80 qed.
  81
  82 lemma cpms_zeta (n) (h) (G) (L):
  83                 ∀T1,T. ⬆*[1] T ≘ T1 →
  84                 ∀V,T2. ⦃G, L⦄ ⊢ T ➡*[n, h] T2 → ⦃G, L⦄ ⊢ +ⓓV.T1 ➡*[n, h] T2.
  85 #n #h #G #L #T1 #T #HT1 #V #T2 #H @(cpms_ind_dx … H) -T2
  86 /3 width=3 by cpms_step_dx, cpm_cpms, cpm_zeta/
  87 qed.
  88
  89 (* Basic_2A1: uses: cprs_zeta *)
  90 lemma cpms_zeta_dx (n) (h) (G) (L):
  91                    ∀T2,T. ⬆*[1] T2 ≘ T →
  92                    ∀V,T1. ⦃G, L.ⓓV⦄ ⊢ T1 ➡*[n, h] T → ⦃G, L⦄ ⊢ +ⓓV.T1 ➡*[n, h] T2.
  93 #n #h #G #L #T2 #T #HT2 #V #T1 #H @(cpms_ind_sn … H) -T1
  94 /3 width=3 by cpms_step_sn, cpm_cpms, cpm_bind, cpm_zeta/
  95 qed.
  96
  97 (* Basic_2A1: uses: cprs_eps *)
  98 lemma cpms_eps (n) (h) (G) (L):
  99                ∀T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2 →
 100                ∀V. ⦃G, L⦄ ⊢ ⓝV.T1 ➡*[n, h] T2.
 101 #n #h #G #L #T1 #T2 #H @(cpms_ind_sn … H) -T1
 102 /3 width=3 by cpms_step_sn, cpm_cpms, cpm_eps/
 103 qed.
 104
 105 lemma cpms_ee (n) (h) (G) (L):
 106               ∀U1,U2. ⦃G, L⦄ ⊢ U1 ➡*[n, h] U2 →
 107               ∀T. ⦃G, L⦄ ⊢ ⓝU1.T ➡*[↑n, h] U2.
 108 #n #h #G #L #U1 #U2 #H @(cpms_ind_sn … H) -U1 -n
 109 [ /3 width=1 by cpm_cpms, cpm_ee/
 110 | #n1 #n2 #U1 #U #HU1 #HU2 #_ #T >plus_S1
 111   /3 width=3 by cpms_step_sn, cpm_ee/
 112 ]
 113 qed.
 114
 115 (* Basic_2A1: uses: cprs_beta_dx *)
 116 lemma cpms_beta_dx (n) (h) (G) (L):
 117                    ∀V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 →
 118                    ∀W1,W2. ⦃G, L⦄ ⊢ W1 ➡[h] W2 →
 119                    ∀T1,T2. ⦃G, L.ⓛW1⦄ ⊢ T1 ➡*[n, h] T2 →
 120                    ∀p. ⦃G, L⦄ ⊢ ⓐV1.ⓛ{p}W1.T1 ➡*[n, h] ⓓ{p}ⓝW2.V2.T2.
 121 #n #h #G #L #V1 #V2 #HV12 #W1 #W2 #HW12 #T1 #T2 #H @(cpms_ind_dx … H) -T2
 122 /4 width=7 by cpms_step_dx, cpm_cpms, cpms_bind_dx, cpms_appl_dx, cpm_beta/
 123 qed.
 124
 125 (* Basic_2A1: uses: cprs_theta_dx *)
 126 lemma cpms_theta_dx (n) (h) (G) (L):
 127                     ∀V1,V. ⦃G, L⦄ ⊢ V1 ➡[h] V →
 128                     ∀V2. ⬆*[1] V ≘ V2 →
 129                     ∀W1,W2. ⦃G, L⦄ ⊢ W1 ➡[h] W2 →
 130                     ∀T1,T2. ⦃G, L.ⓓW1⦄ ⊢ T1 ➡*[n, h] T2 →
 131                     ∀p. ⦃G, L⦄ ⊢ ⓐV1.ⓓ{p}W1.T1 ➡*[n, h] ⓓ{p}W2.ⓐV2.T2.
 132 #n #h #G #L #V1 #V #HV1 #V2 #HV2 #W1 #W2 #HW12 #T1 #T2 #H @(cpms_ind_dx … H) -T2
 133 /4 width=9 by cpms_step_dx, cpm_cpms, cpms_bind_dx, cpms_appl_dx, cpm_theta/
 134 qed.
 135
 136 (* Basic properties with r-transition ***************************************)
 137
 138 (* Basic_1: was: pr3_refl *)
 139 lemma cprs_refl: ∀h,G,L. reflexive … (cpms h G L 0).
 140 /2 width=1 by cpm_cpms/ qed.
 141
 142 (* Advanced properties ******************************************************)
 143
 144 lemma cpms_sort (h) (G) (L) (n):
 145                 ∀s. ⦃G,L⦄ ⊢ ⋆s ➡*[n,h] ⋆((next h)^n s).
 146 #h #G #L #n elim n -n [ // ]
 147 #n #IH #s <plus_SO
 148 /3 width=3 by cpms_step_dx, cpm_sort/
 149 qed.
 150
 151 (* Basic inversion lemmas ***************************************************)
 152
 153 lemma cpms_inv_sort1 (n) (h) (G) (L): ∀X2,s. ⦃G, L⦄ ⊢ ⋆s ➡*[n, h] X2 → X2 = ⋆(((next h)^n) s).
 154 #n #h #G #L #X2 #s #H @(cpms_ind_dx … H) -X2 //
 155 #n1 #n2 #X #X2 #_ #IH #HX2 destruct
 156 elim (cpm_inv_sort1 … HX2) -HX2 #H #_ destruct //
 157 qed-.
 158
 159 lemma cpms_inv_cast1 (h) (n) (G) (L):
 160       ∀W1,T1,X2. ⦃G, L⦄ ⊢ ⓝW1.T1 ➡*[n,h] X2 →
 161       ∨∨ ∃∃W2,T2. ⦃G, L⦄ ⊢ W1 ➡*[n,h] W2 & ⦃G, L⦄ ⊢ T1 ➡*[n,h] T2 & X2 = ⓝW2.T2
 162        | ⦃G, L⦄ ⊢ T1 ➡*[n,h] X2
 163        | ∃∃m. ⦃G, L⦄ ⊢ W1 ➡*[m,h] X2 & n = ↑m.
 164 #h #n #G #L #W1 #T1 #X2 #H @(cpms_ind_dx … H) -n -X2
 165 [ /3 width=5 by or3_intro0, ex3_2_intro/
 166 | #n1 #n2 #X #X2 #_ * [ * || * ]
 167   [ #W #T #HW1 #HT1 #H #HX2 destruct
 168     elim (cpm_inv_cast1 … HX2) -HX2 [ * || * ]
 169     [ #W2 #T2 #HW2 #HT2 #H destruct
 170       /4 width=5 by cpms_step_dx, ex3_2_intro, or3_intro0/
 171     | #HX2 /3 width=3 by cpms_step_dx, or3_intro1/
 172     | #m #HX2 #H destruct <plus_n_Sm
 173       /4 width=3 by cpms_step_dx, ex2_intro, or3_intro2/
 174     ]
 175   | #HX #HX2 /3 width=3 by cpms_step_dx, or3_intro1/
 176   | #m #HX #H #HX2 destruct
 177     /4 width=3 by cpms_step_dx, ex2_intro, or3_intro2/
 178   ]
 179 ]
 180 qed-.
 181
 182 (* Basic_2A1: removed theorems 5:
 183               sta_cprs_scpds lstas_scpds scpds_strap1 scpds_fwd_cprs
 184               scpds_inv_lstas_eq
 185 *)