matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpxs_etc.ma

   1
   2 include "basic_2/reduction/lpx_drop.ma".
   3 include "basic_2/computation/cpxs_lift.ma".
   4 include "basic_2/rt_computation/cpxs_cpxs.ma".
   5
   6 (* Properties on sn extended parallel reduction for local environments ******)
   7
   8 lemma cpx_bind2: ∀h,o,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ⬈[h, o] V2 →
   9                  ∀I,T1,T2. ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ⬈[h, o] T2 →
  10                  ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ⬈*[h, o] ⓑ{a,I}V2.T2.
  11 /4 width=5 by lpx_cpx_trans, cpxs_bind_dx, lpx_pair/ qed.
  12
  13 (* Advanced properties ******************************************************)
  14
  15 lemma cpxs_bind2_dx: ∀h,o,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ⬈[h, o] V2 →
  16                      ∀I,T1,T2. ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ⬈*[h, o] T2 →
  17                      ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ⬈*[h, o] ⓑ{a,I}V2.T2.
  18 /4 width=5 by lpx_cpxs_trans, cpxs_bind_dx, lpx_pair/ qed.
  19
  20 (* Properties on supclosure *************************************************)
  21
  22 lemma fqu_cpxs_trans_neq: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
  23                           ∀U2. ⦃G2, L2⦄ ⊢ T2 ⬈*[h, o] U2 → (T2 = U2 → ⊥) →
  24                           ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ⬈*[h, o] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐ ⦃G2, L2, U2⦄.
  25 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  26 [ #I #G #L #V1 #V2 #HV12 #_ elim (lift_total V2 0 1)
  27   #U2 #HVU2 @(ex3_intro … U2)
  28   [1,3: /3 width=7 by fqu_drop, cpxs_delta, drop_pair, drop_drop/
  29   | #H destruct
  30     lapply (lift_inv_lref2_be … HVU2 ? ?) -HVU2 //
  31   ]
  32 | #I #G #L #V1 #T #V2 #HV12 #H @(ex3_intro … (②{I}V2.T))
  33   [1,3: /2 width=4 by fqu_pair_sn, cpxs_pair_sn/
  34   | #H0 destruct /2 width=1 by/
  35   ]
  36 | #a #I #G #L #V #T1 #T2 #HT12 #H @(ex3_intro … (ⓑ{a,I}V.T2))
  37   [1,3: /2 width=4 by fqu_bind_dx, cpxs_bind/
  38   | #H0 destruct /2 width=1 by/
  39   ]
  40 | #I #G #L #V #T1 #T2 #HT12 #H @(ex3_intro … (ⓕ{I}V.T2))
  41   [1,3: /2 width=4 by fqu_flat_dx, cpxs_flat/
  42   | #H0 destruct /2 width=1 by/
  43   ]
  44 | #G #L #K #T1 #U1 #k #HLK #HTU1 #T2 #HT12 #H elim (lift_total T2 0 (k+1))
  45   #U2 #HTU2 @(ex3_intro … U2)
  46   [1,3: /2 width=10 by cpxs_lift, fqu_drop/
  47   | #H0 destruct /3 width=5 by lift_inj/
  48 ]
  49 qed-.
  50
  51 lemma fquq_cpxs_trans_neq: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
  52                            ∀U2. ⦃G2, L2⦄ ⊢ T2 ⬈*[h, o] U2 → (T2 = U2 → ⊥) →
  53                            ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ⬈*[h, o] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐⸮ ⦃G2, L2, U2⦄.
  54 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H12 #U2 #HTU2 #H elim (fquq_inv_gen … H12) -H12
  55 [ #H12 elim (fqu_cpxs_trans_neq … H12 … HTU2 H) -T2
  56   /3 width=4 by fqu_fquq, ex3_intro/
  57 | * #HG #HL #HT destruct /3 width=4 by ex3_intro/
  58 ]
  59 qed-.
  60
  61 lemma fqup_cpxs_trans_neq: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ →
  62                            ∀U2. ⦃G2, L2⦄ ⊢ T2 ⬈*[h, o] U2 → (T2 = U2 → ⊥) →
  63                            ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ⬈*[h, o] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐+ ⦃G2, L2, U2⦄.
  64 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind_dx … H) -G1 -L1 -T1
  65 [ #G1 #L1 #T1 #H12 #U2 #HTU2 #H elim (fqu_cpxs_trans_neq … H12 … HTU2 H) -T2
  66   /3 width=4 by fqu_fqup, ex3_intro/
  67 | #G #G1 #L #L1 #T #T1 #H1 #_ #IH12 #U2 #HTU2 #H elim (IH12 … HTU2 H) -T2
  68   #U1 #HTU1 #H #H12 elim (fqu_cpxs_trans_neq … H1 … HTU1 H) -T1
  69   /3 width=8 by fqup_strap2, ex3_intro/
  70 ]
  71 qed-.
  72
  73 lemma fqus_cpxs_trans_neq: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
  74                            ∀U2. ⦃G2, L2⦄ ⊢ T2 ⬈*[h, o] U2 → (T2 = U2 → ⊥) →
  75                            ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ⬈*[h, o] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐* ⦃G2, L2, U2⦄.
  76 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H12 #U2 #HTU2 #H elim (fqus_inv_gen … H12) -H12
  77 [ #H12 elim (fqup_cpxs_trans_neq … H12 … HTU2 H) -T2
  78   /3 width=4 by fqup_fqus, ex3_intro/
  79 | * #HG #HL #HT destruct /3 width=4 by ex3_intro/
  80 ]
  81 qed-.