matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpxs_tdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/rpx_rdeq.ma".
  16 include "basic_2/rt_computation/cpxs.ma".
  17
  18 (* UNBOUND CONTEXT-SENSITIVE PARALLEL RT-COMPUTATION FOR TERMS **************)
  19
  20 (* Properties with sort-irrelevant equivalence for terms ********************)
  21
  22 lemma tdeq_cpxs_trans: ∀h,U1,T1. U1 ≛ T1 → ∀G,L,T2. ⦃G, L⦄ ⊢ T1 ⬈*[h] T2 →
  23                        ∃∃U2. ⦃G, L⦄ ⊢ U1 ⬈*[h] U2 & U2 ≛ T2.
  24 #h #U1 #T1 #HUT1 #G #L #T2 #HT12 @(cpxs_ind … HT12) -T2 /2 width=3 by ex2_intro/
  25 #T #T2 #_ #HT2 * #U #HU1 #HUT elim (tdeq_cpx_trans … HUT … HT2) -T -T1
  26 /3 width=3 by ex2_intro, cpxs_strap1/
  27 qed-.
  28
  29 (* Note: this requires tdeq to be symmetric *)
  30 (* Nasic_2A1: uses: cpxs_neq_inv_step_sn *)
  31 lemma cpxs_tdneq_fwd_step_sn: ∀h,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ⬈*[h] T2 → (T1 ≛ T2 → ⊥) →
  32                               ∃∃T,T0. ⦃G, L⦄ ⊢ T1 ⬈[h] T & T1 ≛ T → ⊥ & ⦃G, L⦄ ⊢ T ⬈*[h] T0 & T0 ≛ T2.
  33 #h #G #L #T1 #T2 #H @(cpxs_ind_dx … H) -T1
  34 [ #H elim H -H //
  35 | #T1 #T0 #HT10 #HT02 #IH #Hn12
  36   elim (tdeq_dec T1 T0) [ -HT10 -HT02 #H10 | -IH #Hn10 ]
  37   [ elim IH -IH /3 width=3 by tdeq_trans/ -Hn12
  38     #T3 #T4 #HT03 #Hn03 #HT34 #H42
  39     elim (tdeq_cpx_trans … H10 … HT03) -HT03 #T5 #HT15 #H53
  40     elim (tdeq_cpxs_trans … H53 … HT34) -HT34 #T6 #HT56 #H64
  41     /5 width=8 by tdeq_canc_sn, (* 2x *) tdeq_trans, ex4_2_intro/
  42   | /3 width=6 by ex4_2_intro/
  43   ]
  44 ]
  45 qed-.