matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpxs_lfpx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/cpx_fqus.ma".
  16 include "basic_2/rt_transition/lfpx_fquq.ma".
  17 include "basic_2/rt_computation/cpxs_drops.ma".
  18 include "basic_2/rt_computation/cpxs_cpxs.ma".
  19
  20 (* UNCOUNTED CONTEXT-SENSITIVE PARALLEL RT-COMPUTATION FOR TERMS ************)
  21
  22 (* Properties with uncounted parallel rt-transition on referred entries *****)
  23
  24 lemma lfpx_cpxs_conf: ∀h,G. s_r_confluent1 … (cpxs h G) (lfpx h G).
  25 /3 width=5 by lfpx_cpx_conf, s_r_conf1_LTC1/ qed-.
  26
  27 lemma lfpx_cpx_trans: ∀h,G. s_r_transitive … (cpx h G) (lfpx h G).
  28 #h #G #L2 #T1 #T2 #H @(cpx_ind … H) -G -L2 -T1 -T2 //
  29 [ #G #L2 #s1 #L1 #H elim (lfpx_inv_sort … H) -H * /2 width=1 by cpx_cpxs/
  30 | #I #G #L2 #V #V2 #W2 #_ #IH #HVW2 #Y1 #H
  31   elim (lfpx_inv_zero_pair_dx … H) -H #L1 #V1 #HL1 #HV1 #H destruct
  32   /5 width=3 by lfpx_cpx_conf, cpxs_delta, cpxs_strap2/
  33 | #I2 #G #L2 #V2 #W2 #i #_ #IH #HVW2 #Y1 #H
  34   elim (lfpx_inv_lref_bind_dx … H) -H #I1 #L1 #HL1 #H destruct
  35   /4 width=3 by cpxs_lref, cpxs_strap2/
  36 | #p #I #G #L2 #V #V2 #T #T2 #_ #_ #IHV #IHT #L1 #H
  37   elim (lfpx_inv_bind … H) -H /3 width=1 by cpxs_bind/
  38 | #I #G #L2 #V #V2 #T #T2 #_ #_ #IHV #IHT #L1 #H
  39   elim (lfpx_inv_flat … H) -H /3 width=1 by cpxs_flat/
  40 | #G #L2 #V #T #T2 #T0 #_ #IH #HT02 #L1 #H
  41   elim (lfpx_inv_bind … H) -H /3 width=3 by cpxs_zeta/
  42 | #G #L2 #V #T #T2 #_ #IH #L1 #H
  43   elim (lfpx_inv_flat … H) -H /3 width=1 by cpxs_eps/
  44 | #G #L2 #V #V2 #T #_ #IH #L1 #H
  45   elim (lfpx_inv_flat … H) -H /3 width=1 by cpxs_ee/
  46 | #p #G #L2 #V #V2 #W #W2 #T #T2 #_ #_ #_ #IHV #IHW #IHT #L1 #H
  47   elim (lfpx_inv_flat … H) -H #HV #H
  48   elim (lfpx_inv_bind … H) -H /3 width=1 by cpxs_beta/
  49 | #p #G #L2 #V #V2 #V0 #W #W2 #T #T2 #_ #_ #_ #IHV #IHW #IHT #HV20 #L1 #H
  50   elim (lfpx_inv_flat … H) -H #HV #H
  51   elim (lfpx_inv_bind … H) -H /3 width=3 by cpxs_theta/
  52 ]
  53 qed.
  54
  55 lemma lfpx_cpxs_trans: ∀h,G. s_rs_transitive … (cpx h G) (lfpx h G).
  56 /3 width=6 by lfpx_cpx_conf, lfpx_cpx_trans, s_r_trans_LTC1/
  57 qed-.
  58
  59 (* Advanced properties ******************************************************)
  60
  61 lemma cpx_bind2: ∀h,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 →
  62                  ∀I,T1,T2. ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ⬈[h] T2 →
  63                  ∀p. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ⬈*[h] ⓑ{p,I}V2.T2.
  64 /4 width=5 by lfpx_cpx_trans, cpxs_bind_dx, lfpx_pair_refl/ qed.
  65
  66 lemma cpxs_bind2_dx: ∀h,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 →
  67                      ∀I,T1,T2. ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ⬈*[h] T2 →
  68                      ∀p. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ⬈*[h] ⓑ{p,I}V2.T2.
  69 /4 width=5 by lfpx_cpxs_trans, cpxs_bind_dx, lfpx_pair_refl/ qed.
  70
  71 (* Properties with plus-iterated structural successor for closures **********)
  72
  73 (* Basic_2A1: uses: lpx_fqup_trans *)
  74 lemma lfpx_fqup_trans: ∀h,b,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+[b] ⦃G2, L2, T2⦄ →
  75                        ∀K1. ⦃G1, K1⦄ ⊢ ⬈[h, T1] L1 →
  76                        ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ⬈*[h] T & ⦃G1, K1, T⦄ ⊐+[b] ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ⬈[h, T2] L2.
  77 #h #b #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
  78 [ #G2 #L2 #T2 #H12 #K1 #HKL1 elim (lfpx_fqu_trans … H12 … HKL1) -L1
  79   /3 width=5 by cpx_cpxs, fqu_fqup, ex3_2_intro/
  80 | #G #G2 #L #L2 #T #T2 #_ #H2 #IH1 #K1 #HLK1 elim (IH1 … HLK1) -L1
  81   #L0 #T0 #HT10 #HT0 #HL0 elim (lfpx_fqu_trans … H2 … HL0) -L
  82   #L #T3 #HT3 #HT32 #HL2 elim (fqup_cpx_trans … HT0 … HT3) -T
  83   /3 width=7 by cpxs_strap1, fqup_strap1, ex3_2_intro/
  84 ]
  85 qed-.
  86
  87 (* Properties with star-iterated structural successor for closures **********)
  88
  89 (* Basic_2A1: uses: lpx_fqus_trans *)
  90 lemma lfpx_fqus_trans: ∀h,b,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐*[b] ⦃G2, L2, T2⦄ →
  91                        ∀K1. ⦃G1, K1⦄ ⊢ ⬈[h, T1] L1 →
  92                        ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ⬈*[h] T & ⦃G1, K1, T⦄ ⊐*[b] ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ⬈[h, T2] L2.
  93 #h #b #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #HKL1 elim (fqus_inv_fqup … H) -H
  94 [ #H12 elim (lfpx_fqup_trans … H12 … HKL1) -L1 /3 width=5 by fqup_fqus, ex3_2_intro/
  95 | * #H1 #H2 #H3 destruct /2 width=5 by ex3_2_intro/
  96 ]
  97 qed-.