matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpms_fpbg.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/cpm_fpbc.ma".
  16 include "basic_2/rt_computation/fpbg_fqus.ma".
  17 include "basic_2/rt_computation/fpbg_cpxs.ma".
  18 include "basic_2/rt_computation/cpms_fpbs.ma".
  19
  20 (* T-BOUND CONTEXT-SENSITIVE PARALLEL RT-COMPUTATION FOR TERMS **************)
  21
  22 (* Forward lemmas with proper parallel rst-computation for closures *********)
  23
  24 lemma cpms_tneqx_fwd_fpbg (h) (n):
  25       ∀G,L,T1,T2. ❪G,L❫ ⊢ T1 ➡*[h,n] T2 →
  26       (T1 ≅ T2 → ⊥) → ❪G,L,T1❫ > ❪G,L,T2❫.
  27 /3 width=3 by cpms_fwd_cpxs, cpxs_tneqx_fpbg/ qed-.
  28
  29 lemma fpbg_cpms_trans (h) (n):
  30       ∀G1,G2,L1,L2,T1,T. ❪G1,L1,T1❫ > ❪G2,L2,T❫ →
  31       ∀T2. ❪G2,L2❫ ⊢ T ➡*[h,n] T2 → ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  32 /3 width=5 by fpbg_fpbs_trans, cpms_fwd_fpbs/ qed-.
  33
  34 lemma cpms_fpbg_trans (h) (n):
  35       ∀G1,L1,T1,T. ❪G1,L1❫ ⊢ T1 ➡*[h,n] T →
  36       ∀G2,L2,T2. ❪G1,L1,T❫ > ❪G2,L2,T2❫ → ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  37 /3 width=5 by fpbs_fpbg_trans, cpms_fwd_fpbs/ qed-.
  38
  39 lemma fqup_cpms_fwd_fpbg (h):
  40       ∀G1,G2,L1,L2,T1,T. ❪G1,L1,T1❫ ⬂+ ❪G2,L2,T❫ →
  41       ∀n,T2. ❪G2,L2❫ ⊢ T ➡*[h,n] T2 → ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  42 /3 width=5 by cpms_fwd_fpbs, fqup_fpbg, fpbg_fpbs_trans/ qed-.
  43
  44 lemma cpm_tneqx_cpm_cpms_teqx_sym_fwd_fpbg (h) (G) (L) (T1):
  45       ∀n1,T. ❪G,L❫ ⊢ T1 ➡[h,n1] T → (T1 ≅ T → ⊥) →
  46       ∀n2,T2. ❪G,L❫⊢ T ➡*[h,n2] T2 → T1 ≅ T2 → ❪G,L,T1❫ > ❪G,L,T1❫.
  47 #h #G #L #T1 #n1 #T #H1T1 #H2T1 #n2 #T2 #H1T2 #H2T12
  48 /4 width=10 by fpbc_fpbs_fpbg, cpms_fwd_fpbs, fpbs_teqg_trans, cpm_fwd_fpbc, teqx_sym/
  49 qed-.