matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpms_lpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/lpr.ma".
  16 include "basic_2/rt_computation/cpms_cpms.ma".
  17
  18 (* T-BOUND CONTEXT-SENSITIVE PARALLEL RT-COMPUTATION FOR TERMS **************)
  19
  20 (* Properties with parallel rt-transition for full local environments *******)
  21
  22 lemma lpr_cpm_trans (n) (h) (G):
  23                     ∀L2,T1,T2. ❪G,L2❫ ⊢ T1 ➡[n,h] T2 →
  24                     ∀L1. ❪G,L1❫ ⊢ ➡[h] L2 → ❪G,L1❫ ⊢ T1 ➡*[n,h] T2.
  25 #n #h #G #L2 #T1 #T2 #H @(cpm_ind … H) -n -G -L2 -T1 -T2
  26 [ /2 width=3 by/
  27 | /3 width=2 by cpm_cpms/
  28 | #n #G #K2 #V2 #V4 #W4 #_ #IH #HVW4 #L1 #H
  29   elim (lpr_inv_pair_dx … H) -H #K1 #V1 #HK12 #HV12 #H destruct
  30   /4 width=3 by cpms_delta, cpms_step_sn/
  31 | #n #G #K2 #V2 #V4 #W4 #_ #IH #HVW4 #L1 #H
  32   elim (lpr_inv_pair_dx … H) -H #K1 #V1 #HK12 #HV12 #H destruct
  33   /4 width=3 by cpms_ell, cpms_step_sn/
  34 | #n #I2 #G #K2 #T #U #i #_ #IH #HTU #L1 #H
  35   elim (lpr_inv_bind_dx … H) -H #I1 #K1 #HK12 #HI12 #H destruct
  36   /4 width=3 by cpms_lref, cpms_step_sn/
  37 | /4 width=1 by cpms_bind, lpr_bind_refl_dx/
  38 | /3 width=1 by cpms_appl/
  39 | /3 width=1 by cpms_cast/
  40 | /4 width=3 by cpms_zeta, lpr_bind_refl_dx/
  41 | /3 width=1 by cpms_eps/
  42 | /3 width=1 by cpms_ee/
  43 | /4 width=1 by lpr_bind_refl_dx, cpms_beta/
  44 | /4 width=3 by lpr_bind_refl_dx, cpms_theta/
  45 ]
  46 qed-.
  47
  48 lemma lpr_cpms_trans (n) (h) (G):
  49                      ∀L1,L2. ❪G,L1❫ ⊢ ➡[h] L2 →
  50                      ∀T1,T2. ❪G,L2❫ ⊢ T1 ➡*[n,h] T2 → ❪G,L1❫ ⊢ T1 ➡*[n,h] T2.
  51 #n #h #G #L1 #L2 #HL12 #T1 #T2 #H @(cpms_ind_sn … H) -n -T1
  52 /3 width=3 by lpr_cpm_trans, cpms_trans/
  53 qed-.
  54
  55 (* Advanced properties ******************************************************)
  56
  57 (* Basic_2A1: includes cpr_bind2 *)
  58 lemma cpm_bind2 (n) (h) (G) (L):
  59                 ∀V1,V2. ❪G,L❫ ⊢ V1 ➡[h] V2 →
  60                 ∀I,T1,T2. ❪G,L.ⓑ[I]V2❫ ⊢ T1 ➡[n,h] T2 →
  61                 ∀p. ❪G,L❫ ⊢ ⓑ[p,I]V1.T1 ➡*[n,h] ⓑ[p,I]V2.T2.
  62 /4 width=5 by lpr_cpm_trans, cpms_bind_dx, lpr_pair/ qed.
  63
  64 (* Basic_2A1: includes cprs_bind2_dx *)
  65 lemma cpms_bind2_dx (n) (h) (G) (L):
  66                     ∀V1,V2. ❪G,L❫ ⊢ V1 ➡[h] V2 →
  67                     ∀I,T1,T2. ❪G,L.ⓑ[I]V2❫ ⊢ T1 ➡*[n,h] T2 →
  68                     ∀p. ❪G,L❫ ⊢ ⓑ[p,I]V1.T1 ➡*[n,h] ⓑ[p,I]V2.T2.
  69 /4 width=5 by lpr_cpms_trans, cpms_bind_dx, lpr_pair/ qed.