matita/matita/contribs/lambdadelta/basic_2/rt_computation/csx_lfpx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/cpxs_lfpx.ma".
  16 include "basic_2/rt_computation/csx_drops.ma".
  17 include "basic_2/rt_computation/csx_cpxs.ma".
  18
  19 (* STRONGLY NORMALIZING TERMS FOR UNCOUNTED PARALLEL RT-TRANSITION **********)
  20
  21 (* Advanced properties ******************************************************)
  22
  23 (* Basic_2A1: was just: csx_lpx_conf *)
  24 lemma csx_lfpx_conf: ∀h,o,G,L1,T. ⦃G, L1⦄ ⊢ ⬈*[h, o] 𝐒⦃T⦄ →
  25                      ∀L2. ⦃G, L1⦄ ⊢ ⬈[h, T] L2 → ⦃G, L2⦄ ⊢ ⬈*[h, o] 𝐒⦃T⦄.
  26 #h #o #G #L1 #T #H @(csx_ind_cpxs … H) -T
  27 /5 width=3 by csx_intro, lfpx_cpx_trans, lfpx_cpxs_conf/
  28 qed-.
  29
  30 lemma csx_abst: ∀h,o,p,G,L,W. ⦃G, L⦄ ⊢ ⬈*[h, o] 𝐒⦃W⦄ →
  31                 ∀T. ⦃G, L.ⓛW⦄ ⊢ ⬈*[h, o] 𝐒⦃T⦄ → ⦃G, L⦄ ⊢ ⬈*[h, o] 𝐒⦃ⓛ{p}W.T⦄.
  32 #h #o #p #G #L #W #HW @(csx_ind … HW) -W
  33 #W #_ #IHW #T #HT @(csx_ind … HT) -T #T #HT #IHT
  34 @csx_intro #X #H1 #H2
  35 elim (cpx_inv_abst1 … H1) -H1
  36 #W0 #T0 #HLW0 #HLT0 #H destruct
  37 elim (tdneq_inv_pair … H2) -H2
  38 [ #H elim H -H //
  39 | -IHT #H lapply (csx_cpx_trans … o … HLT0) // -HT
  40   #HT0 lapply (csx_lfpx_conf … HT0 … (L.ⓛW0)) -HT0 /4 width=1 by lfpx_pair/
  41 | -IHW -HT /4 width=3 by csx_cpx_trans, cpx_pair_sn/
  42 ]
  43 qed.
  44
  45 lemma csx_abbr: ∀h,o,p,G,L,V. ⦃G, L⦄ ⊢ ⬈*[h, o] 𝐒⦃V⦄ →
  46                 ∀T. ⦃G, L.ⓓV⦄ ⊢ ⬈*[h, o] 𝐒⦃T⦄ → ⦃G, L⦄ ⊢ ⬈*[h, o] 𝐒⦃ⓓ{p}V.T⦄.
  47 #h #o #p #G #L #V #HV @(csx_ind … HV) -V
  48 #V #_ #IHV #T #HT @(csx_ind_cpxs … HT) -T #T #HT #IHT
  49 @csx_intro #X #H1 #H2
  50 elim (cpx_inv_abbr1 … H1) -H1 *
  51 [ #V1 #T1 #HLV1 #HLT1 #H destruct
  52   elim (tdneq_inv_pair … H2) -H2
  53   [ #H elim H -H //
  54   | /4 width=3 by csx_cpx_trans, csx_lfpx_conf, lfpx_pair/
  55   | -IHV /4 width=3 by csx_cpx_trans, cpx_cpxs, cpx_pair_sn/
  56   ]
  57 | -IHV -IHT -H2
  58   /4 width=7 by csx_cpx_trans, csx_inv_lifts, drops_drop, drops_refl/
  59 ]
  60 qed.
  61
  62 fact csx_appl_theta_aux: ∀h,o,p,G,L,U. ⦃G, L⦄ ⊢ ⬈*[h, o] 𝐒⦃U⦄ → ∀V1,V2. ⬆*[1] V1 ≡ V2 →
  63                          ∀V,T. U = ⓓ{p}V.ⓐV2.T → ⦃G, L⦄ ⊢ ⬈*[h, o] 𝐒⦃ⓐV1.ⓓ{p}V.T⦄.
  64 #h #o #p #G #L #X #H @(csx_ind_cpxs … H) -X
  65 #X #HVT #IHVT #V1 #V2 #HV12 #V #T #H destruct
  66 lapply (csx_fwd_pair_sn … HVT) #HV
  67 lapply (csx_fwd_bind_dx … HVT) -HVT #HVT
  68 @csx_intro #X #HL #H
  69 elim (cpx_inv_appl1 … HL) -HL *
  70 [ -HV #V0 #Y #HLV10 #HL #H0 destruct
  71   elim (cpx_inv_abbr1 … HL) -HL *
  72   [ -HVT #V3 #T3 #HV3 #HLT3 #H0 destruct
  73     elim (cpx_lifts_sn … HLV10 (Ⓣ) … (L.ⓓV) … HV12) -HLV10 /3 width=1 by drops_refl, drops_drop/ #V4 #HV04 #HV24
  74     elim (tdeq_dec h o (ⓓ{p}V.ⓐV2.T) (ⓓ{p}V3.ⓐV4.T3)) #H0
  75     [ -IHVT -HV3 -HV24 -HLT3
  76       elim (tdeq_inv_pair … H0) -H0 #_ #HV3 #H0
  77       elim (tdeq_inv_pair … H0) -H0 #_ #HV24 #HT3
  78       elim (tdneq_inv_pair … H) -H #H elim H -H -G -L
  79       /3 width=6 by tdeq_inv_lifts_bi, tdeq_pair/
  80     | -V1 @(IHVT … H0 … HV04) -o -V0 /4 width=1 by cpx_cpxs, cpx_flat, cpx_bind/
  81     ]
  82   | -H -IHVT #T0 #HLT0 #HT0 #H0 destruct
  83     lapply (csx_cpx_trans … HVT (ⓐV2.T0) ?) /2 width=1 by cpx_flat/ -T #HVT0
  84     lapply (csx_inv_lifts … HVT0 (Ⓣ) … L ???) -HVT0
  85     /3 width=5 by csx_cpx_trans, cpx_pair_sn, drops_refl, drops_drop, lifts_flat/
  86   ]
  87 | -HV -HV12 -HVT -IHVT -H #b #V0 #W0 #W1 #T0 #T1 #_ #_ #_ #H destruct
  88 | -IHVT -H #b #V0 #V3 #W0 #W1 #T0 #T1 #HLV10 #HV03 #HLW01 #HLT01 #H1 #H2 destruct
  89   lapply (cpx_lifts_bi … HLV10 (Ⓣ) … (L.ⓓW0) … HV12 … HV03) -HLV10 -HV12 -HV03 /3 width=1 by drops_refl, drops_drop/ #HLV23
  90   @csx_abbr /2 width=3 by csx_cpx_trans/ -HV
  91   @(csx_lfpx_conf … (L.ⓓW0)) /2 width=1 by lfpx_pair/ -W1
  92   /4 width=5 by csx_cpxs_trans, cpx_cpxs, cpx_flat/
  93 ]
  94 qed-.
  95
  96 lemma csx_appl_theta: ∀h,o,p,G,L,V,V2,T. ⦃G, L⦄ ⊢ ⬈*[h, o] 𝐒⦃ⓓ{p}V.ⓐV2.T⦄ →
  97                       ∀V1. ⬆*[1] V1 ≡ V2 → ⦃G, L⦄ ⊢ ⬈*[h, o] 𝐒⦃ⓐV1.ⓓ{p}V.T⦄.
  98 /2 width=5 by csx_appl_theta_aux/ qed.