matita/matita/contribs/lambdadelta/basic_2/rt_computation/csx_cpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/cpxs_teqx.ma".
  16 include "basic_2/rt_computation/cpxs_cpxs.ma".
  17 include "basic_2/rt_computation/csx_csx.ma".
  18
  19 (* STRONGLY NORMALIZING TERMS FOR EXTENDED PARALLEL RT-TRANSITION ***********)
  20
  21 (* Properties with extended context-sensitive rt-computation for terms ******)
  22
  23 (* Basic_1: was just: sn3_intro *)
  24 lemma csx_intro_cpxs (G) (L):
  25       ∀T1. (∀T2. ❪G,L❫ ⊢ T1 ⬈* T2 → (T1 ≛ T2 → ⊥) → ❪G,L❫ ⊢ ⬈*𝐒 T2) →
  26       ❪G,L❫ ⊢ ⬈*𝐒 T1.
  27 /4 width=1 by cpx_cpxs, csx_intro/ qed-.
  28
  29 (* Basic_1: was just: sn3_pr3_trans *)
  30 lemma csx_cpxs_trans (G) (L):
  31       ∀T1. ❪G,L❫ ⊢ ⬈*𝐒 T1 →
  32       ∀T2. ❪G,L❫ ⊢ T1 ⬈* T2 → ❪G,L❫ ⊢ ⬈*𝐒 T2.
  33 #G #L #T1 #HT1 #T2 #H @(cpxs_ind … H) -T2
  34 /2 width=3 by csx_cpx_trans/
  35 qed-.
  36
  37 (* Eliminators with extended context-sensitive rt-computation for terms *****)
  38
  39 lemma csx_ind_cpxs_teqx (G) (L):
  40       ∀Q:predicate term.
  41       (∀T1. ❪G,L❫ ⊢ ⬈*𝐒 T1 →
  42         (∀T2. ❪G,L❫ ⊢ T1 ⬈* T2 → (T1 ≛ T2 → ⊥) → Q T2) → Q T1
  43       ) →
  44       ∀T1. ❪G,L❫ ⊢ ⬈*𝐒 T1 →
  45       ∀T0. ❪G,L❫ ⊢ T1 ⬈* T0 → ∀T2. T0 ≛ T2 → Q T2.
  46 #G #L #Q #IH #T1 #H @(csx_ind … H) -T1
  47 #T1 #HT1 #IH1 #T0 #HT10 #T2 #HT02
  48 @IH -IH /3 width=3 by csx_cpxs_trans, csx_teqx_trans/ -HT1 #V2 #HTV2 #HnTV2
  49 lapply (teqx_tneqx_trans … HT02 … HnTV2) -HnTV2 #H
  50 elim (teqx_cpxs_trans … HT02 … HTV2) -T2 #V0 #HTV0 #HV02
  51 lapply (tneqx_teqx_canc_dx … H … HV02) -H #HnTV0
  52 elim (teqx_dec T1 T0) #H
  53 [ lapply (teqx_tneqx_trans … H … HnTV0) -H -HnTV0 #Hn10
  54   lapply (cpxs_trans … HT10 … HTV0) -T0 #H10
  55   elim (cpxs_tneqx_fwd_step_sn … H10 …  Hn10) -H10 -Hn10
  56   /3 width=8 by teqx_trans/
  57 | elim (cpxs_tneqx_fwd_step_sn … HT10 … H) -HT10 -H #T #V #HT1 #HnT1 #HTV #HVT0
  58   elim (teqx_cpxs_trans … HVT0 … HTV0) -T0
  59   /3 width=8 by cpxs_trans, teqx_trans/
  60 ]
  61 qed-.
  62
  63 (* Basic_2A1: was: csx_ind_alt *)
  64 lemma csx_ind_cpxs (G) (L) (Q:predicate …):
  65       (∀T1. ❪G,L❫ ⊢ ⬈*𝐒 T1 →
  66         (∀T2. ❪G,L❫ ⊢ T1 ⬈* T2 → (T1 ≛ T2 → ⊥) → Q T2) → Q T1
  67       ) →
  68       ∀T. ❪G,L❫ ⊢ ⬈*𝐒 T → Q T.
  69 #G #L #Q #IH #T #HT
  70 @(csx_ind_cpxs_teqx … IH … HT) -IH -HT // (**) (* full auto fails *)
  71 qed-.