matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpxs_rdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/cpx_rdeq.ma".
  16 include "basic_2/rt_computation/cpxs_tdeq.ma".
  17
  18 (* UNBOUND CONTEXT-SENSITIVE PARALLEL RT-COMPUTATION FOR TERMS **************)
  19
  20 (* Properties with sort-irrelevant equivalence for local environments *******)
  21
  22 (* Basic_2A1: was just: lleq_cpxs_trans *)
  23 lemma rdeq_cpxs_trans: ∀h,G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ⬈*[h] T1 →
  24                        ∀L2. L2 ≛[T0] L0 →
  25                        ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈*[h] T & T ≛ T1.
  26 #h #G #L0 #T0 #T1 #H @(cpxs_ind_dx … H) -T0 /2 width=3 by ex2_intro/
  27 #T0 #T #HT0 #_ #IH #L2 #HL2
  28 elim (rdeq_cpx_trans … HL2 … HT0) #U1 #H1 #H2
  29 elim (IH L2) -IH /2 width=5 by cpx_rdeq_conf_dx/ -L0 #U2 #H3 #H4
  30 elim (tdeq_cpxs_trans … H2 … H3) -T #U0 #H2 #H3
  31 /3 width=5 by cpxs_strap2, tdeq_trans, ex2_intro/
  32 qed-.
  33
  34 (* Basic_2A1: was just: cpxs_lleq_conf *)
  35 lemma cpxs_rdeq_conf: ∀h,G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ⬈*[h] T1 →
  36                       ∀L2. L0 ≛[T0] L2 →
  37                       ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈*[h] T & T ≛ T1.
  38 /3 width=3 by rdeq_cpxs_trans, rdeq_sym/ qed-.
  39
  40 (* Basic_2A1: was just: cpxs_lleq_conf_dx *)
  41 lemma cpxs_rdeq_conf_dx: ∀h,G,L2,T1,T2. ⦃G, L2⦄ ⊢ T1 ⬈*[h] T2 →
  42                          ∀L1. L1 ≛[T1] L2 → L1 ≛[T2] L2.
  43 #h #G #L2 #T1 #T2 #H @(cpxs_ind … H) -T2 /3 width=6 by cpx_rdeq_conf_dx/
  44 qed-.
  45
  46 (* Basic_2A1: was just: lleq_conf_sn *)
  47 lemma cpxs_rdeq_conf_sn: ∀h,G,L1,T1,T2. ⦃G, L1⦄ ⊢ T1 ⬈*[h] T2 →
  48                          ∀L2. L1 ≛[T1] L2 → L1 ≛[T2] L2.
  49 /4 width=6 by cpxs_rdeq_conf_dx, rdeq_sym/ qed-.