matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpxs_lfpx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/lfpx_lfpx.ma".
  16 include "basic_2/rt_computation/cpxs_drops.ma".
  17 include "basic_2/rt_computation/cpxs_cpxs.ma".
  18
  19 (* UNCOUNTED CONTEXT-SENSITIVE PARALLEL RT-COMPUTATION FOR TERMS ************)
  20
  21 (* Properties with uncounted parallel rt-transition on referred entries *****)
  22
  23 lemma lfpx_cpxs_conf: ∀h,G. s_r_confluent1 … (cpxs h G) (lfpx h G).
  24 /3 width=5 by lfpx_cpx_conf, s_r_conf1_LTC1/ qed-.
  25
  26 lemma lfpx_cpx_trans: ∀h,G. s_r_transitive … (cpx h G) (lfpx h G).
  27 #h #G #L2 #T1 #T2 #H @(cpx_ind … H) -G -L2 -T1 -T2 //
  28 [ #G #L2 #s1 #L1 #H elim (lfpx_inv_sort … H) -H * /2 width=1 by cpx_cpxs/
  29 | #I #G #L2 #V #V2 #W2 #_ #IH #HVW2 #Y1 #H
  30   elim (lfpx_inv_zero_pair_dx … H) -H #L1 #V1 #HL1 #HV1 #H destruct
  31   /5 width=3 by lfpx_cpx_conf, cpxs_delta, cpxs_strap2/
  32 | #I #G #L2 #V #V2 #W2 #i #_ #IH #HVW2 #Y1 #H
  33   elim (lfpx_inv_lref_pair_dx … H) -H #L1 #V1 #HL1 #HV1
  34   /4 width=3 by cpxs_lref, cpxs_strap2/
  35 | #p #I #G #L2 #V #V2 #T #T2 #_ #_ #IHV #IHT #L1 #H
  36   elim (lfpx_inv_bind … H) -H /3 width=1 by cpxs_bind/
  37 | #I #G #L2 #V #V2 #T #T2 #_ #_ #IHV #IHT #L1 #H
  38   elim (lfpx_inv_flat … H) -H /3 width=1 by cpxs_flat/
  39 | #G #L2 #V #T #T2 #T0 #_ #IH #HT02 #L1 #H
  40   elim (lfpx_inv_bind … H) -H /3 width=3 by cpxs_zeta/
  41 | #G #L2 #V #T #T2 #_ #IH #L1 #H
  42   elim (lfpx_inv_flat … H) -H /3 width=1 by cpxs_eps/
  43 | #G #L2 #V #V2 #T #_ #IH #L1 #H
  44   elim (lfpx_inv_flat … H) -H /3 width=1 by cpxs_ee/
  45 | #p #G #L2 #V #V2 #W #W2 #T #T2 #_ #_ #_ #IHV #IHW #IHT #L1 #H
  46   elim (lfpx_inv_flat … H) -H #HV #H
  47   elim (lfpx_inv_bind … H) -H /3 width=1 by cpxs_beta/
  48 | #p #G #L2 #V #V2 #V0 #W #W2 #T #T2 #_ #_ #_ #IHV #IHW #IHT #HV20 #L1 #H
  49   elim (lfpx_inv_flat … H) -H #HV #H
  50   elim (lfpx_inv_bind … H) -H /3 width=3 by cpxs_theta/
  51 ]
  52 qed.
  53
  54 lemma lfpx_cpxs_trans: ∀h,G. s_rs_transitive … (cpx h G) (lfpx h G).
  55 #h #G #L2 #T1 #T2 #H #L1 #HL12 @(cpxs_ind … H) -T2
  56 /4 width=7 by lfpx_cpx_trans, cpxs_trans, lfpx_cpxs_conf/
  57 qed-.