matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpms.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/lib/ltc.ma".
  16 include "basic_2/notation/relations/predstar_6.ma".
  17 include "basic_2/notation/relations/predstar_5.ma".
  18 include "basic_2/rt_transition/cpm.ma".
  19
  20 (* T-BOUND CONTEXT-SENSITIVE PARALLEL RT-COMPUTATION FOR TERMS **************)
  21
  22 (* Basic_2A1: uses: scpds *)
  23 definition cpms (h) (G) (L): relation3 nat term term ≝
  24                              ltc … plus … (cpm h G L).
  25
  26 interpretation
  27    "t-bound context-sensitive parallel rt-computarion (term)"
  28    'PRedStar n h G L T1 T2 = (cpms h G L n T1 T2).
  29
  30 interpretation
  31    "context-sensitive parallel r-computation (term)"
  32    'PRedStar h G L T1 T2 = (cpms h G L O T1 T2).
  33
  34 (* Basic properties *********************************************************)
  35
  36 lemma cpm_cpms (h) (G) (L): ∀n,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 → ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2.
  37 /2 width=1 by ltc_rc/ qed.
  38
  39 lemma cpms_step_sn (h) (G) (L): ∀n1,T1,T. ⦃G, L⦄ ⊢ T1 ➡[n1, h] T →
  40                                 ∀n2,T2. ⦃G, L⦄ ⊢ T ➡*[n2, h] T2 → ⦃G, L⦄ ⊢ T1 ➡*[n1+n2, h] T2.
  41 /2 width=3 by ltc_sn/ qed-.
  42
  43 lemma cpms_step_dx (h) (G) (L): ∀n1,T1,T. ⦃G, L⦄ ⊢ T1 ➡*[n1, h] T →
  44                                 ∀n2,T2. ⦃G, L⦄ ⊢ T ➡[n2, h] T2 → ⦃G, L⦄ ⊢ T1 ➡*[n1+n2, h] T2.
  45 /2 width=3 by ltc_dx/ qed-.
  46
  47 (* Basic properties with r-transition ***************************************)
  48
  49 lemma cprs_refl: ∀h,G,L. reflexive … (cpms h G L 0).
  50 /2 width=1 by cpm_cpms/ qed.
  51
  52 (* Basic eliminators ********************************************************)
  53
  54 lemma cpms_ind_sn (h) (G) (L) (T2) (Q:relation2 …):
  55                   Q 0 T2 →
  56                   (∀n1,n2,T1,T. ⦃G, L⦄ ⊢ T1 ➡[n1, h] T → ⦃G, L⦄ ⊢ T ➡*[n2, h] T2 → Q n2 T → Q (n1+n2) T1) →
  57                   ∀n,T1. ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2 → Q n T1.
  58 #h #G #L #T2 #R @ltc_ind_sn_refl //
  59 qed-.
  60
  61 lemma cpms_ind_dx (h) (G) (L) (T1) (Q:relation2 …):
  62                   Q 0 T1 →
  63                   (∀n1,n2,T,T2. ⦃G, L⦄ ⊢ T1 ➡*[n1, h] T → Q n1 T → ⦃G, L⦄ ⊢ T ➡[n2, h] T2 → Q (n1+n2) T2) →
  64                   ∀n,T2. ⦃G, L⦄ ⊢ T1 ➡*[n, h] T2 → Q n T2.
  65 #h #G #L #T1 #R @ltc_ind_dx_refl //
  66 qed-.
  67
  68 (* Basic_2A1: removed theorems 4:
  69               sta_cprs_scpds lstas_scpds scpds_strap1 scpds_fwd_cprs
  70 *)