matita/matita/contribs/lambdadelta/basic_2/rt_computation/csx_aaa.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/gcp_aaa.ma".
  16 include "basic_2/rt_computation/cpxs_aaa.ma".
  17 include "basic_2/rt_computation/csx_gcp.ma".
  18 include "basic_2/rt_computation/csx_gcr.ma".
  19
  20 (* STRONGLY NORMALIZING TERMS FOR UNBOUND PARALLEL RT-TRANSITION ************)
  21
  22 (* Main properties with atomic arity assignment *****************************)
  23
  24 theorem aaa_csx: ∀h,o,G,L,T,A. ⦃G, L⦄ ⊢ T ⁝ A → ⦃G, L⦄ ⊢ ⬈*[h, o] 𝐒⦃T⦄.
  25 #h #o #G #L #T #A #H
  26 @(gcr_aaa … (csx_gcp h o) (csx_gcr h o) … H)
  27 qed.
  28
  29 (* Advanced eliminators *****************************************************)
  30
  31 fact aaa_ind_csx_aux: ∀h,o,G,L,A. ∀Q:predicate term.
  32                       (∀T1. ⦃G, L⦄ ⊢ T1 ⁝ A →
  33                             (∀T2. ⦃G, L⦄ ⊢ T1 ⬈[h] T2 → (T1 ≛[h, o] T2 → ⊥) → Q T2) → Q T1
  34                       ) →
  35                       ∀T. ⦃G, L⦄ ⊢ ⬈*[h, o] 𝐒⦃T⦄ → ⦃G, L⦄ ⊢ T ⁝ A →  Q T.
  36 #h #o #G #L #A #Q #IH #T #H @(csx_ind … H) -T /4 width=5 by cpx_aaa_conf/
  37 qed-.
  38
  39 lemma aaa_ind_csx: ∀h,o,G,L,A. ∀Q:predicate term.
  40                    (∀T1. ⦃G, L⦄ ⊢ T1 ⁝ A →
  41                          (∀T2. ⦃G, L⦄ ⊢ T1 ⬈[h] T2 → (T1 ≛[h, o] T2 → ⊥) → Q T2) → Q T1
  42                    ) →
  43                    ∀T. ⦃G, L⦄ ⊢ T ⁝ A → Q T.
  44 /5 width=9 by aaa_ind_csx_aux, aaa_csx/ qed-.
  45
  46 fact aaa_ind_csx_cpxs_aux: ∀h,o,G,L,A. ∀Q:predicate term.
  47                            (∀T1. ⦃G, L⦄ ⊢ T1 ⁝ A →
  48                                  (∀T2. ⦃G, L⦄ ⊢ T1 ⬈*[h] T2 → (T1 ≛[h, o] T2 → ⊥) → Q T2) → Q T1
  49                            ) →
  50                            ∀T. ⦃G, L⦄ ⊢ ⬈*[h, o] 𝐒⦃T⦄ → ⦃G, L⦄ ⊢ T ⁝ A →  Q T.
  51 #h #o #G #L #A #Q #IH #T #H @(csx_ind_cpxs … H) -T /4 width=5 by cpxs_aaa_conf/
  52 qed-.
  53
  54 (* Basic_2A1: was: aaa_ind_csx_alt *)
  55 lemma aaa_ind_csx_cpxs: ∀h,o,G,L,A. ∀Q:predicate term.
  56                         (∀T1. ⦃G, L⦄ ⊢ T1 ⁝ A →
  57                               (∀T2. ⦃G, L⦄ ⊢ T1 ⬈*[h] T2 → (T1 ≛[h, o] T2 → ⊥) → Q T2) → Q T1
  58                         ) →
  59                         ∀T. ⦃G, L⦄ ⊢ T ⁝ A → Q T.
  60 /5 width=9 by aaa_ind_csx_cpxs_aux, aaa_csx/ qed-.