matita/matita/contribs/lambdadelta/basic_2/rt_computation/cpxs_theq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/syntax/theq_tdeq.ma".
  16 include "basic_2/rt_computation/cpxs_lsubr.ma".
  17 include "basic_2/rt_computation/cpxs_cnx.ma".
  18 include "basic_2/rt_computation/lpxs_cpxs.ma".
  19
  20 (* UNBOUND CONTEXT-SENSITIVE PARALLEL RT-COMPUTATION FOR TERMS **************)
  21
  22 (* Forward lemmas with head equivalence for terms ***************************)
  23
  24 lemma cpxs_fwd_sort: ∀h,G,L,X2,s1. ⦃G, L⦄ ⊢ ⋆s1 ⬈*[h] X2 → ⋆s1 ⩳ X2.
  25 #h #G #L #X2 #s1 #H
  26 elim (cpxs_inv_sort1 … H) -H #s2 #H destruct //
  27 qed-.
  28
  29 (* Note: probably this is an inversion lemma *)
  30 (* Basic_2A1: was: cpxs_fwd_delta *)
  31 lemma cpxs_fwd_delta_drops: ∀h,I,G,L,K,V1,i. ⬇*[i] L ≘ K.ⓑ{I}V1 →
  32                             ∀V2. ⬆*[↑i] V1 ≘ V2 →
  33                             ∀X2. ⦃G, L⦄ ⊢ #i ⬈*[h] X2 →
  34                             ∨∨ #i ⩳ X2 | ⦃G, L⦄ ⊢ V2 ⬈*[h] X2.
  35 #h #I #G #L #K #V1 #i #HLK #V2 #HV12 #X2 #H
  36 elim (cpxs_inv_lref1_drops … H) -H /2 width=1 by or_introl/
  37 * #I0 #K0 #V0 #U0 #HLK0 #HVU0 #HU0
  38 lapply (drops_mono … HLK0 … HLK) -HLK0 #H destruct
  39 /4 width=9 by cpxs_lifts_bi, drops_isuni_fwd_drop2, or_intror/
  40 qed-.
  41
  42 (* Basic_1: was just: pr3_iso_beta *)
  43 lemma cpxs_fwd_beta: ∀h,p,G,L,V,W,T,X2. ⦃G, L⦄ ⊢ ⓐV.ⓛ{p}W.T ⬈*[h] X2 →
  44                      ∨∨ ⓐV.ⓛ{p}W.T ⩳ X2 | ⦃G, L⦄ ⊢ ⓓ{p}ⓝW.V.T ⬈*[h] X2.
  45 #h #p #G #L #V #W #T #X2 #H elim (cpxs_inv_appl1 … H) -H *
  46 [ #V0 #T0 #_ #_ #H destruct /2 width=1 by theq_pair, or_introl/
  47 | #b #W0 #T0 #HT0 #HU
  48   elim (cpxs_inv_abst1 … HT0) -HT0 #W1 #T1 #HW1 #HT1 #H destruct
  49   lapply (lsubr_cpxs_trans … HT1 (L.ⓓⓝW.V) ?) -HT1
  50   /5 width=3 by cpxs_trans, cpxs_bind, cpxs_pair_sn, lsubr_beta, or_intror/
  51 | #b #V1 #V2 #V0 #T1 #_ #_ #HT1 #_
  52   elim (cpxs_inv_abst1 … HT1) -HT1 #W2 #T2 #_ #_ #H destruct
  53 ]
  54 qed-.
  55
  56 lemma cpxs_fwd_theta: ∀h,p,G,L,V1,V,T,X2. ⦃G, L⦄ ⊢ ⓐV1.ⓓ{p}V.T ⬈*[h] X2 →
  57                       ∀V2. ⬆*[1] V1 ≘ V2 →
  58                       ∨∨ ⓐV1.ⓓ{p}V.T ⩳ X2 | ⦃G, L⦄ ⊢ ⓓ{p}V.ⓐV2.T ⬈*[h] X2.
  59 #h #p #G #L #V1 #V #T #X2 #H #V2 #HV12
  60 elim (cpxs_inv_appl1 … H) -H *
  61 [ -HV12 #V0 #T0 #_ #_ #H destruct /2 width=1 by theq_pair, or_introl/
  62 | #q #W #T0 #HT0 #HU
  63   elim (cpxs_inv_abbr1_dx … HT0) -HT0 *
  64   [ #V3 #T3 #_ #_ #H destruct
  65   | #X #HT2 #H #H0 destruct
  66     elim (lifts_inv_bind1 … H) -H #W2 #T2 #HW2 #HT02 #H destruct
  67     @or_intror @(cpxs_trans … HU) -X2 (**) (* explicit constructor *)
  68     @(cpxs_trans … (+ⓓV.ⓐV2.ⓛ{q}W2.T2)) [ /3 width=1 by cpxs_flat_dx, cpxs_bind_dx/ ] -T
  69     @(cpxs_strap2 … (ⓐV1.ⓛ{q}W.T0)) [2: /2 width=1 by cpxs_beta_dx/ ]
  70     /4 width=7 by cpx_zeta, lifts_bind, lifts_flat/
  71   ]
  72 | #q #V3 #V4 #V0 #T0 #HV13 #HV34 #HT0 #HU
  73   @or_intror @(cpxs_trans … HU) -X2 (**) (* explicit constructor *)
  74   elim (cpxs_inv_abbr1_dx … HT0) -HT0 *
  75   [ #V5 #T5 #HV5 #HT5 #H destruct
  76     /6 width=9 by cpxs_lifts_bi, drops_refl, drops_drop, cpxs_flat, cpxs_bind/
  77   | #X #HT1 #H #H0 destruct
  78     elim (lifts_inv_bind1 … H) -H #V5 #T5 #HV05 #HT05 #H destruct
  79     lapply (cpxs_lifts_bi … HV13 (Ⓣ) … (L.ⓓV0) … HV12 … HV34) -V3 /3 width=1 by drops_refl, drops_drop/ #HV24
  80     @(cpxs_trans … (+ⓓV.ⓐV2.ⓓ{q}V5.T5)) [ /3 width=1 by cpxs_flat_dx, cpxs_bind_dx/ ] -T
  81     @(cpxs_strap2 … (ⓐV1.ⓓ{q}V0.T0)) [ /4 width=7 by cpx_zeta, lifts_bind, lifts_flat/ ] -V -V5 -T5
  82     @(cpxs_strap2 … (ⓓ{q}V0.ⓐV2.T0)) /3 width=3 by cpxs_pair_sn, cpxs_bind_dx, cpx_theta/
  83   ]
  84 ]
  85 qed-.
  86
  87 lemma cpxs_fwd_cast: ∀h,G,L,W,T,X2. ⦃G, L⦄ ⊢ ⓝW.T ⬈*[h] X2 →
  88                      ∨∨ ⓝW. T ⩳ X2 | ⦃G, L⦄ ⊢ T ⬈*[h] X2 | ⦃G, L⦄ ⊢ W ⬈*[h] X2.
  89 #h #G #L #W #T #X2 #H
  90 elim (cpxs_inv_cast1 … H) -H /2 width=1 by or3_intro1, or3_intro2/ *
  91 #W0 #T0 #_ #_ #H destruct /2 width=1 by theq_pair, or3_intro0/
  92 qed-.
  93
  94 lemma cpxs_fwd_cnx: ∀h,G,L,T1. ⦃G, L⦄ ⊢ ⬈[h] 𝐍⦃T1⦄ →
  95                     ∀X2. ⦃G, L⦄ ⊢ T1 ⬈*[h] X2 → T1 ⩳ X2.
  96 /3 width=5 by cpxs_inv_cnx1, tdeq_theq/ qed-.