matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpms.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/lib/ltc.ma".
  16 include "basic_2/notation/relations/predstar_6.ma".
  17 include "basic_2/notation/relations/predstar_5.ma".
  18 include "basic_2/rt_transition/cpm.ma".
  19
  20 (* T-BOUND CONTEXT-SENSITIVE PARALLEL RT-COMPUTATION FOR TERMS **************)
  21
  22 (* Basic_2A1: uses: scpds *)
  23 definition cpms (h) (G) (L): relation3 nat term term ≝
  24                              ltc … plus … (cpm h G L).
  25
  26 interpretation
  27    "t-bound context-sensitive parallel rt-computarion (term)"
  28    'PRedStar n h G L T1 T2 = (cpms h G L n T1 T2).
  29
  30 interpretation
  31    "context-sensitive parallel r-computation (term)"
  32    'PRedStar h G L T1 T2 = (cpms h G L O T1 T2).
  33
  34 (* Basic eliminators ********************************************************)
  35
  36 lemma cpms_ind_sn (h) (G) (L) (T2) (Q:relation2 …):
  37                   Q 0 T2 →
  38                   (∀n1,n2,T1,T. ⦃G, L⦄ ⊢ T1 ➡[n1, h] T → ⦃G, L⦄ ⊢ T ➡*[n2, h] T2 → Q n2 T → Q (n1+n2) T1) →
  39                   ∀n,T1. ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2 → Q n T1.
  40 #h #G #L #T2 #R @ltc_ind_sn_refl //
  41 qed-.
  42
  43 lemma cpms_ind_dx (h) (G) (L) (T1) (Q:relation2 …):
  44                   Q 0 T1 →
  45                   (∀n1,n2,T,T2. ⦃G, L⦄ ⊢ T1 ➡*[n1, h] T → Q n1 T → ⦃G, L⦄ ⊢ T ➡[n2, h] T2 → Q (n1+n2) T2) →
  46                   ∀n,T2. ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2 → Q n T2.
  47 #h #G #L #T1 #R @ltc_ind_dx_refl //
  48 qed-.
  49
  50 (* Basic properties *********************************************************)
  51
  52 (* Basic_1: includes: pr1_pr0 *)
  53 (* Basic_1: uses: pr3_pr2 *)
  54 (* Basic_2A1: includes: cpr_cprs *)
  55 lemma cpm_cpms (h) (G) (L): ∀n,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 → ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2.
  56 /2 width=1 by ltc_rc/ qed.
  57
  58 lemma cpms_step_sn (h) (G) (L): ∀n1,T1,T. ⦃G, L⦄ ⊢ T1 ➡[n1, h] T →
  59                                 ∀n2,T2. ⦃G, L⦄ ⊢ T ➡*[n2, h] T2 → ⦃G, L⦄ ⊢ T1 ➡*[n1+n2, h] T2.
  60 /2 width=3 by ltc_sn/ qed-.
  61
  62 lemma cpms_step_dx (h) (G) (L): ∀n1,T1,T. ⦃G, L⦄ ⊢ T1 ➡*[n1, h] T →
  63                                 ∀n2,T2. ⦃G, L⦄ ⊢ T ➡[n2, h] T2 → ⦃G, L⦄ ⊢ T1 ➡*[n1+n2, h] T2.
  64 /2 width=3 by ltc_dx/ qed-.
  65
  66 (* Basic_2A1: uses: cprs_bind_dx *)
  67 lemma cpms_bind_dx (n) (h) (G) (L):
  68                    ∀V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 →
  69                    ∀I,T1,T2. ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡*[n, h] T2 →
  70                    ∀p. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ➡*[n, h] ⓑ{p,I}V2.T2.
  71 #n #h #G #L #V1 #V2 #HV12 #I #T1 #T2 #H #a @(cpms_ind_sn … H) -T1
  72 /3 width=3 by cpms_step_sn, cpm_cpms, cpm_bind/ qed.
  73
  74 lemma cpms_appl_dx (n) (h) (G) (L):
  75                    ∀V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 →
  76                    ∀T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2 →
  77                    ⦃G, L⦄ ⊢ ⓐV1.T1 ➡*[n, h] ⓐV2.T2.
  78 #n #h #G #L #V1 #V2 #HV12 #T1 #T2 #H @(cpms_ind_sn … H) -T1
  79 /3 width=3 by cpms_step_sn, cpm_cpms, cpm_appl/
  80 qed.
  81
  82 (* Basic_2A1: uses: cprs_zeta *)
  83 lemma cpms_zeta (n) (h) (G) (L):
  84                 ∀T2,T. ⬆*[1] T2 ≘ T →
  85                 ∀V,T1. ⦃G, L.ⓓV⦄ ⊢ T1 ➡*[n, h] T → ⦃G, L⦄ ⊢ +ⓓV.T1 ➡*[n, h] T2.
  86 #n #h #G #L #T2 #T #HT2 #V #T1 #H @(cpms_ind_sn … H) -T1
  87 /3 width=3 by cpms_step_sn, cpm_cpms, cpm_bind, cpm_zeta/
  88 qed.
  89
  90 (* Basic_2A1: uses: cprs_eps *)
  91 lemma cpms_eps (n) (h) (G) (L):
  92                ∀T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2 →
  93                ∀V. ⦃G, L⦄ ⊢ ⓝV.T1 ➡*[n, h] T2.
  94 #n #h #G #L #T1 #T2 #H @(cpms_ind_sn … H) -T1
  95 /3 width=3 by cpms_step_sn, cpm_cpms, cpm_eps/
  96 qed.
  97
  98 (* Basic_2A1: uses: cprs_beta_dx *)
  99 lemma cpms_beta_dx (n) (h) (G) (L):
 100                    ∀V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 →
 101                    ∀W1,W2. ⦃G, L⦄ ⊢ W1 ➡[h] W2 →
 102                    ∀T1,T2. ⦃G, L.ⓛW1⦄ ⊢ T1 ➡*[n, h] T2 →
 103                    ∀p. ⦃G, L⦄ ⊢ ⓐV1.ⓛ{p}W1.T1 ➡*[n, h] ⓓ{p}ⓝW2.V2.T2.
 104 #n #h #G #L #V1 #V2 #HV12 #W1 #W2 #HW12 #T1 #T2 #H @(cpms_ind_dx … H) -T2
 105 /4 width=7 by cpms_step_dx, cpm_cpms, cpms_bind_dx, cpms_appl_dx, cpm_beta/
 106 qed.
 107
 108 (* Basic_2A1: uses: cprs_theta_dx *)
 109 lemma cpms_theta_dx (n) (h) (G) (L):
 110                     ∀V1,V. ⦃G, L⦄ ⊢ V1 ➡[h] V →
 111                     ∀V2. ⬆*[1] V ≘ V2 →
 112                     ∀W1,W2. ⦃G, L⦄ ⊢ W1 ➡[h] W2 →
 113                     ∀T1,T2. ⦃G, L.ⓓW1⦄ ⊢ T1 ➡*[n, h] T2 →
 114                     ∀p. ⦃G, L⦄ ⊢ ⓐV1.ⓓ{p}W1.T1 ➡*[n, h] ⓓ{p}W2.ⓐV2.T2.
 115 #n #h #G #L #V1 #V #HV1 #V2 #HV2 #W1 #W2 #HW12 #T1 #T2 #H @(cpms_ind_dx … H) -T2
 116 /4 width=9 by cpms_step_dx, cpm_cpms, cpms_bind_dx, cpms_appl_dx, cpm_theta/
 117 qed.
 118
 119 (* Basic inversion lemmas ***************************************************)
 120
 121 lemma cpms_inv_sort1 (n) (h) (G) (L): ∀X2,s. ⦃G, L⦄ ⊢ ⋆s ➡*[n, h] X2 → X2 = ⋆(((next h)^n) s).
 122 #n #h #G #L #X2 #s #H @(cpms_ind_dx … H) -X2 //
 123 #n1 #n2 #X #X2 #_ #IH #HX2 destruct
 124 elim (cpm_inv_sort1 … HX2) -HX2 * // #H1 #H2 destruct
 125 /2 width=3 by refl, trans_eq/
 126 qed-.
 127
 128 (* Basic properties with r-transition ***************************************)
 129
 130 (* Basic_1: was: pr3_refl *)
 131 lemma cprs_refl: ∀h,G,L. reflexive … (cpms h G L 0).
 132 /2 width=1 by cpm_cpms/ qed.
 133
 134 (* Basic_2A1: removed theorems 4:
 135               sta_cprs_scpds lstas_scpds scpds_strap1 scpds_fwd_cprs
 136 *)