matita/matita/contribs/lambdadelta/basic_2/rt_computation/csx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predtystrong_4.ma".
  16 include "static_2/syntax/tdeq.ma".
  17 include "basic_2/rt_transition/cpx.ma".
  18
  19 (* STRONGLY NORMALIZING TERMS FOR UNBOUND PARALLEL RT-TRANSITION ************)
  20
  21 definition csx: ∀h. relation3 genv lenv term ≝
  22                 λh,G,L. SN … (cpx h G L) tdeq.
  23
  24 interpretation
  25    "strong normalization for unbound context-sensitive parallel rt-transition (term)"
  26    'PRedTyStrong h G L T = (csx h G L T).
  27
  28 (* Basic eliminators ********************************************************)
  29
  30 lemma csx_ind: ∀h,G,L. ∀Q:predicate term.
  31                (∀T1. ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃T1⦄ →
  32                      (∀T2. ⦃G, L⦄ ⊢ T1 ⬈[h] T2 → (T1 ≛ T2 → ⊥) → Q T2) →
  33                      Q T1
  34                ) →
  35                ∀T. ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃T⦄ →  Q T.
  36 #h #G #L #Q #H0 #T1 #H elim H -T1
  37 /5 width=1 by SN_intro/
  38 qed-.
  39
  40 (* Basic properties *********************************************************)
  41
  42 (* Basic_1: was just: sn3_pr2_intro *)
  43 lemma csx_intro: ∀h,G,L,T1.
  44                  (∀T2. ⦃G, L⦄ ⊢ T1 ⬈[h] T2 → (T1 ≛ T2 → ⊥) → ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃T2⦄) →
  45                  ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃T1⦄.
  46 /4 width=1 by SN_intro/ qed.
  47
  48 (* Basic forward lemmas *****************************************************)
  49
  50 fact csx_fwd_pair_sn_aux: ∀h,G,L,U. ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃U⦄ →
  51                           ∀I,V,T. U = ②{I}V.T → ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃V⦄.
  52 #h #G #L #U #H elim H -H #U0 #_ #IH #I #V #T #H destruct
  53 @csx_intro #V2 #HLV2 #HV2
  54 @(IH (②{I}V2.T)) -IH /2 width=3 by cpx_pair_sn/ -HLV2
  55 #H elim (tdeq_inv_pair … H) -H /2 width=1 by/
  56 qed-.
  57
  58 (* Basic_1: was just: sn3_gen_head *)
  59 lemma csx_fwd_pair_sn: ∀h,I,G,L,V,T. ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃②{I}V.T⦄ → ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃V⦄.
  60 /2 width=5 by csx_fwd_pair_sn_aux/ qed-.
  61
  62 fact csx_fwd_bind_dx_aux: ∀h,G,L,U. ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃U⦄ →
  63                           ∀p,I,V,T. U = ⓑ{p,I}V.T → ⦃G, L.ⓑ{I}V⦄ ⊢ ⬈*[h] 𝐒⦃T⦄.
  64 #h #G #L #U #H elim H -H #U0 #_ #IH #p #I #V #T #H destruct
  65 @csx_intro #T2 #HLT2 #HT2
  66 @(IH (ⓑ{p,I}V.T2)) -IH /2 width=3 by cpx_bind/ -HLT2
  67 #H elim (tdeq_inv_pair … H) -H /2 width=1 by/
  68 qed-.
  69
  70 (* Basic_1: was just: sn3_gen_bind *)
  71 lemma csx_fwd_bind_dx: ∀h,p,I,G,L,V,T. ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃ⓑ{p,I}V.T⦄ → ⦃G, L.ⓑ{I}V⦄ ⊢ ⬈*[h] 𝐒⦃T⦄.
  72 /2 width=4 by csx_fwd_bind_dx_aux/ qed-.
  73
  74 fact csx_fwd_flat_dx_aux: ∀h,G,L,U. ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃U⦄ →
  75                           ∀I,V,T. U = ⓕ{I}V.T → ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃T⦄.
  76 #h #G #L #U #H elim H -H #U0 #_ #IH #I #V #T #H destruct
  77 @csx_intro #T2 #HLT2 #HT2
  78 @(IH (ⓕ{I}V.T2)) -IH /2 width=3 by cpx_flat/ -HLT2
  79 #H elim (tdeq_inv_pair … H) -H /2 width=1 by/
  80 qed-.
  81
  82 (* Basic_1: was just: sn3_gen_flat *)
  83 lemma csx_fwd_flat_dx: ∀h,I,G,L,V,T. ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃ⓕ{I}V.T⦄ → ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃T⦄.
  84 /2 width=5 by csx_fwd_flat_dx_aux/ qed-.
  85
  86 lemma csx_fwd_bind: ∀h,p,I,G,L,V,T. ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃ⓑ{p,I}V.T⦄ →
  87                     ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃V⦄ ∧ ⦃G, L.ⓑ{I}V⦄ ⊢ ⬈*[h] 𝐒⦃T⦄.
  88 /3 width=3 by csx_fwd_pair_sn, csx_fwd_bind_dx, conj/ qed-.
  89
  90 lemma csx_fwd_flat: ∀h,I,G,L,V,T. ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃ⓕ{I}V.T⦄ →
  91                     ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃V⦄ ∧ ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃T⦄.
  92 /3 width=3 by csx_fwd_pair_sn, csx_fwd_flat_dx, conj/ qed-.
  93
  94 (* Basic_1: removed theorems 14:
  95             sn3_cdelta
  96             sn3_gen_cflat sn3_cflat sn3_cpr3_trans sn3_shift sn3_change
  97             sn3_appl_cast sn3_appl_beta sn3_appl_lref sn3_appl_abbr
  98             sn3_appl_appls sn3_bind sn3_appl_bind sn3_appls_bind
  99 *)
 100 (* Basic_2A1: removed theorems 6:
 101               csxa_ind csxa_intro csxa_cpxs_trans csxa_intro_cpx
 102               csx_csxa csxa_csx
 103 *)