matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpms_fpbg.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/fpbg_fqup.ma".
  16 include "basic_2/rt_computation/fpbg_cpxs.ma".
  17 include "basic_2/rt_computation/cpms_fpbs.ma".
  18
  19 (* T-BOUND CONTEXT-SENSITIVE PARALLEL RT-COMPUTATION FOR TERMS **************)
  20
  21 (* Forward lemmas with proper parallel rst-computation for closures *********)
  22
  23 lemma cpms_tneqx_fwd_fpbg (h) (n):
  24       ∀G,L,T1,T2. ❪G,L❫ ⊢ T1 ➡*[h,n] T2 →
  25       (T1 ≛ T2 → ⊥) → ❪G,L,T1❫ > ❪G,L,T2❫.
  26 /3 width=3 by cpms_fwd_cpxs, cpxs_tneqx_fpbg/ qed-.
  27
  28 lemma fpbg_cpms_trans (h) (n):
  29       ∀G1,G2,L1,L2,T1,T. ❪G1,L1,T1❫ > ❪G2,L2,T❫ →
  30       ∀T2. ❪G2,L2❫ ⊢ T ➡*[h,n] T2 → ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  31 /3 width=5 by fpbg_fpbs_trans, cpms_fwd_fpbs/ qed-.
  32
  33 lemma cpms_fpbg_trans (h) (n):
  34       ∀G1,L1,T1,T. ❪G1,L1❫ ⊢ T1 ➡*[h,n] T →
  35       ∀G2,L2,T2. ❪G1,L1,T❫ > ❪G2,L2,T2❫ → ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  36 /3 width=5 by fpbs_fpbg_trans, cpms_fwd_fpbs/ qed-.
  37
  38 lemma fqup_cpms_fwd_fpbg (h):
  39       ∀G1,G2,L1,L2,T1,T. ❪G1,L1,T1❫ ⬂+ ❪G2,L2,T❫ →
  40       ∀n,T2. ❪G2,L2❫ ⊢ T ➡*[h,n] T2 → ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  41 /3 width=5 by cpms_fwd_fpbs, fqup_fpbg, fpbg_fpbs_trans/ qed-.
  42
  43 lemma cpm_tneqx_cpm_cpms_teqx_sym_fwd_fpbg (h) (G) (L) (T1):
  44       ∀n1,T. ❪G,L❫ ⊢ T1 ➡[h,n1] T → (T1 ≛ T → ⊥) →
  45       ∀n2,T2. ❪G,L❫⊢ T ➡*[h,n2] T2 → T1 ≛ T2 → ❪G,L,T1❫ > ❪G,L,T1❫.
  46 #h #G #L #T1 #n1 #T #H1T1 #H2T1 #n2 #T2 #H1T2 #H2T12
  47 /4 width=7 by cpms_fwd_fpbs, cpm_fpb, fpbs_teqx_trans, teqx_sym, ex2_3_intro/
  48 qed-.