matita/matita/contribs/lambdadelta/basic_2/rt_computation/csx_aaa.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/gcp_aaa.ma".
  16 include "basic_2/rt_computation/cpxs_aaa.ma".
  17 include "basic_2/rt_computation/csx_gcp.ma".
  18 include "basic_2/rt_computation/csx_gcr.ma".
  19
  20 (* STRONGLY NORMALIZING TERMS FOR EXTENDED PARALLEL RT-TRANSITION ***********)
  21
  22 (* Main properties with atomic arity assignment *****************************)
  23
  24 theorem aaa_csx (G) (L):
  25         ∀T,A. ❪G,L❫ ⊢ T ⁝ A → ❪G,L❫ ⊢ ⬈*𝐒 T.
  26 #G #L #T #A #H
  27 @(gcr_aaa … csx_gcp csx_gcr … H)
  28 qed.
  29
  30 (* Advanced eliminators *****************************************************)
  31
  32 fact aaa_ind_csx_aux (G) (L):
  33      ∀A. ∀Q:predicate ….
  34      (∀T1. ❪G,L❫ ⊢ T1 ⁝ A →
  35        (∀T2. ❪G,L❫ ⊢ T1 ⬈ T2 → (T1 ≛ T2 → ⊥) → Q T2) → Q T1
  36      ) →
  37      ∀T. ❪G,L❫ ⊢ ⬈*𝐒 T → ❪G,L❫ ⊢ T ⁝ A →  Q T.
  38 #G #L #A #Q #IH #T #H @(csx_ind … H) -T /4 width=5 by cpx_aaa_conf/
  39 qed-.
  40
  41 lemma aaa_ind_csx (G) (L):
  42       ∀A. ∀Q:predicate ….
  43       (∀T1. ❪G,L❫ ⊢ T1 ⁝ A →
  44         (∀T2. ❪G,L❫ ⊢ T1 ⬈ T2 → (T1 ≛ T2 → ⊥) → Q T2) → Q T1
  45       ) →
  46       ∀T. ❪G,L❫ ⊢ T ⁝ A → Q T.
  47 /5 width=9 by aaa_ind_csx_aux, aaa_csx/ qed-.
  48
  49 fact aaa_ind_csx_cpxs_aux (G) (L):
  50      ∀A. ∀Q:predicate ….
  51      (∀T1. ❪G,L❫ ⊢ T1 ⁝ A →
  52        (∀T2. ❪G,L❫ ⊢ T1 ⬈* T2 → (T1 ≛ T2 → ⊥) → Q T2) → Q T1
  53      ) →
  54      ∀T. ❪G,L❫ ⊢ ⬈*𝐒 T → ❪G,L❫ ⊢ T ⁝ A →  Q T.
  55 #G #L #A #Q #IH #T #H @(csx_ind_cpxs … H) -T /4 width=5 by cpxs_aaa_conf/
  56 qed-.
  57
  58 (* Basic_2A1: was: aaa_ind_csx_alt *)
  59 lemma aaa_ind_csx_cpxs (G) (L):
  60       ∀A. ∀Q:predicate ….
  61       (∀T1. ❪G,L❫ ⊢ T1 ⁝ A →
  62         (∀T2. ❪G,L❫ ⊢ T1 ⬈* T2 → (T1 ≛ T2 → ⊥) → Q T2) → Q T1
  63       ) →
  64       ∀T. ❪G,L❫ ⊢ T ⁝ A → Q T.
  65 /5 width=9 by aaa_ind_csx_cpxs_aux, aaa_csx/ qed-.