matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpxs_lpx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/cpx_fqus.ma".
  16 include "basic_2/rt_transition/lpx_fquq.ma".
  17 include "basic_2/rt_computation/cpxs_drops.ma".
  18 include "basic_2/rt_computation/cpxs_cpxs.ma".
  19
  20 (* UNBOUND CONTEXT-SENSITIVE PARALLEL RT-COMPUTATION FOR TERMS **************)
  21
  22 (* Properties with unbound rt-transition for full local environments ********)
  23
  24 lemma lpx_cpx_trans: ∀h,G. s_r_transitive … (cpx h G) (λ_.lpx h G).
  25 #h #G #L2 #T1 #T2 #H @(cpx_ind … H) -G -L2 -T1 -T2
  26 [ /2 width=3 by/
  27 | /3 width=2 by cpx_cpxs, cpx_ess/
  28 | #I #G #K2 #V2 #V4 #W4 #_ #IH #HVW4 #L1 #H
  29   elim (lpx_inv_pair_dx … H) -H #K1 #V1 #HK12 #HV12 #H destruct
  30   /4 width=3 by cpxs_delta, cpxs_strap2/
  31 | #I2 #G #K2 #T #U #i #_ #IH #HTU #L1 #H
  32   elim (lpx_inv_bind_dx … H) -H #I1 #K1 #HK12 #HI12 #H destruct
  33   /4 width=3 by cpxs_lref, cpxs_strap2/
  34 |5,10: /4 width=1 by cpxs_beta, cpxs_bind, lpx_bind_refl_dx/
  35 |6,8,9: /3 width=1 by cpxs_flat, cpxs_ee, cpxs_eps/
  36 | /4 width=3 by cpxs_zeta, lpx_bind_refl_dx/
  37 | /4 width=3 by cpxs_theta, cpxs_strap1, lpx_bind_refl_dx/
  38 ]
  39 qed-.
  40
  41 lemma lpx_cpxs_trans: ∀h,G. s_rs_transitive … (cpx h G) (λ_.lpx h G).
  42 #h #G @s_r_trans_CTC1 /2 width=3 by lpx_cpx_trans/ (**) (* full auto fails *)
  43 qed-.
  44
  45 (* Advanced properties ******************************************************)
  46
  47 lemma cpx_bind2: ∀h,G,L,V1,V2. ❪G,L❫ ⊢ V1 ⬈[h] V2 →
  48                  ∀I,T1,T2. ❪G,L.ⓑ[I]V2❫ ⊢ T1 ⬈[h] T2 →
  49                  ∀p. ❪G,L❫ ⊢ ⓑ[p,I]V1.T1 ⬈*[h] ⓑ[p,I]V2.T2.
  50 /4 width=5 by lpx_cpx_trans, cpxs_bind_dx, lpx_pair/ qed.
  51
  52 lemma cpxs_bind2_dx: ∀h,G,L,V1,V2. ❪G,L❫ ⊢ V1 ⬈[h] V2 →
  53                      ∀I,T1,T2. ❪G,L.ⓑ[I]V2❫ ⊢ T1 ⬈*[h] T2 →
  54                      ∀p. ❪G,L❫ ⊢ ⓑ[p,I]V1.T1 ⬈*[h] ⓑ[p,I]V2.T2.
  55 /4 width=5 by lpx_cpxs_trans, cpxs_bind_dx, lpx_pair/ qed.
  56
  57 (* Properties with plus-iterated structural successor for closures **********)
  58
  59 (* Basic_2A1: uses: lpx_fqup_trans *)
  60 lemma lpx_fqup_trans: ∀h,b,G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ⬂+[b] ❪G2,L2,T2❫ →
  61                       ∀K1. ❪G1,K1❫ ⊢ ⬈[h] L1 →
  62                       ∃∃K2,T. ❪G1,K1❫ ⊢ T1 ⬈*[h] T & ❪G1,K1,T❫ ⬂+[b] ❪G2,K2,T2❫ & ❪G2,K2❫ ⊢ ⬈[h] L2.
  63 #h #b #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
  64 [ #G2 #L2 #T2 #H12 #K1 #HKL1 elim (lpx_fqu_trans … H12 … HKL1) -L1
  65   /3 width=5 by cpx_cpxs, fqu_fqup, ex3_2_intro/
  66 | #G #G2 #L #L2 #T #T2 #_ #H2 #IH1 #K1 #HLK1 elim (IH1 … HLK1) -L1
  67   #L0 #T0 #HT10 #HT0 #HL0 elim (lpx_fqu_trans … H2 … HL0) -L
  68   #L #T3 #HT3 #HT32 #HL2 elim (fqup_cpx_trans … HT0 … HT3) -T
  69   /3 width=7 by cpxs_strap1, fqup_strap1, ex3_2_intro/
  70 ]
  71 qed-.
  72
  73 (* Properties with star-iterated structural successor for closures **********)
  74
  75 (* Basic_2A1: uses: lpx_fqus_trans *)
  76 lemma lpx_fqus_trans: ∀h,b,G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ⬂*[b] ❪G2,L2,T2❫ →
  77                       ∀K1. ❪G1,K1❫ ⊢ ⬈[h] L1 →
  78                       ∃∃K2,T. ❪G1,K1❫ ⊢ T1 ⬈*[h] T & ❪G1,K1,T❫ ⬂*[b] ❪G2,K2,T2❫ & ❪G2,K2❫ ⊢ ⬈[h] L2.
  79 #h #b #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #HKL1 elim (fqus_inv_fqup … H) -H
  80 [ #H12 elim (lpx_fqup_trans … H12 … HKL1) -L1 /3 width=5 by fqup_fqus, ex3_2_intro/
  81 | * #H1 #H2 #H3 destruct /2 width=5 by ex3_2_intro/
  82 ]
  83 qed-.