matita/matita/contribs/lambdadelta/basic_2/rt_computation/csx_simple_teqo.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/syntax/teqo_simple.ma".
  16 include "static_2/syntax/teqo_teqo.ma".
  17 include "basic_2/rt_transition/cpx_simple.ma".
  18 include "basic_2/rt_computation/cpxs.ma".
  19 include "basic_2/rt_computation/csx_csx.ma".
  20
  21 (* STRONGLY NORMALIZING TERMS FOR EXTENDED PARALLEL RT-TRANSITION ***********)
  22
  23 (* Properties with outer equivalence for terms ******************************)
  24
  25 (* Basic_1: was just: sn3_appl_appl *)
  26 (* Basic_2A1: was: csx_appl_simple_tsts *)
  27 lemma csx_appl_simple_teqo (G) (L):
  28       ∀V. ❪G,L❫ ⊢ ⬈*𝐒 V → ∀T1. ❪G,L❫ ⊢ ⬈*𝐒 T1 →
  29       (∀T2. ❪G,L❫ ⊢ T1 ⬈* T2 → (T1 ⩳ T2 → ⊥) → ❪G,L❫ ⊢ ⬈*𝐒 ⓐV.T2) →
  30       𝐒❪T1❫ → ❪G,L❫ ⊢ ⬈*𝐒 ⓐV.T1.
  31 #G #L #V #H @(csx_ind … H) -V
  32 #V #_ #IHV #T1 #H @(csx_ind … H) -T1
  33 #T1 #H1T1 #IHT1 #H2T1 #H3T1
  34 @csx_intro #X #HL #H
  35 elim (cpx_inv_appl1_simple … HL) -HL //
  36 #V0 #T0 #HLV0 #HLT10 #H0 destruct
  37 elim (tneqx_inv_pair … H) -H
  38 [ #H elim H -H //
  39 | -IHT1 #HV0
  40   @(csx_cpx_trans … (ⓐV0.T1)) /2 width=1 by cpx_flat/ -HLT10
  41   @IHV -IHV /4 width=3 by csx_cpx_trans, cpx_pair_sn/
  42 | -IHV -H1T1 #H1T10
  43   @(csx_cpx_trans … (ⓐV.T0)) /2 width=1 by cpx_flat/ -HLV0
  44   elim (teqo_dec T1 T0) #H2T10
  45   [ @IHT1 -IHT1 /4 width=5 by cpxs_strap2, cpxs_strap1, teqo_canc_sn, simple_teqo_repl_dx/
  46   | -IHT1 -H3T1 -H1T10 /3 width=1 by cpx_cpxs/
  47   ]
  48 ]
  49 qed.