matita/matita/contribs/lambdadelta/basic_2/rt_computation/csx_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/relocation/lifts_teqx.ma".
  16 include "basic_2/rt_transition/cpx_drops.ma".
  17 include "basic_2/rt_computation/csx.ma".
  18
  19 (* STRONGLY NORMALIZING TERMS FOR UNBOUND PARALLEL RT-TRANSITION ************)
  20
  21 (* Properties with generic relocation ***************************************)
  22
  23 (* Basic_1: was just: sn3_lift *)
  24 (* Basic_2A1: was just: csx_lift *)
  25 lemma csx_lifts (h) (G):
  26       d_liftable1 … (csx h G).
  27 #h #G #K #T #H @(csx_ind … H) -T
  28 #T1 #_ #IH #b #f #L #HLK #U1 #HTU1
  29 @csx_intro #U2 #HU12 #HnU12
  30 elim (cpx_inv_lifts_sn … HU12 … HLK … HTU1) -HU12
  31 /4 width=7 by teqx_lifts_bi/
  32 qed-.
  33
  34 (* Inversion lemmas with generic slicing ************************************)
  35
  36 (* Basic_1: was just: sn3_gen_lift *)
  37 (* Basic_2A1: was just: csx_inv_lift *)
  38 lemma csx_inv_lifts (h) (G):
  39       d_deliftable1 … (csx h G).
  40 #h #G #L #U #H @(csx_ind … H) -U
  41 #U1 #_ #IH #b #f #K #HLK #T1 #HTU1
  42 @csx_intro #T2 #HT12 #HnT12
  43 elim (cpx_lifts_sn … HT12 … HLK … HTU1) -HT12
  44 /4 width=7 by teqx_inv_lifts_bi/
  45 qed-.